robot-systest/testsuite/basic_07-secure_key_management.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation     [BASIC-07] Secure key management.
  15
  16 Library   OperatingSystem
  17 Library   SSHLibrary
  18
  19 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  20 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  23
  24 Variables   %{ROBOT_DEVOPS_FOLDER}/resources/basic_07-secure_key_management_data.py
  25
  26 Suite Teardown   Run Keyword And Ignore Error   Test Cleanup
  27
  28
  29 *** Variables ***
  30 ${username}   ubuntu
  31 ${password}   osm4u
  32 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  33 ${action_name}   touch
  34 ${vnf_member_index}   1
  35 ${day_1_file_name}   /home/ubuntu/first-touch
  36 ${day_2_file_name}   /home/ubuntu/mytouch1
  37 ${ns_timeout}   15min
  38
  39
  40 *** Test Cases ***
  41 Create Nopasswd Charm VNF Descriptor
  42     [Tags]   nopasswd   sanity   regression
  43
  44     Create VNFD  '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  45
  46
  47 Create Nopasswd Charm NS Descriptor
  48     [Tags]   nopasswd   sanity   regression
  49
  50     Create NSD  '%{PACKAGES_FOLDER}/${nsd_pkg}'
  51
  52
  53 Instantiate Nopasswd Charm Network Service
  54     [Tags]   nopasswd   sanity   regression
  55
  56     ${id}=  Create Network Service  ${nsd_name}  %{VIM_TARGET}  ${ns_name}  ${ns_config}  ${EMPTY}  ${ns_timeout}
  57     Set Suite Variable  ${ns_id}  ${id}
  58
  59
  60 Get Management Ip Addresses
  61     [Tags]   nopasswd   sanity   regression
  62
  63     ${ip_addr}  Get Vnf Management Ip Address  ${ns_id}  ${vnf_member_index}
  64     log  ${ip_addr}
  65     Set Suite Variable  ${vnf_ip_addr}  ${ip_addr}
  66
  67
  68 Test SSH Access
  69     [Tags]   nopasswd   sanity   regression
  70
  71     Variable Should Exist  ${vnf_ip_addr}  msg=IP address of the management VNF is not available
  72     Sleep  30s  Waiting ssh daemon to be up
  73     Test SSH Connection  ${vnf_ip_addr}  ${username}  ${password}  ${EMPTY}
  74
  75
  76 Check Remote Files Created Via Day 1 Operations
  77     [Documentation]     The Nopasswd VNF has a Day 1 operation that creates a file named ${day_1_file_name} and performs it without password.
  78     ...                 This test checks whether that files have been created or not.
  79     [Tags]   nopasswd   sanity   regression
  80
  81     Check If remote File Exists  ${vnf_ip_addr}  ${username}  ${password}  ${EMPTY}  ${day_1_file_name}
  82
  83
  84 Execute Day 2 Operations
  85     [Documentation]     Performs one Day 2 operation that creates a new file, this action is executed without password too.
  86     [Tags]   nopasswd   sanity   regression
  87
  88     Variable Should Exist  ${ns_id}  msg=Network service instance is not available
  89     ${ns_op_id}=  Execute NS Action  ${ns_name}  ${action_name}  ${vnf_member_index}  filename=${day_2_file_name}
  90
  91
  92 Check Remote Files Created Via Day 2 Operations
  93     [Documentation]     Check whether the file created in the previous test via Day 2 operation exists or not.
  94     [Tags]   nopasswd   sanity   regression
  95
  96     Check If remote File Exists  ${vnf_ip_addr}  ${username}  ${password}  ${EMPTY}  ${day_2_file_name}
  97
  98
  99 Delete NS Instance
 100     [Tags]   nopasswd   sanity   regression  cleanup
 101
 102     Delete NS  ${ns_name}
 103
 104
 105 Delete NS Descriptor
 106     [Tags]   nopasswd   sanity   regression  cleanup
 107
 108     Delete NSD  ${nsd_name}
 109
 110
 111 Delete VNF Descriptor
 112     [Tags]   nopasswd   sanity   regression  cleanup
 113
 114     Delete VNFD  ${vnfd_name}
 115
 116
 117 *** Keywords ***
 118 Test Cleanup
 119     [Documentation]  Test Suite Cleanup: Deleting descriptors and NS instance
 120
 121     Run Keyword If Test Failed  Delete NS  ${ns_name}
 122
 123     Run Keyword If Test Failed  Delete NSD  ${nsd_name}
 124
 125     Run Keyword If Test Failed  Delete VNFD  ${vnfd_name}
 126