robot-systest/testsuite/basic_06-vnf_with_charm.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation   [BASIC-06] VNF with Charm.
  15
  16 Library   OperatingSystem
  17 Library   SSHLibrary
  18
  19 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  20 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/juju_lib.robot
  24
  25 Force Tags   basic_06   cluster_ee_config   daily   regression
  26
  27 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  28
  29
  30 *** Variables ***
  31 # NS and VNF descriptor package folder and ids
  32 ${vnfd_pkg}   charm-packages/ha_proxy_charm_vnf
  33 ${vnfd_name}   ha_proxy_charm-vnf
  34 ${nsd_pkg}   charm-packages/ha_proxy_charm_ns
  35 ${nsd_name}   ha_proxy_charm-ns
  36
  37 # NS instance name and configuration
  38 ${ns_name}   basic_06_charm_test
  39 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  40
  41 # SSH keys and username to be used
  42 ${publickey}   %{HOME}/.ssh/id_rsa.pub
  43 ${privatekey}   %{HOME}/.ssh/id_rsa
  44 ${username}   ubuntu
  45 ${password}   ${EMPTY}
  46
  47 ${action_name}   touch
  48 ${vnf_member_index_1}   vnf1
  49 ${vnf_member_index_2}   vnf2
  50 ${day_1_file_name}   /home/ubuntu/first-touch
  51 ${day_2_file_name_1}   /home/ubuntu/mytouch1
  52 ${day_2_file_name_2}   /home/ubuntu/mytouch2
  53 ${ns_timeout}   15min
  54
  55 # VNF profile id, execution environment name to check VNF level charm naming
  56 ${vnf_profile_id}   vnf1
  57 ${ee_name}   simple-ee
  58
  59
  60 *** Test Cases ***
  61 Create Charm VNF Descriptor
  62
  63     Create VNFD   '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  64
  65
  66 Create Charm NS Descriptor
  67
  68     Create NSD   '%{PACKAGES_FOLDER}/${nsd_pkg}'
  69
  70
  71 Instantiate Charm Network Service
  72
  73     ${id}=   Create Network Service   ${nsd_name}   %{VIM_TARGET}   ${ns_name}   ${ns_config}   ${publickey}   ${ns_timeout}
  74     Set Suite Variable   ${ns_id}   ${id}
  75     Set Suite Variable   ${model_name}   ${id}
  76
  77
  78 Check VNF Charm Application Name
  79
  80     ${vnf_charm_app_name}=   Get Application Name VNF Level Charm   %{OSM_HOSTNAME}   ${username}   ${password}   %{OSM_RSA_FILE}   ${model_name}   ${vnf_profile_id}   ${ee_name}
  81     ${length}=   Get Length   ${vnf_charm_app_name}
  82     Should Be True   ${length} <50
  83
  84
  85 Get Management Ip Addresses
  86
  87     ${ip_addr_1}   Get Vnf Management Ip Address   ${ns_id}   ${vnf_member_index_1}
  88     log   ${ip_addr_1}
  89     Set Suite Variable   ${vnf_1_ip_addr}   ${ip_addr_1}
  90     ${ip_addr_2}   Get Vnf Management Ip Address   ${ns_id}   ${vnf_member_index_2}
  91     log   ${ip_addr_2}
  92     Set Suite Variable   ${vnf_2_ip_addr}   ${ip_addr_2}
  93
  94
  95 Test SSH Access
  96
  97     Variable Should Exist   ${vnf_1_ip_addr}   msg=IP address of the management VNF '${vnf_member_index_1}' is not available
  98     Variable Should Exist   ${vnf_2_ip_addr}   msg=IP address of the management VNF '${vnf_member_index_2}' is not available
  99     Sleep   30s   Waiting ssh daemon to be up
 100     Test SSH Connection   ${vnf_1_ip_addr}   ${username}   ${password}   ${privatekey}
 101     Test SSH Connection   ${vnf_2_ip_addr}   ${username}   ${password}   ${privatekey}
 102
 103
 104 Check Remote Files Created Via Day 1 Operations
 105     [Documentation]   The Charm VNF has a Day 1 operation that creates a file named ${day_1_file_name}.
 106     ...               This test checks whether that files have been created or not.
 107
 108     Check If remote File Exists   ${vnf_1_ip_addr}   ${username}   ${password}   ${privatekey}   ${day_1_file_name}
 109     Check If remote File Exists   ${vnf_2_ip_addr}   ${username}   ${password}   ${privatekey}   ${day_1_file_name}
 110
 111
 112 Execute Day 2 Operations
 113     [Documentation]   Performs one Day 2 operation per VNF that creates a new file.
 114
 115     Variable Should Exist   ${ns_id}   msg=Network service instance is not available
 116     ${ns_op_id_1}=   Execute NS Action   ${ns_name}   ${action_name}   ${vnf_member_index_1}   filename=${day_2_file_name_1}
 117     ${ns_op_id_2}=   Execute NS Action   ${ns_name}   ${action_name}   ${vnf_member_index_2}   filename=${day_2_file_name_2}
 118
 119
 120 Check Remote Files Created Via Day 2 Operations
 121     [Documentation]   Check whether the files created in the previous test via Day 2 operations exist or not.
 122
 123     Check If remote File Exists   ${vnf_1_ip_addr}   ${username}   ${password}   ${privatekey}   ${day_2_file_name_1}
 124     Check If remote File Exists   ${vnf_2_ip_addr}   ${username}   ${password}   ${privatekey}   ${day_2_file_name_2}
 125
 126
 127 Delete NS Instance
 128     [Tags]   cleanup
 129
 130     Delete NS   ${ns_name}
 131
 132
 133 Delete NS Descriptor
 134     [Tags]   cleanup
 135
 136     Delete NSD   ${nsd_name}
 137
 138
 139 Delete VNF Descriptor
 140     [Tags]   cleanup
 141
 142     Delete VNFD   ${vnfd_name}
 143
 144
 145 *** Keywords ***
 146 Suite Cleanup
 147     [Documentation]   Test Suite Cleanup: Deleting descriptors and NS instance
 148
 149     Run Keyword If Any Tests Failed   Delete NS   ${ns_name}
 150
 151     Run Keyword If Any Tests Failed   Delete NSD   ${nsd_name}
 152
 153     Run Keyword If Any Tests Failed   Delete VNFD   ${vnfd_name}
 154