robot-systest/lib/vnfd_lib.robot

   1 # -*- coding: utf-8 -*-
   2
   3 ##
   4 # Copyright 2019 Tech Mahindra Limited
   5 #
   6 # All Rights Reserved.
   7 #
   8 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   9 # not use this file except in compliance with the License. You may obtain
  10 # a copy of the License at
  11 #
  12 #         http://www.apache.org/licenses/LICENSE-2.0
  13 #
  14 # Unless required by applicable law or agreed to in writing, software
  15 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  16 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  17 # License for the specific language governing permissions and limitations
  18 # under the License.
  19 ##
  20
  21 ## Change log:
  22 # 1. Feature 7829: Jayant Madavi, Mrityunjay Yadav : MY00514913@techmahindra.com : 06-sep-2019
  23 ##
  24
  25 *** Settings ***
  26 Library   String
  27
  28
  29 *** Variables ***
  30 ${success_return_code}   0
  31 ${failure_return_code}   1
  32 ${delete_max_wait_time}   1min
  33 ${delete_pol_time}   15sec
  34
  35
  36 *** Keywords ***
  37 Get VNFDs List
  38     ${rc}   ${stdout}=   Run and Return RC and Output   osm vnfpkg-list
  39     log   ${stdout}
  40     log   ${rc}
  41     Should Be Equal As Integers   ${rc}   ${success_return_code}
  42
  43
  44 Create VNFD
  45     [Documentation]   Onboards ("creates") a NF Package into OSM.
  46     ...               - Parameters:
  47     ...                 - vnfd_pkg: Name (and location) of the NF Package
  48     ...                 - overrides (optional): String with options to override the EPA and/or interface properties of the Package.
  49     ...                                        This is very useful to allow to deploy e.g. non-EPA packages in EPA VIMs (or vice-versa).
  50     ...                                        Valid strings are the same as in the command. E.g.:
  51     ...                                        - `--override-epa`: adds EPA attributes to all VDUs.
  52     ...                                        - `--override-nonepa`: removes all EPA attributes from all VDUs.
  53     ...                                        - `--override-paravirt`: converts all interfaces to `PARAVIRT`. This one can be combined with
  54     ...                                           the others above (e.g. '--override-nonepa --override-paravirt').
  55     ...               - Relevant environment variables:
  56     ...                  - OVERRIDES: If the environment variable "OVERRIDES" exists, it prevails over the value in the argument.
  57     ...                               This is often more convenient to enforce the same behaviour for every test run in a given VIM.
  58
  59     [Arguments]   ${vnfd_pkg}   ${overrides}=${EMPTY}
  60
  61     # If env variable "OVERRIDES" exists, it prevails over the value in the argument
  62     ${overrides}=   Get Environment Variable    OVERRIDES   default=${overrides}
  63
  64     # Proceedes with the onboarding with the appropriate arguments
  65     ${rc}   ${stdout}=   Run and Return RC and Output   osm vnfpkg-create ${overrides} ${vnfd_pkg}
  66     log   ${stdout}
  67     Should Be Equal As Integers   ${rc}   ${success_return_code}
  68     ${lines}=  Get Line Count  ${stdout}
  69     ${last}=  Evaluate  ${lines} - 1
  70     ${id}=  Get Line  ${stdout}  ${last}
  71     [Return]  ${id}
  72
  73
  74 Update VNFD
  75     [Documentation]   Onboards ("Updates") a NF Package into OSM.
  76     ...               - Parameters:
  77     ...                 - vnfd_pkg: Name (and location) of the NF Package
  78     ...                 - vnfd_name: Name of the existing NF Package
  79
  80     [Arguments]   ${vnfd_pkg}   ${vnfd_name}
  81
  82     # Proceedes with the onboarding with the appropriate arguments
  83     ${rc}   ${stdout}=   Run and Return RC and Output   osm vnfpkg-update --content ${vnfd_pkg} ${vnfd_name}
  84     log   ${stdout}
  85     Should Be Equal As Integers   ${rc}   ${success_return_code}
  86     ${lines}=  Get Line Count  ${stdout}
  87     ${last}=  Evaluate  ${lines} - 1
  88     ${id}=  Get Line  ${stdout}  ${last}
  89     [Return]  ${id}
  90
  91
  92 Create VNFD Overriding Fields
  93     [Documentation]   Onboards ("creates") a NF Package into OSM.
  94     ...               - Parameters:
  95     ...                 - vnfd_pkg: Name (and location) of the NF Package
  96     ...                 - override_fields: String with options to override fields in descriptor, format: "key1.key2...=value[;key3...=value;...]"
  97     ...                 - overrides (optional): String with options to override the EPA and/or interface properties of the Package.
  98     ...                                        This is very useful to allow to deploy e.g. non-EPA packages in EPA VIMs (or vice-versa).
  99     ...                                        Valid strings are the same as in the command. E.g.:
 100     ...                                        - `--override-epa`: adds EPA attributes to all VDUs.
 101     ...                                        - `--override-nonepa`: removes all EPA attributes from all VDUs.
 102     ...                                        - `--override-paravirt`: converts all interfaces to `PARAVIRT`. This one can be combined with
 103     ...                                           the others above (e.g. '--override-nonepa --override-paravirt').
 104     ...               - Relevant environment variables:
 105     ...                  - OVERRIDES: If the environment variable "OVERRIDES" exists, it prevails over the value in the argument.
 106     ...                               This is often more convenient to enforce the same behaviour for every test run in a given VIM.
 107
 108     [Arguments]   ${vnfd_pkg}   ${override_fields}   ${overrides}=${EMPTY}
 109
 110     # If env variable "OVERRIDES" exists, it prevails over the value in the argument
 111     ${overrides}=   Get Environment Variable    OVERRIDES   default=${overrides}
 112
 113     # Proceedes with the onboarding with the appropriate arguments
 114     ${rc}   ${stdout}=   Run and Return RC and Output   osm vnfpkg-create ${overrides} ${vnfd_pkg} --override '${override_fields}'
 115     log   ${stdout}
 116     Should Be Equal As Integers   ${rc}   ${success_return_code}
 117     ${lines}=  Get Line Count  ${stdout}
 118     ${last}=  Evaluate  ${lines} - 1
 119     ${id}=  Get Line  ${stdout}  ${last}
 120     [Return]  ${id}
 121
 122
 123 Delete VNFD
 124     [Arguments]   ${vnfd_id}
 125
 126     ${rc}   ${stdout}=   Run and Return RC and Output   osm vnfpkg-delete ${vnfd_id}
 127     log   ${stdout}
 128     Should Be Equal As Integers   ${rc}   ${success_return_code}
 129     WAIT UNTIL KEYWORD SUCCEEDS   ${delete_max_wait_time}   ${delete_pol_time}   Check For VNFD   ${vnfd_id}
 130
 131
 132 Assert Failure Delete VNFD
 133     [Documentation]   Deletes a NF Package that cannot be deleted and asserts the failure
 134     [Arguments]   ${vnfd_id}
 135
 136     ${rc}   ${stdout}=   Run and Return RC and Output   osm vnfpkg-delete ${vnfd_id}
 137     log   ${stdout}
 138     Should Be Equal As Integers   ${rc}   ${failure_return_code}
 139     Should Contain   ${stdout}   409   msg=Expected Conflict   values=False
 140     WAIT UNTIL KEYWORD SUCCEEDS   ${delete_max_wait_time}   ${delete_pol_time}   Check For VNFD   ${vnfd_id}   True
 141
 142
 143 Check For VNFD
 144     [Arguments]   ${vnfd_id}  ${exists}=False
 145
 146     ${rc}   ${stdout}=   Run and Return RC and Output   osm vnfpkg-list | awk '{print $2}' | grep ${vnfd_id}
 147     Run Keyword If  ${exists}  Should Be Equal As Strings  ${stdout}   ${vnfd_id}
 148     ...  ELSE  Should Not Be Equal As Strings  ${stdout}   ${vnfd_id}
 149