robot-systest/lib/vim_lib.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation   Library to manage VIM Targets.
  15
  16 Library   String
  17 Library   Collections
  18 Library   OperatingSystem
  19
  20 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/prometheus_lib.robot
  21
  22
  23 *** Variables ***
  24 ${success_return_code}   0
  25 ${delete_max_wait_time}   1min
  26 ${delete_pol_time}   15sec
  27 ${vim_status_max_wait_time}   3min
  28 ${vim_status_pol_time}   15sec
  29 ${vim_opstate_max_wait_time}   40sec
  30 ${vim_opstate_pol_time}   10sec
  31
  32
  33 *** Keywords ***
  34 Create VIM Target
  35     [Documentation]   Create a VIM Target in OSM.
  36     ...                 The optional parameters (such as 'config' or 'sdn_controller') are given to this function in name=value format. These parameters will be appended to the 'osm vim-create' command with the next syntax: --param_name=param_value
  37     ...                 Return the ID of the created VIM Target.
  38     ...                 Example of execution:
  39     ...                     \${vim_account_id}=   Create VIM Target   \${vim_name}   \${vim_user}   \${vim_password}   \${vim_auth_url}   \${vim_tenant}   \${vim_account_type}   config='{...}'
  40
  41     [Arguments]   ${vim_name}   ${vim_user}   ${vim_password}   ${vim_auth_url}   ${vim_tenant}   ${vim_account_type}   @{optional_parameters}
  42
  43     ${osm_vim_create_command}=   Set Variable   osm vim-create --name ${vim_name} --user ${vim_user} --password ${vim_password} --auth_url ${vim_auth_url} --tenant ${vim_tenant} --account_type ${vim_account_type}
  44     FOR   ${param}   IN   @{optional_parameters}
  45         ${match}   ${param_name}   ${param_value} =   Should Match Regexp   ${param}   (.+)=(.+)   msg=Syntax error in optional parameters
  46         ${osm_vim_create_command}=   Catenate   ${osm_vim_create_command}   --${param_name}=${param_value}
  47     END
  48     ${rc}   ${stdout}=   Run and Return RC and Output   ${osm_vim_create_command}
  49     Log   ${stdout}
  50     Should Be Equal As Integers   ${rc}   ${success_return_code}
  51     [Return]   ${stdout}
  52
  53
  54 Delete VIM Target
  55     [Arguments]   ${vim_name}
  56
  57     ${rc}   ${stdout}=   Run Keyword And Continue On Failure   Run and Return RC and Output   osm vim-delete ${vim_name}
  58     Log   ${stdout}
  59     Wait Until Keyword Succeeds   ${delete_max_wait_time}   ${delete_pol_time}   Check for VIM Target   ${vim_name}
  60
  61
  62 Get VIM Targets
  63     ${rc}   ${stdout}=   Run and Return RC and Output   osm vim-list
  64     Log   ${stdout}
  65     Should Be Equal As Integers   ${rc}   ${success_return_code}
  66
  67
  68 Check for VIM Target
  69     [Arguments]   ${vim_name}
  70
  71     ${rc}   ${stdout}=   Run and Return RC and Output   osm vim-list | awk '{print $2}' | grep ${vim_name}
  72     Should Not Be Equal As Strings   ${stdout}   ${vim_name}
  73
  74
  75 Check for VIM Target Metric
  76     [Arguments]   ${vim_name}   ${prometheus_host}   ${prometheus_port}   ${prometheus_user}   ${prometheus_password}
  77
  78     ${vim_account_id}=   Get VIM Target ID   ${vim_name}
  79     Wait Until Keyword Succeeds   ${vim_status_max_wait_time}   ${vim_status_pol_time}   Check If VIM Target Has Metric   ${vim_account_id}   ${prometheus_host}   ${prometheus_port}   ${prometheus_user}   ${prometheus_password}
  80
  81
  82 Check for VIM Target Status
  83     [Arguments]   ${vim_name}   ${prometheus_host}   ${prometheus_port}   ${prometheus_user}   ${prometheus_password}
  84
  85     ${vim_account_id}=   Get VIM Target ID   ${vim_name}
  86     Wait Until Keyword Succeeds   ${vim_status_max_wait_time}   ${vim_status_pol_time}   Check If VIM Target Is Available   ${vim_account_id}   ${prometheus_host}   ${prometheus_port}   ${prometheus_user}   ${prometheus_password}
  87
  88
  89 Get VIM Target ID
  90     [Arguments]   ${vim_name}
  91
  92     ${rc}   ${stdout}=   Run and Return RC and Output   osm vim-list | grep " ${vim_name} " | awk '{print $4}'
  93     Should Be Equal As Integers   ${rc}   ${success_return_code}
  94     Should Not Be Equal As Strings   ${stdout}   ${EMPTY}   msg=VIM Target '${vim_name}' not found   values=false
  95     [Return]   ${stdout}
  96
  97
  98 Check VIM Target Operational State
  99     [Arguments]   ${vim_name}
 100
 101     Wait Until Keyword Succeeds   ${vim_opstate_max_wait_time}   ${vim_opstate_pol_time}   Check If VIM Target Is Enabled   ${vim_name}
 102
 103
 104 Check If VIM Target Is Enabled
 105     [Arguments]   ${vim_name}
 106
 107     ${rc}   ${stdout}=   Run and Return RC and Output   osm vim-list | grep " ${vim_name} " | awk '{print $6}'
 108     Should Be Equal As Integers   ${rc}   ${success_return_code}
 109     Should Be Equal As Strings   ${stdout}   ENABLED   msg=VIM Target '${vim_name}' is not enabled   values=false
 110
 111
 112 Check If VIM Target Is Available
 113     [Arguments]   ${vim_account_id}   ${prometheus_host}   ${prometheus_port}   ${prometheus_user}   ${prometheus_password}
 114
 115     ${metric}=   Get Metric   ${prometheus_host}   ${prometheus_port}   ${prometheus_user}   ${prometheus_password}   osm_vim_status   vim_account_id=${vim_account_id}
 116     Should Be Equal As Integers   ${metric}   1   msg=VIM Target '${vim_account_id}' is not active   values=false
 117
 118
 119 Check If VIM Target Has Metric
 120     [Arguments]   ${vim_account_id}   ${prometheus_host}   ${prometheus_port}   ${prometheus_user}   ${prometheus_password}
 121
 122     ${metric}=   Get Metric   ${prometheus_host}   ${prometheus_port}   ${prometheus_user}   ${prometheus_password}   osm_vim_status   vim_account_id=${vim_account_id}
 123     Should Be True   ${metric} <2   msg=VIM Target '${vim_account_id}' has no metric