robot-systest/testsuite/hackfest_multivdu.robot

   1 *** Comments ***
   2 #   Licensed under the Apache License, Version 2.0 (the "License");
   3 #   you may not use this file except in compliance with the License.
   4 #   You may obtain a copy of the License at
   5 #
   6 #       http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 #   Unless required by applicable law or agreed to in writing, software
   9 #   distributed under the License is distributed on an "AS IS" BASIS,
  10 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 #   See the License for the specific language governing permissions and
  12 #   limitations under the License.
  13
  14
  15 *** Settings ***
  16 Documentation   [HACKFEST-MULTIVDU] Basic NS with two multi-VDU VNF
  17
  18 Library   OperatingSystem
  19 Library   String
  20 Library   Collections
  21 Library   Process
  22 Library   SSHLibrary
  23
  24 Resource   ../lib/vnfd_lib.resource
  25 Resource   ../lib/nsd_lib.resource
  26 Resource   ../lib/ns_lib.resource
  27 Resource   ../lib/connectivity_lib.resource
  28 Resource   ../lib/ssh_lib.resource
  29
  30 Test Tags   hackfest_multivdu   cluster_main   daily   regression   azure
  31
  32 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  33
  34
  35 *** Variables ***
  36 # NS and VNF descriptor package folder and ids
  37 ${VNFD_PKG}   hackfest_multivdu_vnf
  38 ${VNFD_NAME}   hackfest_multivdu-vnf
  39 ${NSD_PKG}   hackfest_multivdu_ns
  40 ${NSD_NAME}   hackfest_multivdu-ns
  41
  42 # NS instance name and configuration
  43 ${NS_NAME}   hfmultivdu
  44 ${NS_CONFIG}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  45
  46 # SSH keys and username to be used
  47 ${PUBLICKEY}   %{HOME}/.ssh/id_rsa.pub
  48 ${PRIVATEKEY}   %{HOME}/.ssh/id_rsa
  49 ${USERNAME}   ubuntu
  50 ${PASSWORD}   ${EMPTY}
  51
  52 ${NS_ID}   ${EMPTY}
  53 ${VNF_MEMBER_INDEX}   vnf1
  54 ${VNF_IP_ADDR}   ${EMPTY}
  55 ${WAIT_GUARD_FOR_VM_BOOT}   50s
  56
  57
  58 *** Test Cases ***
  59 Create Hackfest multivdu VNF Descriptor
  60     [Documentation]   Upload VNF package for the testsuite.
  61     Create VNFD   '%{PACKAGES_FOLDER}/${VNFD_PKG}'
  62
  63 Create Hackfest Multivdu NS Descriptor
  64     [Documentation]   Upload NS package for the testsuite.
  65     Create NSD   '%{PACKAGES_FOLDER}/${NSD_PKG}'
  66
  67 Network Service Instance Test
  68     [Documentation]   Instantiate NS for the testsuite.
  69     ${status}   ${message}=   Run Keyword And Ignore Error   Variable Should Exist   ${PUBLICKEY}
  70     Log   ${status},${message}
  71     IF   "${status}" == "FAIL"   Set Global Variable   ${PUBLICKEY}   ${EMPTY}
  72     ${id}=   Create Network Service   ${NSD_NAME}   %{VIM_TARGET}   ${NS_NAME}   ${NS_CONFIG}   ${PUBLICKEY}
  73     Set Suite Variable   ${NS_ID}   ${id}
  74     Sleep   ${WAIT_GUARD_FOR_VM_BOOT}   Waiting for VM's daemons to be up and running
  75
  76 Get Vnf Ip Address
  77     [Documentation]   Get the mgmt IP address of the VNF of the NS.
  78     ${ip_addr}=   Get Vnf Management Ip Address   ${NS_ID}   ${VNF_MEMBER_INDEX}
  79     Log   ${ip_addr}
  80     Set Suite Variable   ${VNF_IP_ADDR}   ${ip_addr}
  81
  82 Test Ping
  83     [Documentation]   Test that the mgmt IP address of the VNF is reachable with ping.
  84     Test Connectivity   ${VNF_IP_ADDR}
  85
  86 Test SSH Access
  87     [Documentation]   Check that the VNF is accessible via SSH in its mgmt IP address.
  88     ${status}   ${message}=   Run Keyword And Ignore Error   Variable Should Exist   ${PRIVATEKEY}
  89     Log   ${status},${message}
  90     IF   "${status}" == "FAIL"   Set Global Variable   ${PRIVATEKEY}   ${EMPTY}
  91     Test SSH Connection   ${VNF_IP_ADDR}   ${USERNAME}   ${PASSWORD}   ${PRIVATEKEY}
  92
  93 Delete NS Instance Test
  94     [Documentation]   Delete NS instance.
  95     [Tags]   cleanup
  96     Delete NS   ${NS_NAME}
  97
  98 Delete NS Descriptor Test
  99     [Documentation]   Delete NS package.
 100     [Tags]   cleanup
 101     Delete NSD   ${NSD_NAME}
 102
 103 Delete VNF Descriptor Test
 104     [Documentation]   Delete VNF package.
 105     [Tags]   cleanup
 106     Delete VNFD   ${VNFD_NAME}
 107
 108
 109 *** Keywords ***
 110 Suite Cleanup
 111     [Documentation]   Test Suit Cleanup: Deleting Descriptor, instance and vim
 112     Run Keyword If Any Tests Failed   Delete NS   ${NS_NAME}
 113     Run Keyword If Any Tests Failed   Delete NSD   ${NSD_NAME}
 114     Run Keyword If Any Tests Failed   Delete VNFD   ${VNFD_NAME}