robot-systest/testsuite/epa_05-epa_underlay_passthrough.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation     [EPA-05] EPA underlay PASSTHROUGH.
  15
  16 Library   OperatingSystem
  17 Library   String
  18 Library   Collections
  19 Library   SSHLibrary
  20
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnf_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  24 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  25 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  26 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/openstack_lib.robot
  27
  28 Variables   %{ROBOT_DEVOPS_FOLDER}/resources/epa_05-epa_underlay_passthrough.py
  29
  30 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  31
  32 *** Variables ***
  33 ${vnf_member_index_1}   1
  34 ${vnf_member_index_2}   2
  35 ${username}   ubuntu
  36 ${password}   osm4u
  37 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} , {name: datanet, ip-profile: {ip-version: ipv4, subnet-address: "${datanet_subnet}"}, vnfd-connection-point-ref: [ {member-vnf-index-ref: "1", vnfd-connection-point-ref: vnf-data-ext, ip-address: "${datanet_ip1}"}, {member-vnf-index-ref: "2", vnfd-connection-point-ref: vnf-data-ext, ip-address: "${datanet_ip2}"}]} ] }
  38 ${success_return_code}   0
  39
  40
  41 *** Test Cases ***
  42 Create VNF Descriptor
  43     [Tags]   epa_underlay_passthrough   sanity   regression
  44
  45     Remove Environment Variable  OVERRIDES
  46     Create VNFD  '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  47
  48
  49 Create NS Descriptor
  50     [Tags]   epa_underlay_passthrough   sanity   regression
  51
  52     Create NSD  '%{PACKAGES_FOLDER}/${nsd_pkg}'
  53
  54
  55 Instantiate Network Service
  56     [Tags]   epa_underlay_passthrough   sanity   regression
  57
  58     ${id}=  Create Network Service  ${nsd_name}  %{VIM_TARGET}  ${ns_name}  ${ns_config}  ${publickey}
  59     Set Suite Variable  ${ns_id}  ${id}
  60
  61
  62 Get Management Ip Addresses
  63     [Tags]   epa_underlay_passthrough   sanity   regression
  64
  65     Variable Should Exist  ${ns_id}  msg=Network service instance is not available
  66     ${ip}  Get Vnf Management Ip Address  ${ns_id}  ${vnf_member_index_1}
  67     Set Suite Variable  ${ip_mgmt_1}  ${ip}
  68     log  ${ip_mgmt_1}
  69
  70     ${ip}  Get Vnf Management Ip Address  ${ns_id}  ${vnf_member_index_2}
  71     Set Suite Variable  ${ip_mgmt_2}  ${ip}
  72     log  ${ip_mgmt_2}
  73
  74
  75 Ping from Vnf1 to Vnf2
  76     [Tags]   epa_underlay_passthrough   sanity   regression
  77
  78     Variable Should Exist  ${ip_mgmt_1}  msg=IP address of the data VNF '${vnf_member_index_1}' is not available
  79     Variable Should Exist  ${privatekey}  msg=SSH private key not available
  80     Sleep   30 seconds   Wait for SSH daemon to be up
  81     ${stdout}=   Execute Remote Command Check Rc Return Output   ${ip_mgmt_1}   ${username}   ${password}   ${privatekey}   ip addr ; ping -c 5 ${datanet_ip2}
  82     log  ${stdout}
  83
  84
  85 Ping from Vnf2 to Vnf1
  86     [Tags]   epa_underlay_passthrough   sanity   regression
  87
  88     Variable Should Exist  ${ip_mgmt_2}  msg=IP address of the data VNF '${vnf_member_index_2}' is not available
  89     Variable Should Exist  ${privatekey}  msg=SSH private key not available
  90     ${stdout}=   Execute Remote Command Check Rc Return Output   ${ip_mgmt_2}   ${username}   ${password}   ${privatekey}   ip addr ; ping -c 5 ${datanet_ip1}
  91     log  ${stdout}
  92
  93
  94 Delete NS Instance
  95     [Tags]   epa_underlay_passthrough   sanity   regression  cleanup
  96
  97     Delete NS  ${ns_name}
  98
  99
 100 Delete NS Descriptor
 101     [Tags]   epa_underlay_passthrough   sanity   regression  cleanup
 102
 103     Delete NSD  ${nsd_name}
 104
 105
 106 Delete VNF Descriptor
 107     [Tags]   epa_underlay_passthrough   sanity   regression  cleanup
 108
 109     Delete VNFD  ${vnfd_name}
 110
 111
 112
 113 *** Keywords ***
 114 Suite Cleanup
 115     [Documentation]  Test Suite Cleanup: Deleting descriptors and NS instance
 116
 117     Run Keyword If Any Tests Failed  Delete NS  ${ns_name}
 118
 119     Run Keyword If Any Tests Failed  Delete NSD  ${nsd_name}
 120
 121     Run Keyword If Any Tests Failed  Delete VNFD  ${vnfd_name}
 122
 123