robot-systest/testsuite/basic_17-delete_vnf_package.robot

   1 *** Comments ***
   2 #   Licensed under the Apache License, Version 2.0 (the "License");
   3 #   you may not use this file except in compliance with the License.
   4 #   You may obtain a copy of the License at
   5 #
   6 #       http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 #   Unless required by applicable law or agreed to in writing, software
   9 #   distributed under the License is distributed on an "AS IS" BASIS,
  10 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 #   See the License for the specific language governing permissions and
  12 #   limitations under the License.
  13
  14
  15 *** Settings ***
  16 Documentation   [BASIC-17] Delete VNF Package Before NS Package.
  17
  18 Library   OperatingSystem
  19 Library   String
  20 Library   Collections
  21 Library   Process
  22 Library   SSHLibrary
  23
  24 Resource   ../lib/vnfd_lib.resource
  25 Resource   ../lib/nsd_lib.resource
  26
  27 Test Tags   basic_17   cluster_main   daily   regression   azure
  28
  29 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  30
  31
  32 *** Variables ***
  33 # NS and VNF descriptor package folder and ids
  34 ${VNFD_PKG}   hackfest_basic_vnf
  35 ${VNFD_NAME}   hackfest_basic-vnf
  36 ${NSD_PKG}   hackfest_basic_ns
  37 ${NSD_NAME}   hackfest_basic-ns
  38
  39
  40 *** Test Cases ***
  41 Create VNF Package
  42     [Documentation]   Upload VNF package for the testsuite.
  43     Create VNFD   '%{PACKAGES_FOLDER}/${VNFD_PKG}'
  44
  45 Create NS Package
  46     [Documentation]   Upload NS package for the testsuite.
  47     Create NSD   '%{PACKAGES_FOLDER}/${NSD_PKG}'
  48
  49 Cannot Delete VNF Package
  50     [Documentation]   Assert that the VNF package cannot be deleted without deleting the corresponding NS package using it.
  51     Assert Failure Delete VNFD   ${VNFD_NAME}
  52
  53 Delete NS Package
  54     [Documentation]   Delete NS package from OSM.
  55     [Tags]   cleanup
  56     Delete NSD   ${NSD_NAME}
  57
  58 Delete VNF Package
  59     [Documentation]   Delete VNF package from OSM.
  60     [Tags]   cleanup
  61     Delete VNFD   ${VNFD_NAME}
  62
  63
  64 *** Keywords ***
  65 Suite Cleanup
  66     [Documentation]   Test Suit Cleanup: Deleting NS and VNF packages
  67     Run Keyword If Any Tests Failed   Delete NSD   ${NSD_NAME}
  68     Run Keyword If Any Tests Failed   Delete VNFD   ${VNFD_NAME}