robot-systest/testsuite/basic_07-secure_key_management.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation     [BASIC-07] Secure key management.
  15
  16 Library   OperatingSystem
  17 Library   SSHLibrary
  18
  19 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  20 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  23
  24 Variables   %{ROBOT_DEVOPS_FOLDER}/resources/basic_07-secure_key_management_data.py
  25
  26 Force Tags   basic_07   cluster_ee_config   daily   regression   sanity
  27
  28 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  29
  30
  31 *** Variables ***
  32 ${username}   ubuntu
  33 ${password}   osm4u
  34 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  35 ${action_name}   touch
  36 ${vnf_member_index}   1
  37 ${day_1_file_name}   /home/ubuntu/first-touch
  38 ${day_2_file_name}   /home/ubuntu/mytouch1
  39 ${ns_timeout}   15min
  40
  41
  42 *** Test Cases ***
  43 Create Nopasswd Charm VNF Descriptor
  44     [Tags]   nopasswd   charm   sanity   regression
  45
  46     Create VNFD  '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  47
  48
  49 Create Nopasswd Charm NS Descriptor
  50     [Tags]   nopasswd   charm   sanity   regression
  51
  52     Create NSD  '%{PACKAGES_FOLDER}/${nsd_pkg}'
  53
  54
  55 Instantiate Nopasswd Charm Network Service
  56     [Tags]   nopasswd   charm   sanity   regression
  57
  58     ${id}=  Create Network Service  ${nsd_name}  %{VIM_TARGET}  ${ns_name}  ${ns_config}  ${EMPTY}  ${ns_timeout}
  59     Set Suite Variable  ${ns_id}  ${id}
  60
  61
  62 Get Management Ip Addresses
  63     [Tags]   nopasswd   charm   sanity   regression
  64
  65     ${ip_addr}  Get Vnf Management Ip Address  ${ns_id}  ${vnf_member_index}
  66     log  ${ip_addr}
  67     Set Suite Variable  ${vnf_ip_addr}  ${ip_addr}
  68
  69
  70 Test SSH Access
  71     [Tags]   nopasswd   charm   sanity   regression
  72
  73     Variable Should Exist  ${vnf_ip_addr}  msg=IP address of the management VNF is not available
  74     Sleep  30s  Waiting ssh daemon to be up
  75     Test SSH Connection  ${vnf_ip_addr}  ${username}  ${password}  ${EMPTY}
  76
  77
  78 Check Remote Files Created Via Day 1 Operations
  79     [Documentation]     The Nopasswd VNF has a Day 1 operation that creates a file named ${day_1_file_name} and performs it without password.
  80     ...                 This test checks whether that files have been created or not.
  81     [Tags]   nopasswd   charm   sanity   regression
  82
  83     Check If remote File Exists  ${vnf_ip_addr}  ${username}  ${password}  ${EMPTY}  ${day_1_file_name}
  84
  85
  86 Execute Day 2 Operations
  87     [Documentation]     Performs one Day 2 operation that creates a new file, this action is executed without password too.
  88     [Tags]   nopasswd   charm   sanity   regression
  89
  90     Variable Should Exist  ${ns_id}  msg=Network service instance is not available
  91     ${ns_op_id}=  Execute NS Action  ${ns_name}  ${action_name}  ${vnf_member_index}  filename=${day_2_file_name}
  92
  93
  94 Check Remote Files Created Via Day 2 Operations
  95     [Documentation]     Check whether the file created in the previous test via Day 2 operation exists or not.
  96     [Tags]   nopasswd   charm   sanity   regression
  97
  98     Check If remote File Exists  ${vnf_ip_addr}  ${username}  ${password}  ${EMPTY}  ${day_2_file_name}
  99
 100
 101 Delete NS Instance
 102     [Tags]   nopasswd   charm   sanity   regression  cleanup
 103
 104     Delete NS  ${ns_name}
 105
 106
 107 Delete NS Descriptor
 108     [Tags]   nopasswd   charm   sanity   regression  cleanup
 109
 110     Delete NSD  ${nsd_name}
 111
 112
 113 Delete VNF Descriptor
 114     [Tags]   nopasswd   charm   sanity   regression  cleanup
 115
 116     Delete VNFD  ${vnfd_name}
 117
 118
 119 *** Keywords ***
 120 Suite Cleanup
 121     [Documentation]  Test Suite Cleanup: Deleting descriptors and NS instance
 122
 123     Run Keyword If Any Tests Failed  Delete NS  ${ns_name}
 124
 125     Run Keyword If Any Tests Failed  Delete NSD  ${nsd_name}
 126
 127     Run Keyword If Any Tests Failed  Delete VNFD  ${vnfd_name}
 128