robot-systest/testsuite/basic_31-multivdu_volume_multiattach.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation   [BASIC-31] Basic NS with two multi-VDU VNF
  15
  16 Library   OperatingSystem
  17 Library   String
  18 Library   Collections
  19 Library   Process
  20 Library   SSHLibrary
  21
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  24 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  25 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/connectivity_lib.robot
  26 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  27
  28 Force Tags   basic_31   cluster_main   daily
  29
  30 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  31
  32
  33 *** Variables ***
  34 # NS and VNF descriptor package folder and ids
  35 ${vnfd_pkg}   multivdu_multiattach_vnf
  36 ${vnfd_name}   multivdu_multiattach-vnf
  37 ${nsd_pkg}   multivdu_multiattach_ns
  38 ${nsd_name}   multivdu_multiattach-ns
  39
  40 # NS instance name and configuration
  41 ${ns_name}   multivdu_multiattach
  42 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  43
  44 # SSH keys and username to be used
  45 ${publickey}   %{HOME}/.ssh/id_rsa.pub
  46 ${privatekey}   %{HOME}/.ssh/id_rsa
  47 ${username}   ubuntu
  48 ${password}   ${EMPTY}
  49
  50 ${ns_id}   ${EMPTY}
  51 ${vnf_member_index}   vnf
  52 ${vnf_ip_addr}   ${EMPTY}
  53 ${wait_guard_for_vm_boot}   50s
  54
  55
  56 *** Test Cases ***
  57 Create Hackfest multivdu VNF Descriptor
  58
  59     Create VNFD   '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  60
  61
  62 Create Hackfest Multivdu NS Descriptor
  63
  64     Create NSD   '%{PACKAGES_FOLDER}/${nsd_pkg}'
  65
  66
  67 Network Service Instance Test
  68
  69     ${status}   ${message}=   Run Keyword And Ignore Error   Variable Should Exist   ${publickey}
  70         Run Keyword If   "${status}" == "FAIL"   Set Global Variable   ${publickey}   ${EMPTY}
  71     ${id}=   Create Network Service   ${nsd_name}   %{VIM_TARGET}   ${ns_name}   ${ns_config}   ${publickey}
  72     Set Suite Variable   ${ns_id}   ${id}
  73     Sleep   ${wait_guard_for_vm_boot}   Waiting for VM's daemons to be up and running
  74
  75
  76 Get Vnf ID
  77
  78     ${_vnf_id}=   Get Vnf Id   ${ns_id}   ${vnf_member_index}
  79     Set Suite Variable   ${vnf_id}   ${_vnf_id}
  80
  81
  82 Get Vnf Management Ip Addresses
  83
  84     ${rc}   ${vdu0_ip}=   Run and Return RC and Output   osm vnf-show ${vnf_id} --literal | yq -r '.vdur[0].interfaces[]."ip-address"'
  85     ${rc}   ${vdu1_ip}=   Run and Return RC and Output   osm vnf-show ${vnf_id} --literal | yq -r '.vdur[1].interfaces[]."ip-address"'
  86     Set Suite Variable   ${mgmnt_ip_addr_0}   ${vdu0_ip}
  87     Set Suite Variable   ${mgmnt_ip_addr_1}   ${vdu1_ip}
  88
  89
  90 Ensure that VDUs can share data
  91
  92     Execute Remote Command Check Rc Return Output   ${mgmnt_ip_addr_0}   ${username}   ${EMPTY}   ${privatekey}   sudo mkfs.ext3 -F /dev/vdb && sudo mkdir /shared && sudo mount /dev/vdb /shared && sudo chown ubuntu /shared && echo "osmtest" > /shared/test_file
  93     Execute Remote Command Check Rc Return Output   ${mgmnt_ip_addr_1}   ${username}   osmpass   ${privatekey}   sudo mkdir /shared && sudo mount /dev/vdb /shared && cat /shared/test_file
  94     ${stdout}=   Execute Remote Command Check Rc Return Output   ${mgmnt_ip_addr_0}   ${username}   ${EMPTY}   ${privatekey}   cat /shared/test_file
  95     Log   ${stdout}
  96     Should Be Equal   ${stdout}   osmtest   Shared data can't be read
  97
  98
  99 Delete NS Instance Test
 100     [Tags]   cleanup
 101
 102     Delete NS   ${ns_name}
 103
 104
 105 Delete NS Descriptor Test
 106     [Tags]   cleanup
 107
 108     Delete NSD   ${nsd_name}
 109
 110
 111 Delete VNF Descriptor Test
 112     [Tags]   cleanup
 113
 114     Delete VNFD   ${vnfd_name}
 115
 116
 117 *** Keywords ***
 118 Suite Cleanup
 119     [Documentation]   Test Suit Cleanup: Deleting Descriptor, instance and vim
 120
 121     Run Keyword If Any Tests Failed   Delete NS   ${ns_name}
 122
 123     Run Keyword If Any Tests Failed   Delete NSD   ${nsd_name}
 124
 125     Run Keyword If Any Tests Failed   Delete VNFD   ${vnfd_name}