robot-systest/testsuite/epa_02-additional_capabilities.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation   [EPA-02] Support for additional EPA capabilities.
  15
  16 Library   OperatingSystem
  17 Library   String
  18 Library   Collections
  19 Library   SSHLibrary
  20
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnf_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  24 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  25 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/openstack_lib.robot
  26
  27 Force Tags   epa_02   cluster_epa   daily   regression
  28
  29 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  30
  31
  32 *** Variables ***
  33 # NS and VNF descriptor package folder and ids
  34 ${vnfd_pkg}   epa_quota_vnf
  35 ${vnfd_name}   epa_quota-vnf
  36 ${nsd_pkg}   epa_quota_ns
  37 ${nsd_name}   epa_quota-ns
  38
  39 # NS instance name and configuration
  40 ${ns_name}   epa_02-epa_quota_test
  41 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  42
  43 # SSH public keys file
  44 ${publickey}   %{HOME}/.ssh/id_rsa.pub
  45
  46 ${ns_id}   ${EMPTY}
  47 ${vnf_server_id}   ${EMPTY}
  48 ${flavor_properties}   ${EMPTY}
  49 ${success_return_code}   0
  50
  51
  52 *** Test Cases ***
  53 Create VNF Descriptor
  54
  55     Remove Environment Variable   OVERRIDES
  56     Create VNFD   '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  57
  58
  59 Create NS Descriptor
  60
  61     Create NSD   '%{PACKAGES_FOLDER}/${nsd_pkg}'
  62
  63
  64 Instantiate Network Service
  65
  66     ${id}=   Create Network Service   ${nsd_name}   %{VIM_TARGET}   ${ns_name}   ${ns_config}   ${publickey}
  67     Set Suite Variable   ${ns_id}   ${id}
  68
  69
  70 Get VNF Server ID
  71
  72     ${vnfs_list}=   Get Ns Vnf List   ${ns_id}
  73     ${vim_id}=   Get VNF VIM ID   ${vnfs_list}[0]
  74     Log   ${vim_id}
  75     Set Suite Variable   ${vnf_server_id}   ${vim_id}
  76
  77
  78 Get Server Flavor Properties
  79
  80     ${flavor_id}=   Get Server Flavor ID   ${vnf_server_id}
  81     ${properties}=   Get Flavor Properties   ${flavor_id}
  82     Log   ${properties}
  83     Set Suite Variable   ${flavor_properties}   ${properties}
  84
  85
  86 Check Flavor Quota Properties
  87
  88     ${rc}=   Run and Return RC   echo ${flavor_properties} | grep "cpu_shares_level=custom"
  89     Should Be Equal As Integers   ${rc}   ${success_return_code}
  90     ${rc}=   Run and Return RC   echo ${flavor_properties} | grep "disk_io_shares_level=custom"
  91     Should Be Equal As Integers   ${rc}   ${success_return_code}
  92     ${rc}=   Run and Return RC   echo ${flavor_properties} | grep "memory_shares_level=custom"
  93     Should Be Equal As Integers   ${rc}   ${success_return_code}
  94
  95
  96 Delete NS Instance
  97     [Tags]   cleanup
  98
  99     Delete NS   ${ns_name}
 100
 101
 102 Delete NS Descriptor
 103     [Tags]   cleanup
 104
 105     Delete NSD   ${nsd_name}
 106
 107
 108 Delete VNF Descriptor
 109     [Tags]   cleanup
 110
 111     Delete VNFD   ${vnfd_name}
 112
 113
 114 *** Keywords ***
 115 Suite Cleanup
 116     [Documentation]   Test Suite Cleanup: Deleting descriptors and NS instance
 117
 118     Run Keyword If Any Tests Failed   Delete NS   ${ns_name}
 119
 120     Run Keyword If Any Tests Failed   Delete NSD   ${nsd_name}
 121
 122     Run Keyword If Any Tests Failed   Delete VNFD   ${vnfd_name}
 123