robot-systest/testsuite/sa_02-vnf_with_vim_metrics_and_autoscaling.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation     [SA-02] VNF with VIM-based metrics and auto-scaling.
  15
  16 Library   OperatingSystem
  17 Library   String
  18 Library   Collections
  19 Library   SSHLibrary
  20
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  24 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  25 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/prometheus_lib.robot
  26
  27 Variables   %{ROBOT_DEVOPS_FOLDER}/resources/sa_02-vnf_with_vim_metrics_and_autoscaling_data.py
  28
  29 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  30
  31
  32 *** Variables ***
  33 ${ns_id}   ${EMPTY}
  34 ${username}   ubuntu
  35 ${password}   osm4u
  36 ${vnf_member_index}   1
  37 ${vnf_ip_addr}   ${EMPTY}
  38 ${vnf_id}   ${EMPTY}
  39 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  40
  41
  42 *** Test Cases ***
  43 Create VNF Descriptor
  44     [Tags]   vnf_vim_metrics_autoscaling   sanity   regression
  45
  46     Create VNFD  '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  47
  48
  49 Create NS Descriptor
  50     [Tags]   vnf_vim_metrics_autoscaling   sanity   regression
  51
  52     Create NSD  '%{PACKAGES_FOLDER}/${nsd_pkg}'
  53
  54
  55 Instantiate Network Service
  56     [Tags]   vnf_vim_metrics_autoscaling   sanity   regression
  57
  58     ${id}=  Create Network Service  ${nsd_name}  %{VIM_TARGET}  ${ns_name}  ${ns_config}  ${publickey}
  59     Set Suite Variable  ${ns_id}  ${id}
  60
  61
  62 Get VNF Id
  63     [Tags]   vnf_vim_metrics_autoscaling   sanity   regression
  64
  65     @{vnfr_list}=  Get Ns Vnfr Ids  ${ns_id}
  66     Log List  ${vnfr_list}
  67     Set Suite Variable   ${vnf_id}   ${vnfr_list}[0]
  68
  69
  70 Get VNF IP Address
  71     [Tags]   vnf_vim_metrics_autoscaling   sanity   regression
  72
  73     ${ip_addr}=  Get Vnf Management Ip Address   ${ns_id}   ${vnf_member_index}
  74     log   ${ip_addr}
  75     Set Suite Variable   ${vnf_ip_addr}   ${ip_addr}
  76
  77
  78 Get VNF VIM-based Metric Before Auto-scaling
  79     [Tags]   vnf_vim_metrics_autoscaling   sanity   regression
  80
  81     Variable Should Exist  ${prometheus_poll_retries}  msg=Metric polling retries is not available
  82     Variable Should Exist  ${prometheus_poll_timeout}  msg=Metric polling timeout is not available
  83     Variable Should Exist  ${prometheus_host}  msg=Prometheus address is not available
  84     Variable Should Exist  ${prometheus_port}  msg=Prometheus port is not available
  85     Variable Should Exist  ${metric_name}  msg=Prometheus metric name is not available
  86     ${metric_value}=  Wait Until Keyword Succeeds  ${prometheus_poll_retries}  ${prometheus_poll_timeout}  Get Metric  ${prometheus_host}  ${prometheus_port}  ${metric_name}
  87     Run Keyword Unless  ${metric_value} > 0  Fail  msg=The metric '${metric_name}' value is '${metric_value}'
  88     Run Keyword Unless  ${metric_value} < ${metric_threshold}  Fail  msg=The metric '${metric_name}' value is higher than '${metric_threshold}' before scaling
  89
  90
  91 Increase VIM-based Metric To Force Auto-scaling
  92     [Tags]   vnf_vim_metrics_autoscaling   sanity   regression
  93
  94     Variable Should Exist  ${privatekey}  msg=SSH private key not available
  95     Execute Remote Command Check Rc Return Output   ${vnf_ip_addr}   ${username}   ${password}   ${privatekey}   for i in {1..9}; do yes > /dev/null & done
  96
  97
  98 Wait VIM-based Metric To Exceed Threshold
  99     [Tags]   vnf_vim_metrics_autoscaling   sanity   regression
 100
 101     Variable Should Exist  ${prometheus_poll_retries}  msg=Metric polling retries is not available
 102     Variable Should Exist  ${prometheus_poll_timeout}  msg=Metric polling timeout is not available
 103     Wait Until Keyword Succeeds  ${prometheus_poll_retries}  ${prometheus_poll_timeout}  Check VIM-based Metric Exceeds Threshold
 104
 105
 106 Get VDUs After Auto-scaling
 107     [Tags]   vnf_vim_metrics_autoscaling   sanity   regression
 108
 109     Sleep  1 minute  Wait for auto-scale to take place
 110     @{vdur_list}=  Get Vnf Vdur Names  ${vnf_id}
 111     Log List  ${vdur_list}
 112     ${vdurs}=  Get Length  ${vdur_list}
 113     Run Keyword Unless  ${vdurs} > 1  Fail  msg=There is no new VDU after auto-scaling
 114
 115
 116 Delete NS Instance
 117     [Tags]   vnf_vim_metrics_autoscaling   sanity   regression  cleanup
 118
 119     Delete NS  ${ns_name}
 120
 121
 122 Delete NS Descriptor
 123     [Tags]   vnf_vim_metrics_autoscaling   sanity   regression  cleanup
 124
 125     Delete NSD  ${nsd_name}
 126
 127
 128 Delete VNF Descriptor
 129     [Tags]   vnf_vim_metrics_autoscaling   sanity   regression  cleanup
 130
 131     Delete VNFD  ${vnfd_name}
 132
 133
 134 *** Keywords ***
 135 Suite Cleanup
 136     [Documentation]  Test Suite Cleanup: Deleting descriptors and NS instance
 137
 138     Run Keyword If Any Tests Failed  Delete NS  ${ns_name}
 139     Run Keyword If Any Tests Failed  Delete NSD  ${nsd_name}
 140     Run Keyword If Any Tests Failed  Delete VNFD  ${vnfd_name}
 141
 142
 143 Check VIM-based Metric Exceeds Threshold
 144     [Documentation]  Auxiliar keyword to check if metric exceeds threshold
 145
 146     Variable Should Exist  ${prometheus_host}  msg=Prometheus address is not available
 147     Variable Should Exist  ${prometheus_port}  msg=Prometheus port is not available
 148     Variable Should Exist  ${metric_name}  msg=Prometheus metric name is not available
 149     ${metric_value}=  Get Metric  ${prometheus_host}  ${prometheus_port}  ${metric_name}
 150     Run Keyword Unless  ${metric_value} > ${metric_threshold}  Fail  msg=The metric '${metric_name}' value is '${metric_value}' which is lower than '${metric_threshold}'
 151
 152