robot-systest/lib/sdnc_lib.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation     Library to manage SDNCs.
  15
  16 Library   String
  17 Library   Collections
  18 Library   OperatingSystem
  19
  20 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/prometheus_lib.robot
  21
  22
  23 *** Variables ***
  24 ${success_return_code}   0
  25 ${delete_max_wait_time}   1min
  26 ${delete_pol_time}   15sec
  27 ${sdnc_status_max_wait_time}   6min
  28 ${sdnc_status_pol_time}   1min
  29
  30
  31 *** Keywords ***
  32 Create SDNC
  33     [Documentation]     Creates an SDNC in OSM.
  34     ...                 The optional parameters (such as 'switch_dpid' or 'ip-address') are given to this function in name=value format. These parameters will be appended to the 'osm sdnc-create' command with the next syntax: --param_name=param_value
  35     ...                 Returns the ID of the created SDNC Target.
  36     ...                 Example of execution:
  37     ...                     \${sdnc_id}=  Create SDNC  \${sdnc_name}  \${sdnc_user}  \${sdnc_password}  \${sdnc_url}  \${sdnc_type}  switch_dpid='{...}'
  38
  39     [Arguments]  ${sdnc_name}  ${sdnc_user}  ${sdnc_password}  ${sdnc_url}  ${sdnc_type}  @{optional_parameters}
  40
  41     ${osm_sdnc_create_command}=  Set Variable  osm sdnc-create --name ${sdnc_name} --user ${sdnc_user} --password ${sdnc_password} --url ${sdnc_url} --type ${sdnc_type}
  42     FOR  ${param}  IN  @{optional_parameters}
  43         ${match}  ${param_name}  ${param_value} =  Should Match Regexp  ${param}  (.+)=(.+)  msg=Syntax error in optional parameters
  44         ${osm_sdnc_create_command}=  Catenate  ${osm_sdnc_create_command}  --${param_name}=${param_value}
  45     END
  46     ${rc}  ${stdout}=  Run and Return RC and Output  ${osm_sdnc_create_command}
  47     log  ${stdout}
  48     Should Be Equal As Integers  ${rc}  ${success_return_code}
  49     [Return]  ${stdout}
  50
  51
  52 Check for SDNC To Be Deleted
  53     [Arguments]  ${sdnc_name}
  54
  55     ${rc}  ${stdout}=  Run and Return RC and Output  osm sdnc-list | awk '{print $2}' | grep ${sdnc_name}
  56     Should Not Be Equal As Strings   ${stdout}   ${sdnc_name}
  57
  58
  59 Delete SDNC
  60     [Arguments]   ${sdnc_name}
  61
  62     ${rc}  ${stdout}=  Run Keyword And Continue On Failure  Run and Return RC and Output  osm sdnc-delete ${sdnc_name}
  63     log  ${stdout}
  64     Should Be Equal As Integers  ${rc}  ${success_return_code}  msg=${stdout}  values=False
  65     Wait Until Keyword Succeeds  ${delete_max_wait_time}  ${delete_pol_time}  Check for SDNC To Be Deleted  ${sdnc_name}
  66
  67
  68 Get SDNC List
  69     ${rc}  ${stdout}=  Run and Return RC and Output  osm sdnc-list
  70     log  ${stdout}
  71     Should Be Equal As Integers  ${rc}  ${success_return_code}
  72
  73
  74 Check for SDNC
  75     [Arguments]  ${sdnc_id}
  76
  77     ${rc}  ${stdout}=  Run and Return RC and Output  osm sdnc-show ${sdnc_id} | grep -io ENABLED
  78     log  ${stdout}
  79     Should Be Equal As Integers  ${rc}  ${success_return_code}
  80
  81
  82 Check for SDNC Status
  83     [Arguments]  ${sdnc_id}  ${prometheus_host}  ${prometheus_port}
  84
  85     Wait Until Keyword Succeeds  ${sdnc_status_max_wait_time}  ${sdnc_status_pol_time}  Check If SDNC Is Available  ${sdnc_id}  ${prometheus_host}  ${prometheus_port}
  86
  87
  88 Get SDNC ID
  89     [Arguments]  ${sdnc_name}
  90
  91     ${rc}  ${stdout}=  Run and Return RC and Output  osm sdnc-list | grep " ${sdnc_name} " | awk '{print $4}'
  92     Should Be Equal As Integers  ${rc}  ${success_return_code}
  93     Should Not Be Equal As Strings  ${stdout}  ${EMPTY}  msg=SDNC '${sdnc_name}' not found  values=false
  94     [Return]  ${stdout}
  95
  96
  97 Check If SDNC Is Available
  98     [Arguments]  ${sdnc_id}  ${prometheus_host}  ${prometheus_port}
  99
 100     ${metric}=  Get Metric  ${prometheus_host}  ${prometheus_port}  osm_sdnc_status  sdnc_id=${sdnc_id}
 101     Should Be Equal As Integers  ${metric}  1  msg=SDNC '${sdnc_id}' is not active  values=false