robot-systest/testsuite/basic_16-advanced_onboarding_and_scaling.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation     [BASIC-16] Advanced onboarding with override and complex scaling (3 initial instances, scaled by two).
  15
  16 Library   OperatingSystem
  17 Library   String
  18 Library   Collections
  19
  20 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  24
  25 Variables   %{ROBOT_DEVOPS_FOLDER}/resources/basic_16-advanced_onboarding_and_scaling_data.py
  26
  27 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  28
  29
  30 *** Variables ***
  31 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  32 ${scaling_group}   vdu_autoscale
  33 ${vnf_member_index}  1
  34
  35
  36 *** Test Cases ***
  37 Create Scaling VNF Descriptor
  38     [Tags]   advanced_scaling   sanity   regression
  39
  40     Create VNFD Overriding Fields  '%{PACKAGES_FOLDER}/${vnfd_pkg}'   df.0.instantiation-level.0.vdu-level.0.number-of-instances=${init_instances};df.0.vdu-profile.0.min-number-of-instances=${min_instances};df.0.vdu-profile.0.max-number-of-instances=${max_instances};df.0.scaling-aspect.0.aspect-delta-details.deltas.0.vdu-delta.0.number-of-instances=${delta_instances}
  41
  42
  43 Create Scaling NS Descriptor
  44     [Tags]   advanced_scaling   sanity   regression
  45
  46     Create NSD  '%{PACKAGES_FOLDER}/${nsd_pkg}'
  47
  48
  49 Instantiate Scaling Network Service
  50     [Tags]   advanced_scaling   sanity   regression
  51
  52     ${id}=  Create Network Service  ${nsd_name}  %{VIM_TARGET}  ${ns_name}  ${ns_config}  ${publickey}
  53     Set Suite Variable  ${ns_id}  ${id}
  54
  55
  56 Get Vnf Id
  57     [Tags]   advanced_scaling   sanity   regression
  58
  59     Variable Should Exist  ${ns_id}  msg=Network service instance is not available
  60     @{vnfr_list}=  Get Ns Vnfr Ids  ${ns_id}
  61     Log List  ${vnfr_list}
  62     Set Suite Variable  ${vnf_id}  ${vnfr_list}[0]
  63
  64
  65 Check Vdus Before Scale Out
  66     [Documentation]     Check the number of VDUs instances before the manual scaling.
  67     [Tags]   advanced_scaling   sanity   regression
  68
  69     @{vdur_list}=  Get Vnf Vdur Names  ${vnf_id}
  70     Log List  ${vdur_list}
  71     ${vdurs}=  Get Length  ${vdur_list}
  72     Set Suite Variable  ${initial_vdur_count}  ${vdurs}
  73     Run Keyword Unless  ${init_instances} == ${initial_vdur_count}   Fail  msg=Instantiated VDUs (${initial_vdur_count}) don't match specified number in descriptor (${init_instances})
  74
  75
  76 Perform Manual Vdu Scale Out
  77     [Tags]   advanced_scaling   sanity   regression
  78
  79     Variable Should Exist  ${ns_id}  msg=Network service instance is not available
  80     ${ns_op_id}=  Execute Manual VNF Scale  ${ns_name}  ${vnf_member_index}  ${scaling_group}  SCALE_OUT
  81
  82
  83 Check Vdus After Scale Out
  84     [Documentation]     Check whether there is one more VDU after scaling or not.
  85     [Tags]   advanced_scaling   sanity   regression
  86
  87     Variable Should Exist  ${ns_id}  msg=Network service instance is not available
  88     @{vdur_list}=  Get Vnf Vdur Names  ${vnf_id}
  89     Log List  ${vdur_list}
  90     ${vdurs}=  Get Length  ${vdur_list}
  91     Run Keyword Unless  ${vdurs} == ${initial_vdur_count} + ${delta_instances}  Fail  msg=VDU instances in the VNF (${vdurs}) don't match after Scale Out (${initial_vdur_count} + ${delta_instances})
  92
  93
  94 Perform Manual Vdu Scale In
  95     [Tags]   advanced_scaling   sanity   regression
  96
  97     Variable Should Exist  ${ns_id}  msg=Network service instance is not available
  98     ${ns_op_id}=  Execute Manual VNF Scale  ${ns_name}  ${vnf_member_index}  ${scaling_group}  SCALE_IN
  99
 100
 101 Check Vdus After Scaling In
 102     [Documentation]     Check whether there is one less VDU after scaling or not.
 103     [Tags]   advanced_scaling   sanity   regression
 104
 105     Variable Should Exist  ${ns_id}  msg=Network service instance is not available
 106     @{vdur_list}=  Get Vnf Vdur Names  ${vnf_id}
 107     Log List  ${vdur_list}
 108     ${vdurs}=  Get Length  ${vdur_list}
 109     Run Keyword Unless  ${vdurs} == ${initial_vdur_count}  Fail  msg=There is the same number of VDU records in the VNF after Scale In
 110
 111
 112 Delete NS Instance
 113     [Tags]   advanced_scaling   sanity   regression  cleanup
 114
 115     Delete NS  ${ns_name}
 116
 117
 118 Delete NS Descriptor
 119     [Tags]   advanced_scaling   sanity   regression  cleanup
 120
 121     Delete NSD  ${nsd_name}
 122
 123
 124 Delete VNF Descriptor
 125     [Tags]   advanced_scaling   sanity   regression  cleanup
 126
 127     Delete VNFD  ${vnfd_name}
 128
 129
 130 *** Keywords ***
 131 Suite Cleanup
 132     [Documentation]  Test Suite Cleanup: Deleting descriptors and NS instance
 133
 134     Run Keyword If Any Tests Failed  Delete NS  ${ns_name}
 135     Run Keyword If Any Tests Failed  Delete NSD  ${nsd_name}
 136     Run Keyword If Any Tests Failed  Delete VNFD  ${vnfd_name}
 137