robot-systest/testsuite/sa_02-vnf_with_vim_metrics_and_autoscaling.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation   [SA-02] VNF with VIM-based metrics and auto-scaling.
  15
  16 Library   OperatingSystem
  17 Library   String
  18 Library   Collections
  19 Library   SSHLibrary
  20
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  24 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  25 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/prometheus_lib.robot
  26
  27 Variables   %{ROBOT_DEVOPS_FOLDER}/resources/sa_02-vnf_with_vim_metrics_and_autoscaling_data.py
  28
  29 Force Tags   sa_02   cluster_sa   daily   regression   sanity
  30
  31 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  32
  33
  34 *** Variables ***
  35 # NS instantiation parameters
  36 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  37
  38 # NS and VNF descriptor package folder and ids
  39 ${vnfd_pkg}   hackfest_basic_metrics_vnf
  40 ${vnfd_name}   hackfest_basic_metrics-vnf
  41 ${nsd_pkg}   hackfest_basic_metrics_ns
  42 ${nsd_name}   hackfest_basic-ns-metrics
  43
  44 # NS instance name and id
  45 ${ns_id}   ${EMPTY}
  46 ${ns_name}   sa_02
  47
  48 # SSH keys and username to be used
  49 ${publickey}   %{HOME}/.ssh/id_rsa.pub
  50 ${privatekey}   %{HOME}/.ssh/id_rsa
  51 ${username}   ubuntu
  52 ${password}   osm4u
  53
  54 # Prometheus polling interval and retries
  55 ${prometheus_poll_retries}   15 times
  56 ${prometheus_poll_timeout}   1 minute
  57
  58 # Prometheus metrics to retrieve
  59 ${metric_name}   osm_cpu_utilization
  60
  61 # VNF Variables
  62 ${vnf_member_index}   vnf
  63 ${vnf_ip_addr}   ${EMPTY}
  64 ${vnf_id}   ${EMPTY}
  65
  66 ${success_return_code}   0
  67
  68
  69 *** Test Cases ***
  70 Create VNF Descriptor
  71
  72     Create VNFD   '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  73
  74
  75 Get Thresholds From VNF
  76
  77     ${rc}   ${stdout}=   Run and Return RC and Output   osm vnfpkg-show ${vnfd_name} --literal | yq '.df[0]."scaling-aspect"[0]."scaling-policy"[0]."scaling-criteria"[0]."scale-out-threshold"' | tr -d \\"
  78     Should Be Equal As Integers   ${rc}   ${success_return_code}   msg=${stdout}   values=False
  79     ${scaleout_threshold}=   Convert To Number   ${stdout}
  80     Set Suite Variable   ${metric_threshold}   ${scaleout_threshold}
  81     Log   ${metric_threshold}
  82
  83     ${rc}   ${stdout}=   Run and Return RC and Output   osm vnfpkg-show ${vnfd_name} --literal | yq '.df[0]."scaling-aspect"[0]."scaling-policy"[0]."threshold-time"' | tr -d \\"
  84     Should Be Equal As Integers   ${rc}   ${success_return_code}   msg=${stdout}   values=False
  85     ${threshold_time_value}=   Convert To Number   ${stdout}
  86     Set Suite Variable   ${threshold_time}   ${threshold_time_value}
  87     Log   ${threshold_time}
  88
  89
  90 Create NS Descriptor
  91
  92     Create NSD   '%{PACKAGES_FOLDER}/${nsd_pkg}'
  93
  94
  95 Instantiate Network Service
  96
  97     ${id}=   Create Network Service   ${nsd_name}   %{VIM_TARGET}   ${ns_name}   ${ns_config}   ${publickey}
  98     Set Suite Variable   ${ns_id}   ${id}
  99
 100
 101 Get VNF Id
 102
 103     @{vnfr_list}=   Get Ns Vnfr Ids   ${ns_id}
 104     Log List   ${vnfr_list}
 105     Set Suite Variable   ${vnf_id}   ${vnfr_list}[0]
 106
 107
 108 Get VNF IP Address
 109
 110     ${ip_addr}=   Get Vnf Management Ip Address   ${ns_id}   ${vnf_member_index}
 111     Log   ${ip_addr}
 112     Set Suite Variable   ${vnf_ip_addr}   ${ip_addr}
 113
 114
 115 Get VNF VIM-based Metric Before Auto-scaling
 116
 117     Variable Should Exist   ${prometheus_poll_retries}   msg=Metric polling retries is not available
 118     Variable Should Exist   ${prometheus_poll_timeout}   msg=Metric polling timeout is not available
 119     Variable Should Exist   ${prometheus_host}   msg=Prometheus address is not available
 120     Variable Should Exist   ${prometheus_port}   msg=Prometheus port is not available
 121     Variable Should Exist   ${metric_name}   msg=Prometheus metric name is not available
 122     ${metric_filter}=   Set Variable   ns_id=${ns_id}
 123     ${metric_value}=   Wait Until Keyword Succeeds   ${prometheus_poll_retries}   ${prometheus_poll_timeout}   Get Metric   ${prometheus_host}   ${prometheus_port}   ${prometheus_user}   ${prometheus_password}   ${metric_name}   ${metric_filter}
 124     Run Keyword If   ${metric_value} <= 0   Fail   msg=The metric '${metric_name}' value is '${metric_value}'
 125     Run Keyword If   ${metric_value} >= ${metric_threshold}   Fail   msg=The metric '${metric_name}' value is higher than '${metric_threshold}' before scaling
 126
 127
 128 Increase VIM-based Metric To Force Auto-scaling
 129
 130     Variable Should Exist   ${privatekey}   msg=SSH private key not available
 131     Execute Remote Command Check Rc Return Output   ${vnf_ip_addr}   ${username}   ${password}   ${privatekey}   for i in {1..9}; do yes > /dev/null & done
 132
 133
 134 Wait VIM-based Metric To Exceed Threshold
 135
 136     Variable Should Exist   ${prometheus_poll_retries}   msg=Metric polling retries is not available
 137     Variable Should Exist   ${prometheus_poll_timeout}   msg=Metric polling timeout is not available
 138     Wait Until Keyword Succeeds   ${prometheus_poll_retries}   ${prometheus_poll_timeout}   Check VIM-based Metric Exceeds Threshold
 139
 140
 141 Wait Threshold Time
 142
 143     ${threshold_time_sleep}=   Evaluate   ${threshold_time} + 1
 144     Sleep   ${threshold_time_sleep} minutes   Wait scale-out threshold time plus 1 minute
 145
 146
 147 Check VIM-based Metric Exceeds Threshold After Threshold-time
 148
 149     Check VIM-based Metric Exceeds Threshold
 150
 151
 152 Get VDUs After Auto-scaling
 153
 154     Sleep   2 minutes   Wait for auto-scale to take place
 155     @{vdur_list}=   Get Vnf Vdur Names   ${vnf_id}
 156     Log List   ${vdur_list}
 157     ${vdurs}=   Get Length   ${vdur_list}
 158     Run Keyword If   ${vdurs} <= 1   Fail   msg=There is no new VDU after auto-scaling
 159
 160
 161 Delete NS Instance
 162     [Tags]   cleanup
 163
 164     Delete NS   ${ns_name}
 165
 166
 167 Delete NS Descriptor
 168     [Tags]   cleanup
 169
 170     Delete NSD   ${nsd_name}
 171
 172
 173 Delete VNF Descriptor
 174     [Tags]   cleanup
 175
 176     Delete VNFD   ${vnfd_name}
 177
 178
 179 *** Keywords ***
 180 Suite Cleanup
 181     [Documentation]   Test Suite Cleanup: Deleting descriptors and NS instance
 182
 183     Run Keyword If Any Tests Failed   Delete NS   ${ns_name}
 184     Run Keyword If Any Tests Failed   Delete NSD   ${nsd_name}
 185     Run Keyword If Any Tests Failed   Delete VNFD   ${vnfd_name}
 186
 187
 188 Check VIM-based Metric Exceeds Threshold
 189     [Documentation]   Auxiliar keyword to check if metric exceeds threshold
 190
 191     Variable Should Exist   ${prometheus_host}   msg=Prometheus address is not available
 192     Variable Should Exist   ${prometheus_port}   msg=Prometheus port is not available
 193     Variable Should Exist   ${metric_name}   msg=Prometheus metric name is not available
 194     ${metric_filter}=   Set Variable   ns_id=${ns_id}
 195     ${metric_value}=   Get Metric   ${prometheus_host}   ${prometheus_port}   ${prometheus_user}   ${prometheus_password}   ${metric_name}   ${metric_filter}
 196     Run Keyword If   ${metric_value} <= ${metric_threshold}   Fail   msg=The metric '${metric_name}' value is '${metric_value}' which is lower than '${metric_threshold}'
 197