robot-systest/testsuite/epa_03-crud_operations_on_sdnc.robot

   1 *** Comments ***
   2 #   Licensed under the Apache License, Version 2.0 (the "License");
   3 #   you may not use this file except in compliance with the License.
   4 #   You may obtain a copy of the License at
   5 #
   6 #       http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 #   Unless required by applicable law or agreed to in writing, software
   9 #   distributed under the License is distributed on an "AS IS" BASIS,
  10 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 #   See the License for the specific language governing permissions and
  12 #   limitations under the License.
  13
  14
  15 *** Settings ***
  16 Documentation   [EPA-03] CRUD operations on SDNC accounts.
  17
  18 Resource   ../lib/prometheus_lib.resource
  19 Resource   ../lib/sdnc_lib.resource
  20
  21 Variables   ../resources/epa_03-crud_operations_on_sdnc_data.py
  22
  23 Test Tags   epa_03   cluster_epa   daily   regression
  24
  25 Suite Setup   Run Keyword And Ignore Error   Suite Preparation
  26 Suite Teardown   Run Keyword And Ignore Error   Delete Basic SDNC
  27
  28
  29 *** Variables ***
  30 ${SDNC_ENABLED_MAX_WAIT_TIME}   1min
  31 ${SDNC_ENABLED_POL_TIME}   10
  32
  33
  34 *** Test Cases ***
  35 Create Basic SDNC
  36     [Documentation]   Register SDN controller in OSM.
  37     ${created_sdnc_id}=   Create SDNC   ${sdnc_name}   ${sdnc_user}   ${sdnc_password}   ${sdnc_url}   ${sdnc_type}
  38     Set Suite Variable   ${SDNC_ID}   ${created_sdnc_id}
  39     Wait Until Keyword Succeeds   ${SDNC_ENABLED_MAX_WAIT_TIME}   ${SDNC_ENABLED_POL_TIME}   Check For SDNC   ${SDNC_ID}
  40
  41 Check SDNC Status Is Healthy
  42     [Documentation]   Check in Prometheus that the SDN controller is in healthy state.
  43     Check For SDNC Status   ${SDNC_ID}   ${PROMETHEUS_HOST}   ${PROMETHEUS_PORT}   ${PROMETHEUS_USER}   ${PROMETHEUS_PASSWORD}
  44
  45 Delete Basic SDNC
  46     [Documentation]   Delete SDN controller from OSM.
  47     [Tags]   cleanup
  48     Delete SDNC   ${sdnc_name}
  49
  50
  51 *** Keywords ***
  52 Suite Preparation
  53     [Documentation]   Test Suite Preparation: Setting Prometheus Testsuite Variables.
  54     Set Testsuite Prometheus Variables