robot-systest/testsuite/hackfest_multivdu.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation     [HACKFEST-MULTIVDU] Basic NS with two multi-VDU VNF
  15
  16 Library   OperatingSystem
  17 Library   String
  18 Library   Collections
  19 Library   Process
  20 Library   SSHLibrary
  21
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  24 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  25 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/connectivity_lib.robot
  26 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  27
  28 Force Tags   hackfest_multivdu   cluster_main   daily   regression
  29
  30 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  31
  32
  33 *** Variables ***
  34 # NS and VNF descriptor package folder and ids
  35 ${vnfd_pkg}   hackfest_multivdu_vnf
  36 ${vnfd_name}   hackfest_multivdu-vnf
  37 ${nsd_pkg}   hackfest_multivdu_ns
  38 ${nsd_name}   hackfest_multivdu-ns
  39
  40 # NS instance name and configuration
  41 ${ns_name}   hfmultivdu
  42 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  43
  44 # SSH keys and username to be used
  45 ${publickey}   %{HOME}/.ssh/id_rsa.pub
  46 ${privatekey}   %{HOME}/.ssh/id_rsa
  47 ${username}   ubuntu
  48 ${password}   ${EMPTY}
  49
  50 ${ns_id}   ${EMPTY}
  51 ${vnf_member_index}   vnf1
  52 ${vnf_ip_addr}   ${EMPTY}
  53 ${wait_guard_for_vm_boot}   50s
  54
  55
  56 *** Test Cases ***
  57 Create Hackfest multivdu VNF Descriptor
  58
  59     Create VNFD   '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  60
  61
  62 Create Hackfest Multivdu NS Descriptor
  63
  64     Create NSD   '%{PACKAGES_FOLDER}/${nsd_pkg}'
  65
  66 Network Service Instance Test
  67
  68     ${status}   ${message}=   Run Keyword And Ignore Error  Variable Should Exist   ${publickey}
  69         Run Keyword If   "${status}" == "FAIL"   Set Global Variable   ${publickey}   ${EMPTY}
  70     ${id}=   Create Network Service   ${nsd_name}   %{VIM_TARGET}   ${ns_name}   ${ns_config}   ${publickey}
  71     Set Suite Variable   ${ns_id}   ${id}
  72     Sleep   ${wait_guard_for_vm_boot}  Waiting for VM's daemons to be up and running
  73
  74 Get Vnf Ip Address
  75
  76     ${ip_addr}  Get Vnf Management Ip Address   ${ns_id}   ${vnf_member_index}
  77     log   ${ip_addr}
  78     Set Suite Variable   ${vnf_ip_addr}   ${ip_addr}
  79
  80 Test Ping
  81     Test Connectivity   ${vnf_ip_addr}
  82
  83 Test SSH Access
  84     ${status}   ${message}=   Run Keyword And Ignore Error  Variable Should Exist   ${privatekey}
  85         Run Keyword If   "${status}" == "FAIL"   Set Global Variable   ${privatekey}   ${EMPTY}
  86     Test SSH Connection   ${vnf_ip_addr}  ${username}  ${password}  ${privatekey}
  87
  88 Delete NS Instance Test
  89     [Tags]   cleanup
  90
  91     Delete NS   ${ns_name}
  92
  93
  94 Delete NS Descriptor Test
  95     [Tags]   cleanup
  96
  97     Delete NSD   ${nsd_name}
  98
  99
 100 Delete VNF Descriptor Test
 101     [Tags]   cleanup
 102
 103     Delete VNFD   ${vnfd_name}
 104
 105
 106 *** Keywords ***
 107 Suite Cleanup
 108     [Documentation]  Test Suit Cleanup: Deleting Descriptor, instance and vim
 109
 110     Run Keyword If Any Tests Failed  Delete NS   ${ns_name}
 111
 112     Run Keyword If Any Tests Failed  Delete NSD   ${nsd_name}
 113
 114     Run Keyword If Any Tests Failed  Delete VNFD   ${vnfd_name}