robot-systest/testsuite/sa_01-vnf_with_vim_metrics.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation     [SA-01] VNF with VIM-based metrics.
  15
  16 Library   OperatingSystem
  17 Library   String
  18 Library   Collections
  19
  20 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  24 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/prometheus_lib.robot
  25
  26 Variables   %{ROBOT_DEVOPS_FOLDER}/resources/sa_01-vnf_with_vim_metrics_data.py
  27
  28 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  29
  30
  31 *** Variables ***
  32 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  33
  34
  35 *** Test Cases ***
  36 Create VNF Descriptor
  37     [Tags]   vnf_vim_metrics   sanity   regression
  38
  39     Create VNFD  '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  40
  41
  42 Create NS Descriptor
  43     [Tags]   vnf_vim_metrics   sanity   regression
  44
  45     Create NSD  '%{PACKAGES_FOLDER}/${nsd_pkg}'
  46
  47
  48 Instantiate Network Service
  49     [Tags]   vnf_vim_metrics   sanity   regression
  50
  51     ${id}=  Create Network Service  ${nsd_name}  %{VIM_TARGET}  ${ns_name}  ${ns_config}  ${publickey}
  52     Set Suite Variable  ${ns_id}  ${id}
  53
  54
  55 Get VNF VIM-based Metrics
  56     [Tags]   vnf_vim_metrics   sanity   regression
  57
  58     Variable Should Exist  ${prometheus_poll_retries}  msg=Metric polling retries is not available
  59     Variable Should Exist  ${prometheus_poll_timeout}  msg=Metric polling timeout is not available
  60     Variable Should Exist  ${prometheus_host}  msg=Prometheus address is not available
  61     Variable Should Exist  ${prometheus_port}  msg=Prometheus port is not available
  62     Variable Should Exist  ${metric_1_name}  msg=Prometheus first metric name is not available
  63     Variable Should Exist  ${metric_2_name}  msg=Prometheus second metric name is not available
  64     ${metric_1_value}=  Wait Until Keyword Succeeds  ${prometheus_poll_retries}  ${prometheus_poll_timeout}  Get Metric  ${prometheus_host}  ${prometheus_port}  ${metric_1_name}
  65     Run Keyword Unless  ${metric_1_value} > 0  Fail  msg=The metric '${metric_1_name}' value is '${metric_1_value}'
  66     ${metric_2_value}=  Wait Until Keyword Succeeds  ${prometheus_poll_retries}  ${prometheus_poll_timeout}  Get Metric  ${prometheus_host}  ${prometheus_port}  ${metric_2_name}
  67     Run Keyword Unless  ${metric_2_value} > 0  Fail  msg=The metric '${metric_2_name}' value is '${metric_2_value}'
  68
  69
  70 Delete NS Instance
  71     [Tags]   vnf_vim_metrics   sanity   regression  cleanup
  72
  73     Delete NS  ${ns_name}
  74
  75
  76 Delete NS Descriptor
  77     [Tags]   vnf_vim_metrics   sanity   regression  cleanup
  78
  79     Delete NSD  ${nsd_name}
  80
  81
  82 Delete VNF Descriptor
  83     [Tags]   vnf_vim_metrics   sanity   regression  cleanup
  84
  85     Delete VNFD  ${vnfd_name}
  86
  87
  88 *** Keywords ***
  89 Suite Cleanup
  90     [Documentation]  Test Suite Cleanup: Deleting descriptors and NS instance
  91
  92     Run Keyword If Any Tests Failed  Delete NS  ${ns_name}
  93
  94     Run Keyword If Any Tests Failed  Delete NSD  ${nsd_name}
  95
  96     Run Keyword If Any Tests Failed  Delete VNFD  ${vnfd_name}
  97
  98