robot-systest/testsuite/k8s_07-dummy_helm.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation   [K8s-07] Openldap Helm in isolated cluster with dummy VIM.
  15
  16 Library   OperatingSystem
  17 Library   String
  18 Library   Collections
  19 Library   Process
  20
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vim_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  24 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  25 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/connectivity_lib.robot
  26 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  27 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/k8scluster_lib.robot
  28
  29 Force Tags   k8s_07   cluster_k8s   daily   regression
  30
  31 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  32
  33
  34 *** Variables ***
  35 # VIM Configuration
  36 ${vim_name}   k8s07_dummy
  37 ${vim_user}   user
  38 ${vim_password}   pass
  39 ${vim_auth_url}   http://localhost/dummy
  40 ${vim_tenant}   tenant
  41 ${vim_account_type}   dummy
  42
  43 # K8s cluster data
  44 ${k8scluster_name}   k8s07
  45 ${k8scluster_version}   v1
  46 ${k8scluster_net}   null
  47
  48 # NS and VNF descriptor package files
  49 ${vnfd_pkg}   openldap_knf
  50 ${nsd_pkg}   openldap_ns
  51 ${vnfd_name}   openldap_knf
  52 ${nsd_name}   openldap_ns
  53
  54 # NS instance name
  55 ${ns_name}   ldap
  56
  57 ${ns_id}   ${EMPTY}
  58 ${ns_config}   ${EMPTY}
  59 ${publickey}   ${EMPTY}
  60
  61
  62 *** Test Cases ***
  63 Create Package For OpenLDAP CNF
  64     Create VNFD   '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  65
  66 Create Package For OpenLDAP NS
  67     Create NSD   '%{PACKAGES_FOLDER}/${nsd_pkg}'
  68
  69 Create Dummy VIM
  70     ${created_vim_account_id}=   Create VIM Target   ${vim_name}   ${vim_user}   ${vim_password}   ${vim_auth_url}   ${vim_tenant}   ${vim_account_type}
  71
  72 Add K8s Cluster To OSM
  73     Create K8s Cluster   %{K8S_CREDENTIALS}   ${k8scluster_version}   ${vim_name}   ${k8scluster_net}   ${k8scluster_name}
  74
  75 Create Network Service Instance
  76     ${id}=   Create Network Service   ${nsd_name}   ${vim_name}   ${ns_name}   ${ns_config}   ${publickey}
  77     Set Suite Variable   ${ns_id}   ${id}
  78
  79 Delete Network Service Instance
  80     [Tags]   cleanup
  81     Delete NS   ${ns_name}
  82
  83 Remove K8s Cluster from OSM
  84     [Tags]   cleanup
  85     Delete K8s Cluster   ${k8scluster_name}
  86
  87 Delete VIM
  88     [Tags]   cleanup
  89     Delete VIM Target   ${vim_name}
  90
  91 Delete NS Descriptor Test
  92     [Tags]   cleanup
  93     Delete NSD   ${nsd_name}
  94
  95 Delete VNF Descriptor Test
  96     [Tags]   cleanup
  97     Delete VNFD   ${vnfd_name}
  98
  99
 100 *** Keywords ***
 101 Suite Cleanup
 102     [Documentation]   Test Suit Cleanup: Deleting Descriptor, instance, cluster and vim
 103     Run Keyword If Any Tests Failed   Delete NS   ${ns_name}
 104     Run Keyword If Any Tests Failed   Delete NSD   ${nsd_name}
 105     Run Keyword If Any Tests Failed   Delete VNFD   ${vnfd_name}
 106     Run Keyword If Any Tests Failed   Delete K8s Cluster   ${k8scluster_name}
 107     Run Keyword If Any Tests Failed   Delete VIM Target   ${vim_name}