robot-systest/testsuite/basic_30-ns_ipv6_profile.robot

   1 *** Comments ***
   2 #   Licensed under the Apache License, Version 2.0 (the "License");
   3 #   you may not use this file except in compliance with the License.
   4 #   You may obtain a copy of the License at
   5 #
   6 #       http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 #   Unless required by applicable law or agreed to in writing, software
   9 #   distributed under the License is distributed on an "AS IS" BASIS,
  10 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 #   See the License for the specific language governing permissions and
  12 #   limitations under the License.
  13
  14
  15 *** Settings ***
  16 Documentation   [BASIC-30] NS with a single VNF and two VDU linked by a VLD with ipv6-profile.
  17
  18 Library   OperatingSystem
  19 Library   String
  20 Library   Collections
  21 Library   SSHLibrary
  22 Library   JSONLibrary
  23
  24 Resource   ../lib/vnf_lib.resource
  25 Resource   ../lib/vnfd_lib.resource
  26 Resource   ../lib/nsd_lib.resource
  27 Resource   ../lib/ns_lib.resource
  28 Resource   ../lib/ssh_lib.resource
  29 Resource   ../lib/openstack_lib.resource
  30
  31 Test Tags   basic_30   cluster_main   daily
  32
  33 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  34
  35
  36 *** Variables ***
  37 # NS and VNF descriptor package folder and ids
  38 ${VNFD_PKG}   ubuntu_4ifaces_vnf
  39 ${VNFD_NAME}   ubuntu_4ifaces-vnf
  40 ${NSD_PKG}   ubuntu_4ifaces_ipv6_ns
  41 ${NSD_NAME}   ubuntu_4ifaces-ipv6-ns
  42
  43 # NS instance name and configuration
  44 ${NS_NAME}   basic_30
  45 ${NS_CONFIG}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  46
  47 # SSH keys and username to be used
  48 ${PUBLICKEY}   %{HOME}/.ssh/id_rsa.pub
  49 ${PRIVATEKEY}   %{HOME}/.ssh/id_rsa
  50 ${USERNAME}   ubuntu
  51
  52 # VNFs data
  53 ${VNF_MEMBER_INDEX_1}   vnf1
  54 ${VNF_MEMBER_INDEX_2}   vnf2
  55 ${IFACE1_NAME}   eth1
  56 ${DATANET1_PREFIX}   ^2001:db8::*
  57
  58 ${SUCCESS_RETURN_CODE}   0
  59
  60
  61 *** Test Cases ***
  62 Create VNF Descriptor
  63     [Documentation]   Upload VNF package for the testsuite.
  64     Create VNFD   '%{PACKAGES_FOLDER}/${VNFD_PKG}'
  65
  66 Create NS Descriptor
  67     [Documentation]   Upload NS package for the testsuite.
  68     Create NSD   '%{PACKAGES_FOLDER}/${NSD_PKG}'
  69
  70 Instantiate Network Service
  71     [Documentation]   Instantiate NS for the testsuite.
  72     ${id}=   Create Network Service   ${NSD_NAME}   %{VIM_TARGET}   ${NS_NAME}   ${NS_CONFIG}   ${PUBLICKEY}
  73     Set Suite Variable   ${NS_ID}   ${id}
  74
  75 Get Vnfs Info
  76     [Documentation]   Get information from the two VNF of the NS, specifically VNF instance id and mgmt IP address.
  77     Variable Should Exist   ${NS_ID}   msg=Network service instance is not available
  78     @{vnfr_list}=   Get Ns Vnfr Ids   ${NS_ID}
  79     Log List   ${vnfr_list}
  80     Set Suite Variable   ${VNF_ID1}   ${vnfr_list}[0]
  81     Set Suite Variable   ${VNF_ID2}   ${vnfr_list}[1]
  82     ${ip}=   Get Vnf Management Ip Address   ${NS_ID}   ${VNF_MEMBER_INDEX_1}
  83     Set Suite Variable   ${VNF1_IPMGMT}   ${ip}
  84     Log   ${VNF1_IPMGMT}
  85     ${ip}=   Get Vnf Management Ip Address   ${NS_ID}   ${VNF_MEMBER_INDEX_2}
  86     Set Suite Variable   ${VNF2_IPMGMT}   ${ip}
  87     Log   ${VNF2_IPMGMT}
  88
  89 Check Vnf1 IPs
  90     [Documentation]   Check whether IP addresses of the first VNF in the VNF record meet the expected CIDR.
  91     Variable Should Exist   ${VNF_ID1}   msg=VNF1 is not available
  92     ${rc}   ${stdout}=   Run And Return RC And Output   osm vnf-show ${VNF_ID1} --literal | yq '.vdur[0].interfaces[] | select(.name == "${IFACE1_NAME}")' | yq -r '."ip-address"'
  93     Should Be Equal As Integers   ${rc}   ${SUCCESS_RETURN_CODE}   msg=${stdout}   values=False
  94     Should Match Regexp   ${stdout}   ${DATANET1_PREFIX}   msg=${stdout} doesn't match subnet's regexp ${DATANET1_PREFIX}
  95     Set Suite Variable   ${VNF1_IP1}   ${stdout}
  96
  97 Check Vnf2 IPs
  98     [Documentation]   Check whether IP addresses of the second VNF in the VNF record meet the expected CIDR.
  99     Variable Should Exist   ${VNF_ID2}   msg=VNF2 is not available
 100     ${rc}   ${stdout}=   Run And Return RC And Output   osm vnf-show ${VNF_ID2} --literal | yq '.vdur[0].interfaces[] | select(.name == "${IFACE1_NAME}")' | yq -r '."ip-address"'
 101     Should Be Equal As Integers   ${rc}   ${SUCCESS_RETURN_CODE}   msg=${stdout}   values=False
 102     Should Match Regexp   ${stdout}   ${DATANET1_PREFIX}   msg=${stdout} doesn't match subnet's regexp ${DATANET1_PREFIX}
 103     Set Suite Variable   ${VNF2_IP1}   ${stdout}
 104
 105 Verify Vnf1 Interfaces
 106     [Documentation]   Check whether IP addresses of the first VNF configured inside the VM meet the expected CIDR.
 107     Variable Should Exist   ${VNF1_IPMGMT}   msg=IP address of the data VNF '${VNF_MEMBER_INDEX_1}' is not available
 108     Variable Should Exist   ${PRIVATEKEY}   msg=SSH private key not available
 109     Sleep   120 seconds   Wait for SSH daemon to be up
 110     ${stdout}=   Execute Remote Command Check Rc Return Output   ${VNF1_IPMGMT}   ${USERNAME}   ${EMPTY}   ${PRIVATEKEY}   sudo dhclient -6 ens4 ; ip --brief addr show up | grep -v "^lo" | awk '{print $3}'
 111     Log   ${stdout}
 112     @{ip}=   Split String   ${stdout}
 113     Should Match Regexp   ${ip}[1]   ${DATANET1_PREFIX}   msg=${ip}[1] doesn't match subnet's regexp ${DATANET1_PREFIX}
 114
 115 Verify Vnf2 Interfaces
 116     [Documentation]   Check whether IP addresses of the second VNF configured inside the VM meet the expected CIDR.
 117     Variable Should Exist   ${VNF2_IPMGMT}   msg=IP address of the data VNF '${VNF_MEMBER_INDEX_2}' is not available
 118     Variable Should Exist   ${PRIVATEKEY}   msg=SSH private key not available
 119     ${stdout}=   Execute Remote Command Check Rc Return Output   ${VNF2_IPMGMT}   ${USERNAME}   ${EMPTY}   ${PRIVATEKEY}   sudo dhclient -6 ens4 ; ip --brief addr show up | grep -v "^lo" | awk '{print $3}'
 120     Log   ${stdout}
 121     @{ip}=   Split String   ${stdout}
 122     Should Match Regexp   ${ip}[1]   ${DATANET1_PREFIX}   msg=${ip}[1] doesn't match subnet's regexp ${DATANET1_PREFIX}
 123
 124 Check that ipv6 address_mode and ra_mode are set
 125     [Documentation]   Check that IPv6 address mode and RA mode are set and equal to dhcpv6-stateful.
 126     ${rc}   ${vim_info}=   Run And Return RC And Output   osm vnf-show ${VNF_ID1} --literal | yq '.vdur[] | select(."count-index" == 0)' | yq -r '.vim_info[].interfaces[].vim_info'
 127     Log   ${rc},${vim_info}
 128     ${subnet_id}=   Get Regexp Matches   ${vim_info}   {ip_address: '2001:db8::.*', subnet_id: ([0-9a-f]{8}-[0-9a-f]{4}-[0-9a-f]{4}-[0-9a-f]{4}-[0-9a-f]{12})}   1
 129     ${subnet_info}=   Get Subnet   ${subnet_id}[0]
 130     ${json_object}=   Convert String To JSON   ${subnet_info}
 131     ${address_mode}=   Get From Dictionary   ${json_object}   ipv6_address_mode
 132     ${ra_mode}=   Get From Dictionary   ${json_object}   ipv6_ra_mode
 133     Should Be Equal   ${address_mode}   dhcpv6-stateful   msg=ipv6_address_mode does not equal dhcpv6-stateful
 134     Should Be Equal   ${ra_mode}   dhcpv6-stateful   msg=ipv6_ra_mode does not equal dhcpv6-stateful
 135
 136 Delete NS Instance
 137     [Documentation]   Delete NS instance.
 138     [Tags]   cleanup
 139     Delete NS   ${NS_NAME}
 140
 141 Delete NS Descriptor
 142     [Documentation]   Delete NS package from OSM.
 143     [Tags]   cleanup
 144     Delete NSD   ${NSD_NAME}
 145
 146 Delete VNF Descriptor
 147     [Documentation]   Delete VNF package from OSM.
 148     [Tags]   cleanup
 149     Delete VNFD   ${VNFD_NAME}
 150
 151
 152 *** Keywords ***
 153 Suite Cleanup
 154     [Documentation]   Test Suite Cleanup: Deleting descriptors and NS instance
 155
 156     Run Keyword If Any Tests Failed   Delete NS   ${NS_NAME}
 157     Run Keyword If Any Tests Failed   Delete NSD   ${NSD_NAME}
 158     Run Keyword If Any Tests Failed   Delete VNFD   ${VNFD_NAME}