robot-systest/testsuite/basic_06-vnf_with_charm.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation     [BASIC-06] VNF with Charm.
  15
  16 Library   OperatingSystem
  17 Library   SSHLibrary
  18
  19 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  20 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  23
  24 Variables   %{ROBOT_DEVOPS_FOLDER}/resources/basic_06-vnf_with_charm_data.py
  25
  26 Force Tags   basic_06   cluster_ee_config   daily   regression
  27
  28 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  29
  30
  31 *** Variables ***
  32 ${username}   ubuntu
  33 ${password}   ${EMPTY}
  34 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  35 ${action_name}   touch
  36 ${vnf_member_index_1}   1
  37 ${vnf_member_index_2}   2
  38 ${day_1_file_name}   /home/ubuntu/first-touch
  39 ${day_2_file_name_1}   /home/ubuntu/mytouch1
  40 ${day_2_file_name_2}   /home/ubuntu/mytouch2
  41 ${ns_timeout}   15min
  42
  43
  44 *** Test Cases ***
  45 Create Charm VNF Descriptor
  46
  47     Create VNFD  '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  48
  49
  50 Create Charm NS Descriptor
  51
  52     Create NSD  '%{PACKAGES_FOLDER}/${nsd_pkg}'
  53
  54
  55 Instantiate Charm Network Service
  56
  57     ${id}=  Create Network Service  ${nsd_name}  %{VIM_TARGET}  ${ns_name}  ${ns_config}  ${publickey}  ${ns_timeout}
  58     Set Suite Variable  ${ns_id}  ${id}
  59
  60
  61 Get Management Ip Addresses
  62
  63     ${ip_addr_1}  Get Vnf Management Ip Address  ${ns_id}  ${vnf_member_index_1}
  64     log  ${ip_addr_1}
  65     Set Suite Variable  ${vnf_1_ip_addr}  ${ip_addr_1}
  66     ${ip_addr_2}  Get Vnf Management Ip Address  ${ns_id}  ${vnf_member_index_2}
  67     log  ${ip_addr_2}
  68     Set Suite Variable  ${vnf_2_ip_addr}  ${ip_addr_2}
  69
  70
  71 Test SSH Access
  72
  73     Variable Should Exist  ${vnf_1_ip_addr}  msg=IP address of the management VNF '${vnf_member_index_1}' is not available
  74     Variable Should Exist  ${vnf_2_ip_addr}  msg=IP address of the management VNF '${vnf_member_index_2}' is not available
  75     Sleep  30s  Waiting ssh daemon to be up
  76     Test SSH Connection  ${vnf_1_ip_addr}  ${username}  ${password}  ${privatekey}
  77     Test SSH Connection  ${vnf_2_ip_addr}  ${username}  ${password}  ${privatekey}
  78
  79
  80 Check Remote Files Created Via Day 1 Operations
  81     [Documentation]     The Charm VNF has a Day 1 operation that creates a file named ${day_1_file_name}.
  82     ...                 This test checks whether that files have been created or not.
  83
  84     Check If remote File Exists  ${vnf_1_ip_addr}  ${username}  ${password}  ${privatekey}  ${day_1_file_name}
  85     Check If remote File Exists  ${vnf_2_ip_addr}  ${username}  ${password}  ${privatekey}  ${day_1_file_name}
  86
  87
  88 Execute Day 2 Operations
  89     [Documentation]     Performs one Day 2 operation per VNF that creates a new file.
  90
  91     Variable Should Exist  ${ns_id}  msg=Network service instance is not available
  92     ${ns_op_id_1}=  Execute NS Action  ${ns_name}  ${action_name}  ${vnf_member_index_1}  filename=${day_2_file_name_1}
  93     ${ns_op_id_2}=  Execute NS Action  ${ns_name}  ${action_name}  ${vnf_member_index_2}  filename=${day_2_file_name_2}
  94
  95
  96 Check Remote Files Created Via Day 2 Operations
  97     [Documentation]     Check whether the files created in the previous test via Day 2 operations exist or not.
  98
  99     Check If remote File Exists  ${vnf_1_ip_addr}  ${username}  ${password}  ${privatekey}  ${day_2_file_name_1}
 100     Check If remote File Exists  ${vnf_2_ip_addr}  ${username}  ${password}  ${privatekey}  ${day_2_file_name_2}
 101
 102
 103 Delete NS Instance
 104     [Tags]   cleanup
 105
 106     Delete NS  ${ns_name}
 107
 108
 109 Delete NS Descriptor
 110     [Tags]   cleanup
 111
 112     Delete NSD  ${nsd_name}
 113
 114
 115 Delete VNF Descriptor
 116     [Tags]   cleanup
 117
 118     Delete VNFD  ${vnfd_name}
 119
 120
 121 *** Keywords ***
 122 Suite Cleanup
 123     [Documentation]  Test Suite Cleanup: Deleting descriptors and NS instance
 124
 125     Run Keyword If Any Tests Failed  Delete NS  ${ns_name}
 126
 127     Run Keyword If Any Tests Failed  Delete NSD  ${nsd_name}
 128
 129     Run Keyword If Any Tests Failed  Delete VNFD  ${vnfd_name}
 130