robot-systest/testsuite/basic_07-secure_key_management.robot

   1 *** Comments ***
   2 #   Licensed under the Apache License, Version 2.0 (the "License");
   3 #   you may not use this file except in compliance with the License.
   4 #   You may obtain a copy of the License at
   5 #
   6 #       http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 #   Unless required by applicable law or agreed to in writing, software
   9 #   distributed under the License is distributed on an "AS IS" BASIS,
  10 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 #   See the License for the specific language governing permissions and
  12 #   limitations under the License.
  13
  14
  15 *** Settings ***
  16 Documentation   [BASIC-07] Secure key management.
  17
  18 Library   OperatingSystem
  19 Library   SSHLibrary
  20
  21 Resource   ../lib/vnfd_lib.resource
  22 Resource   ../lib/nsd_lib.resource
  23 Resource   ../lib/ns_lib.resource
  24 Resource   ../lib/ns_operation_lib.resource
  25 Resource   ../lib/ssh_lib.resource
  26
  27 Test Tags   basic_07   cluster_ee_config   regression   azure
  28
  29 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  30
  31
  32 *** Variables ***
  33 # NS and VNF descriptor package folder and ids
  34 ${VNFD_PKG}   charm-packages/nopasswd_proxy_charm_vnf
  35 ${VNFD_NAME}   nopasswd_proxy_charm-vnf
  36 ${NSD_PKG}   charm-packages/nopasswd_proxy_charm_ns
  37 ${NSD_NAME}   nopasswd_proxy_charm-ns
  38
  39 # NS instance name and configuration
  40 ${NS_NAME}   basic_07_secure_key_management
  41 ${NS_CONFIG}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  42 ${NS_TIMEOUT}   15min
  43
  44 # SSH username and passwod
  45 ${USERNAME}   ubuntu
  46 ${PASSWORD}   osm4u
  47
  48 ${ACTION_NAME}   touch
  49 ${VNF_MEMBER_INDEX}   vnf1
  50 ${DAY_1_FILE_NAME}   /home/ubuntu/first-touch
  51 ${DAY_2_FILE_NAME}   /home/ubuntu/mytouch1
  52
  53
  54 *** Test Cases ***
  55 Create Nopasswd Charm VNF Descriptor
  56     [Documentation]   Upload VNF package for the testsuite.
  57     [Tags]   prepare
  58     Create VNFD   '%{PACKAGES_FOLDER}/${VNFD_PKG}'
  59
  60 Create Nopasswd Charm NS Descriptor
  61     [Documentation]   Upload NS package for the testsuite.
  62     [Tags]   prepare
  63     Create NSD   '%{PACKAGES_FOLDER}/${NSD_PKG}'
  64
  65 Instantiate Nopasswd Charm Network Service
  66     [Documentation]   Instantiate NS for the testsuite.
  67     [Tags]   prepare
  68     ${id}=   Create Network Service   ${NSD_NAME}   %{VIM_TARGET}   ${NS_NAME}   ${NS_CONFIG}   ${EMPTY}   ${NS_TIMEOUT}
  69     Log   ${id}
  70
  71 Get Ns Id
  72     [Documentation]   Get NS instance id.
  73     [Tags]   verify
  74     ${id}=   Get Ns Id   ${NS_NAME}
  75     Set Suite Variable   ${NS_ID}   ${id}
  76
  77 Get Management Ip Addresses
  78     [Documentation]   Get the mgmt IP address of the VNF of the NS.
  79     [Tags]   verify
  80     ${ip_addr}=   Get Vnf Management Ip Address   ${NS_ID}   ${VNF_MEMBER_INDEX}
  81     Log   ${ip_addr}
  82     Set Suite Variable   ${VNF_IP_ADDR}   ${ip_addr}
  83
  84 Test SSH Access
  85     [Documentation]   Check that the VNF is accessible via SSH in its mgmt IP address.
  86     [Tags]   verify
  87     Variable Should Exist   ${VNF_IP_ADDR}   msg=IP address of the management VNF is not available
  88     Sleep   30s   Waiting ssh daemon to be up
  89     Test SSH Connection   ${VNF_IP_ADDR}   ${USERNAME}   ${PASSWORD}   ${EMPTY}
  90
  91 Check Remote Files Created Via Day 1 Operations
  92     [Documentation]   The Nopasswd VNF has a Day 1 operation that creates a file named ${day_1_file_name} and performs it without password.
  93     ...               This test checks whether that files have been created or not.
  94     [Tags]   verify
  95     Check If Remote File Exists   ${VNF_IP_ADDR}   ${USERNAME}   ${PASSWORD}   ${EMPTY}   ${DAY_1_FILE_NAME}
  96
  97 Execute Day 2 Operations
  98     [Documentation]   Performs one Day 2 operation that creates a new file, this action is executed without password too.
  99     [Tags]   verify
 100     Variable Should Exist   ${NS_ID}   msg=Network service instance is not available
 101     ${ns_op_id}=   Execute NS Action   ${NS_NAME}   ${ACTION_NAME}   ${VNF_MEMBER_INDEX}   filename=${DAY_2_FILE_NAME}
 102     Log   ${ns_op_id}
 103
 104 Check Remote Files Created Via Day 2 Operations
 105     [Documentation]   Check whether the file created in the previous test via Day 2 operation exists or not.
 106     [Tags]   verify
 107     Check If Remote File Exists   ${VNF_IP_ADDR}   ${USERNAME}   ${PASSWORD}   ${EMPTY}   ${DAY_2_FILE_NAME}
 108
 109 Delete NS Instance
 110     [Documentation]   Delete NS instance.
 111     [Tags]   cleanup
 112     Delete NS   ${NS_NAME}
 113
 114 Delete NS Descriptor
 115     [Documentation]   Delete NS package from OSM.
 116     [Tags]   cleanup
 117     Delete NSD   ${NSD_NAME}
 118
 119 Delete VNF Descriptor
 120     [Documentation]   Delete VNF package from OSM.
 121     [Tags]   cleanup
 122     Delete VNFD   ${VNFD_NAME}
 123
 124
 125 *** Keywords ***
 126 Suite Cleanup
 127     [Documentation]   Test Suite Cleanup: Deleting descriptors and NS instance
 128     Run Keyword If Any Tests Failed   Delete NS   ${NS_NAME}
 129     Run Keyword If Any Tests Failed   Delete NSD   ${NSD_NAME}
 130     Run Keyword If Any Tests Failed   Delete VNFD   ${VNFD_NAME}