robot-systest/testsuite/k8s_10-sol004_sol007_with_k8s_proxy_charms.robot

   1 *** Comments ***
   2 #   Licensed under the Apache License, Version 2.0 (the "License");
   3 #   you may not use this file except in compliance with the License.
   4 #   You may obtain a copy of the License at
   5 #
   6 #       http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 #   Unless required by applicable law or agreed to in writing, software
   9 #   distributed under the License is distributed on an "AS IS" BASIS,
  10 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 #   See the License for the specific language governing permissions and
  12 #   limitations under the License.
  13
  14
  15 *** Settings ***
  16 Documentation   [K8s-10] K8s Proxy Charm using SOL004 and SOL007 packages.
  17
  18 Library   OperatingSystem
  19 Library   SSHLibrary
  20
  21 Resource   ../lib/vnfd_lib.resource
  22 Resource   ../lib/nsd_lib.resource
  23 Resource   ../lib/ns_lib.resource
  24 Resource   ../lib/ns_operation_lib.resource
  25 Resource   ../lib/ssh_lib.resource
  26
  27 Test Tags   k8s_10   cluster_ee_config   cluster_k8s_charms   regression   azure
  28
  29 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  30
  31
  32 *** Variables ***
  33 # NS and VNF descriptor package folder and ids
  34 ${VNFD_PKG}   charm-packages/sol004_k8s_proxy_charm_vnf
  35 ${VNFD_NAME}   sol004_k8s_proxy_charm-vnf
  36 ${NSD_PKG}   charm-packages/sol007_k8s_proxy_charm_ns
  37 ${NSD_NAME}   sol007_k8s_proxy_charm-ns
  38
  39 # NS instance name and configuration
  40 ${NS_NAME}   k8s_10-k8s_proxy_charm
  41 ${NS_CONFIG}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  42 ${NS_TIMEOUT}   15min
  43
  44 # SSH keys and username to be used
  45 ${PUBLICKEY}   %{HOME}/.ssh/id_rsa.pub
  46 ${PRIVATEKEY}   %{HOME}/.ssh/id_rsa
  47 ${USERNAME}   ubuntu
  48 ${PASSWORD}   ${EMPTY}
  49
  50 ${ACTION_NAME}   touch
  51 ${VNF_MEMBER_INDEX_1}   vnf1
  52 ${VNF_MEMBER_INDEX_2}   vnf2
  53 ${DAY_1_FILE_NAME}   /home/ubuntu/first-touch
  54 ${DAY_2_FILE_NAME_1}   /home/ubuntu/mytouch1
  55 ${DAY_2_FILE_NAME_2}   /home/ubuntu/mytouch2
  56
  57
  58 *** Test Cases ***
  59 Create Charm VNF Descriptor
  60     [Documentation]   Upload VNF package for the testsuite.
  61     Create VNFD   '%{PACKAGES_FOLDER}/${VNFD_PKG}'
  62
  63 Create Charm NS Descriptor
  64     [Documentation]   Upload NS package for the testsuite.
  65     Create NSD   '%{PACKAGES_FOLDER}/${NSD_PKG}'
  66
  67 Instantiate Charm Network Service
  68     [Documentation]   Instantiate NS for the testsuite.
  69     ${id}=   Create Network Service   ${NSD_NAME}   %{VIM_TARGET}   ${NS_NAME}   ${NS_CONFIG}   ${PUBLICKEY}   ${NS_TIMEOUT}
  70     Set Suite Variable   ${NS_ID}   ${id}
  71
  72 Get Management Ip Addresses
  73     [Documentation]   Get the mgmt IP addresses of both VNF of the NS.
  74     ${ip_addr_1}=   Get Vnf Management Ip Address   ${NS_ID}   ${VNF_MEMBER_INDEX_1}
  75     Log   ${ip_addr_1}
  76     Set Suite Variable   ${VNF_1_IP_ADDR}   ${ip_addr_1}
  77     ${ip_addr_2}=   Get Vnf Management Ip Address   ${NS_ID}   ${VNF_MEMBER_INDEX_2}
  78     Log   ${ip_addr_2}
  79     Set Suite Variable   ${VNF_2_IP_ADDR}   ${ip_addr_2}
  80
  81 Test SSH Access
  82     [Documentation]   Check that both VNF are accessible via SSH in their mgmt IP addresses.
  83     Variable Should Exist   ${VNF_1_IP_ADDR}   msg=IP address of the management VNF '${VNF_MEMBER_INDEX_1}' is not available
  84     Variable Should Exist   ${VNF_2_IP_ADDR}   msg=IP address of the management VNF '${VNF_MEMBER_INDEX_2}' is not available
  85     Sleep   30s   Waiting ssh daemon to be up
  86     Test SSH Connection   ${VNF_1_IP_ADDR}   ${USERNAME}   ${PASSWORD}   ${PRIVATEKEY}
  87     Test SSH Connection   ${VNF_2_IP_ADDR}   ${USERNAME}   ${PASSWORD}   ${PRIVATEKEY}
  88
  89 Check Remote Files Created Via Day 1 Operations
  90     [Documentation]   The Charm VNF has a Day 1 operation that creates a file named ${day_1_file_name}.
  91     ...               This test checks whether that files have been created or not.
  92     Check If Remote File Exists   ${VNF_1_IP_ADDR}   ${USERNAME}   ${PASSWORD}   ${PRIVATEKEY}   ${DAY_1_FILE_NAME}
  93     Check If Remote File Exists   ${VNF_2_IP_ADDR}   ${USERNAME}   ${PASSWORD}   ${PRIVATEKEY}   ${DAY_1_FILE_NAME}
  94
  95 Execute Day 2 Operations
  96     [Documentation]   Performs one Day 2 operation per VNF that creates a new file.
  97     Variable Should Exist   ${NS_ID}   msg=Network service instance is not available
  98     ${ns_op_id_1}=   Execute NS Action   ${NS_NAME}   ${ACTION_NAME}   ${VNF_MEMBER_INDEX_1}   filename=${DAY_2_FILE_NAME_1}
  99     Log   ${ns_op_id_1}
 100     ${ns_op_id_2}=   Execute NS Action   ${NS_NAME}   ${ACTION_NAME}   ${VNF_MEMBER_INDEX_2}   filename=${DAY_2_FILE_NAME_2}
 101     Log   ${ns_op_id_2}
 102
 103 Check Remote Files Created Via Day 2 Operations
 104     [Documentation]   Check whether the files created in the previous test via Day 2 operations exist or not.
 105     Check If Remote File Exists   ${VNF_1_IP_ADDR}   ${USERNAME}   ${PASSWORD}   ${PRIVATEKEY}   ${DAY_2_FILE_NAME_1}
 106     Check If Remote File Exists   ${VNF_2_IP_ADDR}   ${USERNAME}   ${PASSWORD}   ${PRIVATEKEY}   ${DAY_2_FILE_NAME_2}
 107
 108 Delete NS Instance
 109     [Documentation]   Delete NS instance.
 110     [Tags]   cleanup
 111     Delete NS   ${NS_NAME}
 112
 113 Delete NS Descriptor
 114     [Documentation]   Delete NS package from OSM.
 115     [Tags]   cleanup
 116     Delete NSD   ${NSD_NAME}
 117
 118 Delete VNF Descriptor
 119     [Documentation]   Delete VNF package from OSM.
 120     [Tags]   cleanup
 121     Delete VNFD   ${VNFD_NAME}
 122
 123
 124 *** Keywords ***
 125 Suite Cleanup
 126     [Documentation]   Test Suite Cleanup: Deleting descriptors and NS instance
 127     Run Keyword If Any Tests Failed   Delete NS   ${NS_NAME}
 128     Run Keyword If Any Tests Failed   Delete NSD   ${NSD_NAME}
 129     Run Keyword If Any Tests Failed   Delete VNFD   ${VNFD_NAME}