robot-systest/testsuite/basic_06-vnf_with_charm.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation     [BASIC-06] VNF with Charm.
  15
  16 Library   OperatingSystem
  17 Library   SSHLibrary
  18
  19 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  20 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  23
  24 Variables   %{ROBOT_DEVOPS_FOLDER}/resources/basic_06-vnf_with_charm_data.py
  25
  26 Suite Teardown   Run Keyword And Ignore Error   Test Cleanup
  27
  28
  29 *** Variables ***
  30 ${username}   ubuntu
  31 ${password}   ${EMPTY}
  32 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  33 ${action_name}   touch
  34 ${vnf_member_index_1}   1
  35 ${vnf_member_index_2}   2
  36 ${day_1_file_name}   /home/ubuntu/first-touch
  37 ${day_2_file_name_1}   /home/ubuntu/mytouch1
  38 ${day_2_file_name_2}   /home/ubuntu/mytouch2
  39
  40
  41 *** Test Cases ***
  42 Create Charm VNF Descriptor
  43     [Tags]  charm
  44
  45     Create VNFD  '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  46
  47
  48 Create Charm NS Descriptor
  49     [Tags]  charm
  50
  51     Create NSD  '%{PACKAGES_FOLDER}/${nsd_pkg}'
  52
  53
  54 Instantiate Charm Network Service
  55     [Tags]  charm
  56
  57     ${id}=  Create Network Service  ${nsd_name}  %{VIM_TARGET}  ${ns_name}  ${ns_config}  ${publickey}
  58     Set Suite Variable  ${ns_id}  ${id}
  59
  60
  61 Get Management Ip Addresses
  62     [Tags]  charm
  63
  64     ${ip_addr_1}  Get Vnf Management Ip Address  ${ns_id}  ${vnf_member_index_1}
  65     log  ${ip_addr_1}
  66     Set Suite Variable  ${vnf_1_ip_addr}  ${ip_addr_1}
  67     ${ip_addr_2}  Get Vnf Management Ip Address  ${ns_id}  ${vnf_member_index_2}
  68     log  ${ip_addr_2}
  69     Set Suite Variable  ${vnf_2_ip_addr}  ${ip_addr_2}
  70
  71
  72 Test SSH Access
  73     [Tags]  charm
  74
  75     Variable Should Exist  ${vnf_1_ip_addr}  msg=IP address of the management VNF '${vnf_member_index_1}' is not available
  76     Variable Should Exist  ${vnf_2_ip_addr}  msg=IP address of the management VNF '${vnf_member_index_2}' is not available
  77     Sleep  30s  Waiting ssh daemon to be up
  78     Test SSH Connection  ${vnf_1_ip_addr}  ${username}  ${password}  ${privatekey}
  79     Test SSH Connection  ${vnf_2_ip_addr}  ${username}  ${password}  ${privatekey}
  80
  81
  82 Check Remote Files Created Via Day 1 Operations
  83     [Documentation]     The Charm VNF has a Day 1 operation that creates a file named ${day_1_file_name}.
  84     ...                 This test checks whether that files have been created or not.
  85     [Tags]  charm
  86
  87     Check If remote File Exists  ${vnf_1_ip_addr}  ${username}  ${password}  ${privatekey}  ${day_1_file_name}
  88     Check If remote File Exists  ${vnf_2_ip_addr}  ${username}  ${password}  ${privatekey}  ${day_1_file_name}
  89
  90
  91 Execute Day 2 Operations
  92     [Documentation]     Performs one Day 2 operation per VNF that creates a new file.
  93     [Tags]  charm
  94
  95     Variable Should Exist  ${ns_id}  msg=Network service instance is not available
  96     ${ns_op_id_1}=  Execute NS Action  ${ns_name}  ${action_name}  ${vnf_member_index_1}  filename=${day_2_file_name_1}
  97     ${ns_op_id_2}=  Execute NS Action  ${ns_name}  ${action_name}  ${vnf_member_index_2}  filename=${day_2_file_name_2}
  98
  99
 100 Check Remote Files Created Via Day 2 Operations
 101     [Documentation]     Check whether the files created in the previous test via Day 2 operations exist or not.
 102     [Tags]  charm
 103
 104     Check If remote File Exists  ${vnf_1_ip_addr}  ${username}  ${password}  ${privatekey}  ${day_2_file_name_1}
 105     Check If remote File Exists  ${vnf_2_ip_addr}  ${username}  ${password}  ${privatekey}  ${day_2_file_name_2}
 106
 107
 108 Delete NS Instance
 109     [Tags]  charm  cleanup
 110
 111     Delete NS  ${ns_name}
 112
 113
 114 Delete NS Descriptor
 115     [Tags]  charm  cleanup
 116
 117     Delete NSD  ${nsd_name}
 118
 119
 120 Delete VNF Descriptor
 121     [Tags]  charm  cleanup
 122
 123     Delete VNFD  ${vnfd_name}
 124
 125
 126 *** Keywords ***
 127 Test Cleanup
 128     [Documentation]  Test Suite Cleanup: Deleting descriptors and NS instance
 129
 130     Run Keyword If Test Failed  Delete NS  ${ns_name}
 131
 132     Run Keyword If Test Failed  Delete NSD  ${nsd_name}
 133
 134     Run Keyword If Test Failed  Delete VNFD  ${vnfd_name}
 135