robot-systest/testsuite/basic_07-secure_key_management.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation     [BASIC-07] Secure key management.
  15
  16 Library   OperatingSystem
  17 Library   SSHLibrary
  18
  19 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  20 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  23
  24 Variables   %{ROBOT_DEVOPS_FOLDER}/resources/basic_07-secure_key_management_data.py
  25
  26 Suite Teardown   Run Keyword And Ignore Error   Test Cleanup
  27
  28
  29 *** Variables ***
  30 ${username}   ubuntu
  31 ${password}   osm4u
  32 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  33 ${action_name}   touch
  34 ${vnf_member_index}   1
  35 ${day_1_file_name}   /home/ubuntu/first-touch
  36 ${day_2_file_name}   /home/ubuntu/mytouch1
  37
  38
  39 *** Test Cases ***
  40 Create Nopasswd Charm VNF Descriptor
  41     [Tags]  nopasswd
  42
  43     Create VNFD  '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  44
  45
  46 Create Nopasswd Charm NS Descriptor
  47     [Tags]  nopasswd
  48
  49     Create NSD  '%{PACKAGES_FOLDER}/${nsd_pkg}'
  50
  51
  52 Instantiate Nopasswd Charm Network Service
  53     [Tags]  nopasswd
  54
  55     ${id}=  Create Network Service  ${nsd_name}  %{VIM_TARGET}  ${ns_name}  ${ns_config}  ${EMPTY}
  56     Set Suite Variable  ${ns_id}  ${id}
  57
  58
  59 Get Management Ip Addresses
  60     [Tags]  nopasswd
  61
  62     ${ip_addr}  Get Vnf Management Ip Address  ${ns_id}  ${vnf_member_index}
  63     log  ${ip_addr}
  64     Set Suite Variable  ${vnf_ip_addr}  ${ip_addr}
  65
  66
  67 Test SSH Access
  68     [Tags]  nopasswd
  69
  70     Variable Should Exist  ${vnf_ip_addr}  msg=IP address of the management VNF is not available
  71     Sleep  30s  Waiting ssh daemon to be up
  72     Test SSH Connection  ${vnf_ip_addr}  ${username}  ${password}  ${EMPTY}
  73
  74
  75 Check Remote Files Created Via Day 1 Operations
  76     [Documentation]     The Nopasswd VNF has a Day 1 operation that creates a file named ${day_1_file_name} and performs it without password.
  77     ...                 This test checks whether that files have been created or not.
  78     [Tags]  nopasswd
  79
  80     Check If remote File Exists  ${vnf_ip_addr}  ${username}  ${password}  ${EMPTY}  ${day_1_file_name}
  81
  82
  83 Execute Day 2 Operations
  84     [Documentation]     Performs one Day 2 operation that creates a new file, this action is executed without password too.
  85     [Tags]  nopasswd
  86
  87     Variable Should Exist  ${ns_id}  msg=Network service instance is not available
  88     ${ns_op_id}=  Execute NS Action  ${ns_name}  ${action_name}  ${vnf_member_index}  filename=${day_2_file_name}
  89
  90
  91 Check Remote Files Created Via Day 2 Operations
  92     [Documentation]     Check whether the file created in the previous test via Day 2 operation exists or not.
  93     [Tags]  nopasswd
  94
  95     Check If remote File Exists  ${vnf_ip_addr}  ${username}  ${password}  ${EMPTY}  ${day_2_file_name}
  96
  97
  98 Delete NS Instance
  99     [Tags]  nopasswd  cleanup
 100
 101     Delete NS  ${ns_name}
 102
 103
 104 Delete NS Descriptor
 105     [Tags]  nopasswd  cleanup
 106
 107     Delete NSD  ${nsd_name}
 108
 109
 110 Delete VNF Descriptor
 111     [Tags]  nopasswd  cleanup
 112
 113     Delete VNFD  ${vnfd_name}
 114
 115
 116 *** Keywords ***
 117 Test Cleanup
 118     [Documentation]  Test Suite Cleanup: Deleting descriptors and NS instance
 119
 120     Run Keyword If Test Failed  Delete NS  ${ns_name}
 121
 122     Run Keyword If Test Failed  Delete NSD  ${nsd_name}
 123
 124     Run Keyword If Test Failed  Delete VNFD  ${vnfd_name}
 125