robot-systest/testsuite/heal_02-scale_vdu_healing.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation   [HEAL-02] Healing of scaled charm VDUs
  15
  16 Library   OperatingSystem
  17 Library   String
  18 Library   Collections
  19 Library   Process
  20 Library   SSHLibrary
  21
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnf_lib.robot
  24 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  25 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  26 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  27 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/openstack_lib.robot
  28
  29 Force Tags   heal_02   cluster_heal   daily
  30
  31
  32 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  33
  34
  35 *** Variables ***
  36 # NS and VNF descriptor package folder and ids
  37 ${vnfd_volumes_pkg}   several_volumes_vnf
  38 ${vnfd_volumes_name}   several_volumes-vnf
  39 ${vdu_volumes_name}   several_volumes-VM
  40 ${vnf_several_index}   several_volumes_vnf
  41 ${vnfd_charm_pkg}   charm-packages/native_manual_scale_charm_vnf
  42 ${vnfd_charm_name}   native_manual_scale_charm-vnf
  43 ${vdu_charm_name}   mgmtVM
  44 ${vnf_charm_index}   charm_vnf
  45 ${vnf_charm_scaling_group}   manual-scaling_mgmtVM
  46 ${vnf_charm_cloudinit_file}   /root/helloworld.txt
  47 ${vnf_charm_day1_file}   /home/ubuntu/first-touch
  48 ${nsd_pkg}   volumes_nativecharm_ns
  49 ${nsd_name}   volumes_nativecharm-ns
  50
  51 # NS instance name and configuration
  52 ${ns_name}   heal_02
  53 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  54 ${scale_wait_time}   4min
  55
  56 # SSH keys and username to be used
  57 ${publickey}   %{HOME}/.ssh/id_rsa.pub
  58 ${privatekey}   %{HOME}/.ssh/id_rsa
  59 ${username}   ubuntu
  60 ${password}   ${EMPTY}
  61
  62 ${success_return_code}   0
  63
  64 @{vim_vdus}   @{EMPTY}
  65 @{vim_volumes}   @{EMPTY}
  66
  67
  68 *** Test Cases ***
  69 Create VNF Descriptors
  70     Create VNFD   '%{PACKAGES_FOLDER}/${vnfd_charm_pkg}'
  71     Create VNFD   '%{PACKAGES_FOLDER}/${vnfd_volumes_pkg}'
  72
  73
  74 Create NS Descriptor
  75     Create NSD   '%{PACKAGES_FOLDER}/${nsd_pkg}'
  76
  77
  78 Network Service Instance Test
  79     ${id}=   Create Network Service   ${nsd_name}   %{VIM_TARGET}   ${ns_name}   ${ns_config}   ${publickey}
  80     Set Suite Variable   ${ns_id}   ${id}
  81
  82
  83 Get NS Id
  84     [Tags]   cleanup
  85     ${variables}   Get Variables
  86     IF   not "\${ns_id}" in "${variables}"
  87         ${id}=   Get Ns Id   ${ns_name}
  88         Set Suite Variable   ${ns_id}   ${id}
  89     END
  90
  91
  92 Scale Out Charm VNF
  93     ${vnf_id}=   Get Vnf Id   ${ns_id}   ${vnf_charm_index}
  94     Set Suite Variable   ${vnf_charm_id}   ${vnf_id}
  95     @{vdur_list}=   Get Vnf Vdur Names   ${vnf_charm_id}
  96     ${vdurs}=   Get Length   ${vdur_list}
  97     Set Suite Variable   ${initial_vdur_count}   ${vdurs}
  98     Execute Manual VNF Scale   ${ns_name}   ${vnf_charm_index}   ${vnf_charm_scaling_group}   SCALE_OUT   ${scale_wait_time}
  99     @{vdur_list}=   Get Vnf Vdur Names   ${vnf_charm_id}
 100     ${vdurs}=   Get Length   ${vdur_list}
 101     Run Keyword If   ${vdurs} != ${initial_vdur_count} + 1   Fail   msg=There is no new VDU records in the VNF after Scale Out
 102
 103
 104 Get VIM Objects
 105     Variable Should Exist   ${ns_id}   msg=NS is not available
 106     @{vnf_id_list}=   Get Ns Vnf List   ${ns_id}
 107     log   ${vnf_id_list}
 108     FOR   ${vnf_id}   IN   @{vnf_id_list}
 109         log   ${vnf_id}
 110         ${id}=   Get VNF VIM ID   ${vnf_id}
 111         @{vdu_ids}=   Split String   ${id}
 112         Append To List   ${vim_vdus}   @{vdu_ids}
 113     END
 114     FOR   ${vdu_id}   IN   @{vim_vdus}
 115         ${volumes_attached}=   Get Server Property   ${vdu_id}   volumes_attached
 116         ${match}=   Get Regexp Matches   ${volumes_attached}   '([0-9a-f\-]+)'   1
 117         IF   ${match} != @{EMPTY}
 118             IF   not "${match}[0]" in "@{vim_volumes}"
 119                 Append To List   ${vim_volumes}   ${match}[0]
 120             END
 121         END
 122     END
 123     log Many   @{vim_vdus}
 124     log Many   @{vim_volumes}
 125
 126
 127 Get Charm VNF Info
 128     Variable Should Exist   ${ns_id}   msg=NS is not available
 129     ${variables}   Get Variables
 130     IF   not "\${vnf_charm_id}" in "${variables}"
 131         ${vnf_id}=   Get Vnf Id   ${ns_id}   ${vnf_charm_index}
 132         Set Suite Variable   ${vnf_charm_id}   ${vnf_id}
 133     END
 134     ${id}=   Get VNF VIM ID   ${vnf_charm_id}
 135     @{vdu_charm_ids}=   Split String   ${id}
 136     Set Suite Variable   @{vdu_charm_ids}   @{vdu_charm_ids}
 137     log   ${vdu_charm_ids}[1]
 138     @{charm_ip_list}=   Get Vnf Vdur IPs   ${vnf_charm_id}
 139     Set Suite Variable   @{charm_ip_list}   @{charm_ip_list}
 140
 141
 142 Halt Charm VDU
 143     Variable Should Exist   @{vdu_charm_ids}   msg=VDU is not available
 144     Halt Server   ${vdu_charm_ids}[1]
 145     Sleep   15
 146
 147
 148 Heal Charm VDU
 149     Variable Should Exist   ${vnf_charm_id}   msg=VNF is not available
 150     Heal Network Service   ${ns_id}   --vnf ${vnf_charm_id} --cause "Heal VM of charm_vnf" --vdu ${vdu_charm_name} --count-index 1 --run-day1
 151
 152
 153 Check VNF After Healing
 154     Variable Should Exist   ${vnf_charm_id}   msg=VNF is not available
 155
 156     @{ip_list}=   Get Vnf Vdur IPs   ${vnf_charm_id}
 157     Should Be Equal   ${ip_list}   ${charm_ip_list}   IP addresses have changed after healing
 158
 159     ${id}=   Get VNF VIM ID   ${vnf_charm_id}
 160     @{ids}=   Split String   ${id}
 161     Should Be Equal   ${vdu_charm_ids}[0]   ${ids}[0]   VDU[0] id has changed after healing
 162     Should Not Be Equal   ${vdu_charm_ids}[1]   ${ids}[1]   VDU[1] id has not changed after healing
 163     Should Be Equal   ${vdu_charm_ids}[2]   ${ids}[2]   VDU[2] id has changed after healing
 164
 165     ${ip}=   Get Vdu Attribute   ${vnf_charm_id}   ip-address   1
 166     ${stdout}=   Execute Remote Command Check Rc Return Output   ${ip}   ${username}   ${password}   ${privatekey}   sudo ls ${vnf_charm_cloudinit_file}
 167     log   ${stdout}
 168     Check If remote File Exists   ${ip}   ${username}   ${password}   ${privatekey}   ${vnf_charm_day1_file}
 169
 170
 171 Update VIM Objects
 172     Variable Should Exist   ${ns_id}   msg=NS is not available
 173     @{vdu_updated}=   Create List
 174     @{vnf_id_list}=   Get Ns Vnf List   ${ns_id}
 175     FOR   ${vnf_id}   IN   @{vnf_id_list}
 176         ${id}=   Get VNF VIM ID   ${vnf_id}
 177         @{vdu_ids}=   Split String   ${id}
 178         Append To List   ${vdu_updated}   @{vdu_ids}
 179         FOR   ${id}   IN   @{vdu_ids}
 180             IF   not "${id}" in "@{vim_vdus}"
 181                 Append To List   ${vim_vdus}   ${id}
 182             END
 183         END
 184     END
 185     FOR   ${vdu_id}   IN   @{vdu_updated}
 186         ${volumes_attached}=   Get Server Property   ${vdu_id}   volumes_attached
 187         ${match}=   Get Regexp Matches   ${volumes_attached}   '([0-9a-f\-]+)'   1
 188         IF   ${match} != @{EMPTY}
 189             IF   not "${match}[0]" in "@{vim_volumes}"
 190                 Append To List   ${vim_volumes}   ${match}[0]
 191             END
 192         END
 193     END
 194     log Many   @{vim_vdus}
 195     log Many   @{vim_volumes}
 196
 197
 198 Delete NS Instance
 199     [Tags]   cleanup
 200     Delete NS   ${ns_name}
 201
 202
 203 Delete NS Descriptor
 204     [Tags]   cleanup
 205     Delete NSD   ${nsd_name}
 206
 207
 208 Delete VNF Descriptors
 209     [Tags]   cleanup
 210     Delete VNFD   ${vnfd_volumes_name}
 211     Delete VNFD   ${vnfd_charm_name}
 212
 213
 214 Delete Objects in VIM
 215     [Tags]   cleanup
 216     ${error}=   Set Variable   0
 217     FOR   ${vol_id}   IN   @{vim_volumes}
 218         log   Checking if volume ${vol_id} is still in VIM
 219         ${exists}=   Check If Volume Exists   ${vol_id}
 220         IF   ${exists}!=0
 221             ${error}=   Set Variable   1
 222             log   Deleting volume ${vol_id}
 223             Run Keyword And Ignore Error   Delete Volume   ${vol_id}
 224         END
 225     END
 226     FOR   ${vdu_id}   IN   @{vim_vdus}
 227         log   Checking if server ${vdu_id} is still in VIM
 228         ${status}=   Run Keyword And Ignore Error   Get Server Property   ${vdu_id}   id
 229         log   ${status}[0]
 230         IF   '${status}[0]' == 'PASS'
 231             ${error}=   Set Variable   1
 232             log   Deleting server ${vdu_id}
 233             Run Keyword And Ignore Error   Delete Server   ${vdu_id}
 234         END
 235     END
 236     IF   ${error}==1
 237         Fail   Some objects created by test were not deleted in VIM
 238     END
 239
 240
 241 *** Keywords ***
 242 Suite Cleanup
 243     [Documentation]   Test Suit Cleanup: Deleting Descriptor, instance and vim
 244
 245     Run Keyword If Any Tests Failed   Delete NS   ${ns_name}
 246     Run Keyword If Any Tests Failed   Delete NSD   ${nsd_name}
 247     Run Keyword If Any Tests Failed   Delete VNFD   ${vnfd_volumes_name}
 248     Run Keyword If Any Tests Failed   Delete VNFD   ${vnfd_charm_name}
 249     Run Keyword If Any Tests Failed   Delete Objects in VIM