robot-systest/testsuite/hackfest_multivdu.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation     [HACKFEST-MULTIVDU] Basic NS with two multi-VDU VNF
  15
  16 Library   OperatingSystem
  17 Library   String
  18 Library   Collections
  19 Library   Process
  20 Library   SSHLibrary
  21
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  24 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  25 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/connectivity_lib.robot
  26 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  27
  28 Variables   %{ROBOT_DEVOPS_FOLDER}/resources/hackfest_multivdu_ns_data.py
  29
  30 Force Tags   hackfest_multivdu   cluster_main   daily   regression
  31
  32 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  33
  34
  35 *** Variables ***
  36 ${ns_id}   ${EMPTY}
  37 ${username}   ubuntu
  38 ${password}   ${EMPTY}
  39 ${vnf_member_index}   1
  40 ${vnf_ip_addr}   ${EMPTY}
  41 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  42 ${wait_guard_for_vm_boot}   50s
  43 # ${ns_config}   ${EMPTY}
  44
  45 *** Test Cases ***
  46 Create Hackfest multivdu VNF Descriptor
  47
  48     Create VNFD   '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  49
  50
  51 Create Hackfest Multivdu NS Descriptor
  52
  53     Create NSD   '%{PACKAGES_FOLDER}/${nsd_pkg}'
  54
  55 Network Service Instance Test
  56
  57     ${status}   ${message}=   Run Keyword And Ignore Error  Variable Should Exist   ${publickey}
  58         Run Keyword If   "${status}" == "FAIL"   Set Global Variable   ${publickey}   ${EMPTY}
  59     ${id}=   Create Network Service   ${nsd_name}   %{VIM_TARGET}   ${ns_name}   ${ns_config}   ${publickey}
  60     Set Suite Variable   ${ns_id}   ${id}
  61     Sleep   ${wait_guard_for_vm_boot}  Waiting for VM's daemons to be up and running
  62
  63 Get Vnf Ip Address
  64
  65     ${ip_addr}  Get Vnf Management Ip Address   ${ns_id}   ${vnf_member_index}
  66     log   ${ip_addr}
  67     Set Suite Variable   ${vnf_ip_addr}   ${ip_addr}
  68
  69 Test Ping
  70     Test Connectivity   ${vnf_ip_addr}
  71
  72 Test SSH Access
  73     ${status}   ${message}=   Run Keyword And Ignore Error  Variable Should Exist   ${privatekey}
  74         Run Keyword If   "${status}" == "FAIL"   Set Global Variable   ${privatekey}   ${EMPTY}
  75     Test SSH Connection   ${vnf_ip_addr}  ${username}  ${password}  ${privatekey}
  76
  77 Delete NS Instance Test
  78     [Tags]   cleanup
  79
  80     Delete NS   ${ns_name}
  81
  82
  83 Delete NS Descriptor Test
  84     [Tags]   cleanup
  85
  86     Delete NSD   ${nsd_name}
  87
  88
  89 Delete VNF Descriptor Test
  90     [Tags]   cleanup
  91
  92     Delete VNFD   ${vnfd_name}
  93
  94
  95 *** Keywords ***
  96 Suite Cleanup
  97     [Documentation]  Test Suit Cleanup: Deleting Descriptor, instance and vim
  98
  99     Run Keyword If Any Tests Failed  Delete NS   ${ns_name}
 100
 101     Run Keyword If Any Tests Failed  Delete NSD   ${nsd_name}
 102
 103     Run Keyword If Any Tests Failed  Delete VNFD   ${vnfd_name}