robot-systest/testsuite/sa_02-vnf_with_vim_metrics_and_autoscaling.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation   [SA-02] VNF with VIM-based metrics and auto-scaling.
  15
  16 Library   OperatingSystem
  17 Library   String
  18 Library   Collections
  19 Library   SSHLibrary
  20
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  24 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  25 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/prometheus_lib.robot
  26
  27 Variables   %{ROBOT_DEVOPS_FOLDER}/resources/sa_02-vnf_with_vim_metrics_and_autoscaling_data.py
  28
  29 Force Tags   sa_02   cluster_sa   daily   regression   sanity
  30
  31 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  32
  33
  34 *** Variables ***
  35 ${ns_id}   ${EMPTY}
  36 ${username}   ubuntu
  37 ${password}   osm4u
  38 ${vnf_member_index}   vnf
  39 ${vnf_ip_addr}   ${EMPTY}
  40 ${vnf_id}   ${EMPTY}
  41 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  42 ${success_return_code}   0
  43
  44
  45 *** Test Cases ***
  46 Create VNF Descriptor
  47
  48     Create VNFD   '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  49
  50
  51 Get Scale-Out Threshold From VNF
  52
  53     ${rc}   ${stdout}=   Run and Return RC and Output   osm vnfpkg-show ${vnfd_name} --literal | yq '.df[0]."scaling-aspect"[0]."scaling-policy"[0]."scaling-criteria"[0]."scale-out-threshold"' | tr -d \\"
  54     Should Be Equal As Integers   ${rc}   ${success_return_code}   msg=${stdout}   values=False
  55     ${scaleout_threshold}=   Convert To Number   ${stdout}
  56     Set Suite Variable   ${metric_threshold}   ${scaleout_threshold}
  57     log   ${metric_threshold}
  58
  59
  60 Create NS Descriptor
  61
  62     Create NSD   '%{PACKAGES_FOLDER}/${nsd_pkg}'
  63
  64
  65 Instantiate Network Service
  66
  67     ${id}=   Create Network Service   ${nsd_name}   %{VIM_TARGET}   ${ns_name}   ${ns_config}   ${publickey}
  68     Set Suite Variable   ${ns_id}   ${id}
  69
  70
  71 Get VNF Id
  72
  73     @{vnfr_list}=   Get Ns Vnfr Ids   ${ns_id}
  74     Log List   ${vnfr_list}
  75     Set Suite Variable   ${vnf_id}   ${vnfr_list}[0]
  76
  77
  78 Get VNF IP Address
  79
  80     ${ip_addr}=   Get Vnf Management Ip Address   ${ns_id}   ${vnf_member_index}
  81     log   ${ip_addr}
  82     Set Suite Variable   ${vnf_ip_addr}   ${ip_addr}
  83
  84
  85 Get VNF VIM-based Metric Before Auto-scaling
  86
  87     Variable Should Exist   ${prometheus_poll_retries}   msg=Metric polling retries is not available
  88     Variable Should Exist   ${prometheus_poll_timeout}   msg=Metric polling timeout is not available
  89     Variable Should Exist   ${prometheus_host}   msg=Prometheus address is not available
  90     Variable Should Exist   ${prometheus_port}   msg=Prometheus port is not available
  91     Variable Should Exist   ${metric_name}   msg=Prometheus metric name is not available
  92     ${metric_value}=   Wait Until Keyword Succeeds   ${prometheus_poll_retries}   ${prometheus_poll_timeout}   Get Metric   ${prometheus_host}   ${prometheus_port}   ${metric_name}
  93     Run Keyword Unless   ${metric_value} > 0   Fail   msg=The metric '${metric_name}' value is '${metric_value}'
  94     Run Keyword Unless   ${metric_value} < ${metric_threshold}   Fail   msg=The metric '${metric_name}' value is higher than '${metric_threshold}' before scaling
  95
  96
  97 Increase VIM-based Metric To Force Auto-scaling
  98
  99     Variable Should Exist   ${privatekey}   msg=SSH private key not available
 100     Execute Remote Command Check Rc Return Output   ${vnf_ip_addr}   ${username}   ${password}   ${privatekey}   for i in {1..9}; do yes > /dev/null & done
 101
 102
 103 Wait VIM-based Metric To Exceed Threshold
 104
 105     Variable Should Exist   ${prometheus_poll_retries}   msg=Metric polling retries is not available
 106     Variable Should Exist   ${prometheus_poll_timeout}   msg=Metric polling timeout is not available
 107     Wait Until Keyword Succeeds   ${prometheus_poll_retries}   ${prometheus_poll_timeout}   Check VIM-based Metric Exceeds Threshold
 108
 109
 110 Get VDUs After Auto-scaling
 111
 112     Sleep   2 minutes   Wait for auto-scale to take place
 113     @{vdur_list}=   Get Vnf Vdur Names   ${vnf_id}
 114     Log List   ${vdur_list}
 115     ${vdurs}=   Get Length   ${vdur_list}
 116     Run Keyword Unless   ${vdurs} > 1   Fail   msg=There is no new VDU after auto-scaling
 117
 118
 119 Delete NS Instance
 120     [Tags]   cleanup
 121
 122     Delete NS   ${ns_name}
 123
 124
 125 Delete NS Descriptor
 126     [Tags]   cleanup
 127
 128     Delete NSD   ${nsd_name}
 129
 130
 131 Delete VNF Descriptor
 132     [Tags]   cleanup
 133
 134     Delete VNFD   ${vnfd_name}
 135
 136
 137 *** Keywords ***
 138 Suite Cleanup
 139     [Documentation]   Test Suite Cleanup: Deleting descriptors and NS instance
 140
 141     Run Keyword If Any Tests Failed   Delete NS   ${ns_name}
 142     Run Keyword If Any Tests Failed   Delete NSD   ${nsd_name}
 143     Run Keyword If Any Tests Failed   Delete VNFD   ${vnfd_name}
 144
 145
 146 Check VIM-based Metric Exceeds Threshold
 147     [Documentation]   Auxiliar keyword to check if metric exceeds threshold
 148
 149     Variable Should Exist   ${prometheus_host}   msg=Prometheus address is not available
 150     Variable Should Exist   ${prometheus_port}   msg=Prometheus port is not available
 151     Variable Should Exist   ${metric_name}   msg=Prometheus metric name is not available
 152     ${metric_value}=   Get Metric   ${prometheus_host}   ${prometheus_port}   ${metric_name}
 153     Run Keyword Unless   ${metric_value} > ${metric_threshold}   Fail   msg=The metric '${metric_name}' value is '${metric_value}' which is lower than '${metric_threshold}'
 154
 155