robot-systest/testsuite/sa_08-vnf_with_vnf_indicators_snmp.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation   [SA-08] VNF with VNF-based indicators through SNMP.
  15
  16 Library   OperatingSystem
  17 Library   String
  18 Library   Collections
  19
  20 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  24 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/prometheus_lib.robot
  25
  26 Force Tags   sa_08   cluster_k8s   daily   regression
  27
  28 Suite Setup   Run Keyword And Ignore Error   Suite Preparation
  29 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  30
  31
  32 *** Variables ***
  33 # NS instantiation parameters
  34 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  35
  36 # NS and VNF descriptor package folder and ids
  37 ${vnfd_pkg}   snmp_ee_vnf
  38 ${vnfd_name}   snmp_ee-vnf
  39 ${nsd_pkg}   snmp_ee_ns
  40 ${nsd_name}   snmp_ee-ns
  41
  42 # NS instance name
  43 ${ns_name}   sa_08-vnf_with_vnf_indicators_snmp_test
  44
  45 # Prometheus polling interval and retries
  46 ${prometheus_poll_retries}   10 times
  47 ${prometheus_poll_timeout}   1 minute
  48
  49 # Prometheus metrics to retrieve
  50 ${metric_1_name}   ifInOctets
  51 ${metric_1_filter}   ifIndex=1
  52 ${metric_2_name}   ifMtu
  53 ${metric_2_filter}   ifIndex=2
  54
  55
  56 *** Test Cases ***
  57 Create VNF Descriptor
  58
  59     Create VNFD   '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  60
  61
  62 Create NS Descriptor
  63
  64     Create NSD   '%{PACKAGES_FOLDER}/${nsd_pkg}'
  65
  66
  67 Instantiate Network Service
  68
  69     ${id}=   Create Network Service   ${nsd_name}   %{VIM_TARGET}   ${ns_name}   ${ns_config}   ${EMPTY}
  70     Set Suite Variable   ${ns_id}   ${id}
  71
  72
  73 Get VNF SNMP Metrics
  74
  75     Variable Should Exist   ${prometheus_host}   msg=Prometheus address is not available
  76     Variable Should Exist   ${prometheus_port}   msg=Prometheus port is not available
  77     Variable Should Exist   ${metric_1_name}   msg=Prometheus first metric name is not available
  78     Variable Should Exist   ${metric_2_name}   msg=Prometheus second metric name is not available
  79     ${metric_1_value}=   Wait Until Keyword Succeeds   ${prometheus_poll_retries}   ${prometheus_poll_timeout}   Get Metric   ${prometheus_host}   ${prometheus_port}   ${prometheus_user}   ${prometheus_password}   ${metric_1_name}   ${metric_1_filter}
  80     Run Keyword If   ${metric_1_value} <= 0   Fail   msg=The metric '${metric_1_name}' value is '${metric_1_value}'
  81     ${metric_2_value}=   Wait Until Keyword Succeeds   ${prometheus_poll_retries}   ${prometheus_poll_timeout}   Get Metric   ${prometheus_host}   ${prometheus_port}   ${prometheus_user}   ${prometheus_password}   ${metric_2_name}   ${metric_2_filter}
  82     Run Keyword If   ${metric_2_value} <= 0   Fail   msg=The metric '${metric_2_name}' value is '${metric_2_value}'
  83
  84
  85 Delete NS Instance
  86     [Tags]   cleanup
  87
  88     Delete NS   ${ns_name}
  89
  90
  91 Delete NS Descriptor
  92     [Tags]   cleanup
  93
  94     Delete NSD   ${nsd_name}
  95
  96
  97 Delete VNF Descriptor
  98     [Tags]   cleanup
  99
 100     Delete VNFD   ${vnfd_name}
 101
 102
 103 *** Keywords ***
 104 Suite Preparation
 105     [Documentation]   Test Suite Preparation: Setting Prometheus Testsuite Variables
 106
 107     Set Testsuite Prometheus Variables
 108
 109
 110 Suite Cleanup
 111     [Documentation]   Test Suite Cleanup: Deleting descriptors and NS instance
 112
 113     Run Keyword If Any Tests Failed   Delete NS   ${ns_name}
 114     Run Keyword If Any Tests Failed   Delete NSD   ${nsd_name}
 115     Run Keyword If Any Tests Failed   Delete VNFD   ${vnfd_name}