robot-systest/testsuite/hackfest_basic.robot

   1 *** Comments ***
   2 #   Licensed under the Apache License, Version 2.0 (the "License");
   3 #   you may not use this file except in compliance with the License.
   4 #   You may obtain a copy of the License at
   5 #
   6 #       http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 #   Unless required by applicable law or agreed to in writing, software
   9 #   distributed under the License is distributed on an "AS IS" BASIS,
  10 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 #   See the License for the specific language governing permissions and
  12 #   limitations under the License.
  13
  14
  15 *** Settings ***
  16 Documentation   [HACKFEST-BASIC] Basic NS with a single-VDU VNF
  17
  18 Library   OperatingSystem
  19 Library   String
  20 Library   Collections
  21 Library   Process
  22 Library   SSHLibrary
  23
  24 Resource   ../lib/vnfd_lib.resource
  25 Resource   ../lib/nsd_lib.resource
  26 Resource   ../lib/ns_lib.resource
  27 Resource   ../lib/connectivity_lib.resource
  28 Resource   ../lib/ssh_lib.resource
  29
  30 Test Tags   hackfest_basic   cluster_main   daily   regression   sanity   azure
  31
  32 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  33
  34
  35 *** Variables ***
  36 # NS and VNF descriptor package folder and ids
  37 ${VNFD_PKG}   hackfest_basic_vnf
  38 ${VNFD_NAME}   hackfest_basic-vnf
  39 ${NSD_PKG}   hackfest_basic_ns
  40 ${NSD_NAME}   hackfest_basic-ns
  41
  42 # NS instance name and configuration
  43 ${NS_NAME}   hfbasic
  44 ${NS_CONFIG}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  45
  46 # SSH keys and username to be used
  47 ${PUBLICKEY}   %{HOME}/.ssh/id_rsa.pub
  48 ${PRIVATEKEY}   %{HOME}/.ssh/id_rsa
  49 ${USERNAME}   ubuntu
  50 ${PASSWORD}   ${EMPTY}
  51
  52 ${NS_ID}   ${EMPTY}
  53 ${VNF_MEMBER_INDEX}   vnf
  54 ${VNF_IP_ADDR}   ${EMPTY}
  55
  56
  57 *** Test Cases ***
  58 Create Hackfest Basic VNF Descriptor
  59     [Documentation]   Upload VNF package for the testsuite.
  60     Create VNFD   '%{PACKAGES_FOLDER}/${VNFD_PKG}'
  61
  62 Create Hackfest Basic NS Descriptor
  63     [Documentation]   Upload NS package for the testsuite.
  64     Create NSD   '%{PACKAGES_FOLDER}/${NSD_PKG}'
  65
  66 Network Service Instance Test
  67     [Documentation]   Instantiate NS for the testsuite.
  68     ${id}=   Create Network Service   ${NSD_NAME}   %{VIM_TARGET}   ${NS_NAME}   ${NS_CONFIG}   ${PUBLICKEY}
  69     Set Suite Variable   ${NS_ID}   ${id}
  70
  71 Get Vnf Ip Address
  72     [Documentation]   Get the mgmt IP address of the VNF of the NS.
  73     ${ip_addr}=   Get Vnf Management Ip Address   ${NS_ID}   ${VNF_MEMBER_INDEX}
  74     Log   ${ip_addr}
  75     Set Suite Variable   ${VNF_IP_ADDR}   ${ip_addr}
  76
  77 Test Ping
  78     [Documentation]   Test that the mgmt IP address of the VNF is reachable with ping.
  79     Test Connectivity   ${VNF_IP_ADDR}
  80
  81 Test SSH Access
  82     [Documentation]   Check that the VNF is accessible via SSH in its mgmt IP address.
  83     Sleep   30s   Waiting ssh daemon to be up
  84     Test SSH Connection   ${VNF_IP_ADDR}   ${USERNAME}   ${PASSWORD}   ${PRIVATEKEY}
  85
  86 Delete NS Instance Test
  87     [Documentation]   Delete NS instance.
  88     [Tags]   cleanup
  89     Delete NS   ${NS_NAME}
  90
  91 Delete NS Descriptor Test
  92     [Documentation]   Delete NS package from OSM.
  93     [Tags]   cleanup
  94     Delete NSD   ${NSD_NAME}
  95
  96 Delete VNF Descriptor Test
  97     [Documentation]   Delete VNF package from OSM.
  98     [Tags]   cleanup
  99     Delete VNFD   ${VNFD_NAME}
 100
 101
 102 *** Keywords ***
 103 Suite Cleanup
 104     [Documentation]   Test Suit Cleanup: Deleting Descriptor, instance and vim
 105     Run Keyword If Any Tests Failed   Delete NS   ${NS_NAME}
 106     Run Keyword If Any Tests Failed   Delete NSD   ${NSD_NAME}
 107     Run Keyword If Any Tests Failed   Delete VNFD   ${VNFD_NAME}