jenkins/ci-pipelines/ci_stage_3.groovy

   1 /* Copyright ETSI Contributors and Others
   2  *
   3  * All Rights Reserved.
   4  *
   5  *   Licensed under the Apache License, Version 2.0 (the "License"); you may
   6  *   not use this file except in compliance with the License. You may obtain
   7  *   a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *   Unless required by applicable law or agreed to in writing, software
  12  *   distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  13  *   WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  14  *   License for the specific language governing permissions and limitations
  15  *   under the License.
  16  */
  17
  18 properties([
  19     parameters([
  20         string(defaultValue: env.GERRIT_BRANCH, description: '', name: 'GERRIT_BRANCH'),
  21         string(defaultValue: 'system', description: '', name: 'NODE'),
  22         string(defaultValue: '', description: '', name: 'BUILD_FROM_SOURCE'),
  23         string(defaultValue: 'unstable', description: '', name: 'REPO_DISTRO'),
  24         string(defaultValue: '', description: '', name: 'COMMIT_ID'),
  25         string(defaultValue: '-stage_2', description: '', name: 'UPSTREAM_SUFFIX'),
  26         string(defaultValue: 'pubkey.asc', description: '', name: 'REPO_KEY_NAME'),
  27         string(defaultValue: 'release', description: '', name: 'RELEASE'),
  28         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NAME'),
  29         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  30         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  31         string(defaultValue: 'OSMETSI', description: '', name: 'GPG_KEY_NAME'),
  32         string(defaultValue: 'artifactory-osm', description: '', name: 'ARTIFACTORY_SERVER'),
  33         string(defaultValue: 'osm-stage_4', description: '', name: 'DOWNSTREAM_STAGE_NAME'),
  34         string(defaultValue: 'testing-daily', description: '', name: 'DOCKER_TAG'),
  35         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_FAIL'),
  36         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_PASS'),
  37         booleanParam(defaultValue: true, description: '', name: 'SAVE_ARTIFACTS_ON_SMOKE_SUCCESS'),
  38         booleanParam(defaultValue: true, description: '', name: 'DO_STAGE_4'),
  39         booleanParam(defaultValue: true, description: '',  name: 'DO_BUILD'),
  40         booleanParam(defaultValue: true, description: '', name: 'DO_INSTALL'),
  41         booleanParam(defaultValue: true, description: '', name: 'DO_SMOKE'),
  42         booleanParam(defaultValue: true, description: '', name: 'DO_DOCKERPUSH'),
  43         booleanParam(defaultValue: false, description: '', name: 'SAVE_ARTIFACTS_OVERRIDE'),
  44         string(defaultValue: '/home/jenkins/hive/openstack-etsi.rc', description: '', name: 'HIVE_VIM_1'),
  45         booleanParam(defaultValue: false, description: '', name: 'DO_ROBOT'),
  46         string(defaultValue: 'sanity', description: 'sanity/regression are the options', name: 'TEST_NAME'),
  47         string(defaultValue: '/home/jenkins/hive/robot-systest.cfg', description: '', name: 'ROBOT_VIM'),
  48         string(defaultValue: '/home/jenkins/hive/kubeconfig.yaml', description: '', name: 'KUBECONFIG'),
  49         string(defaultValue: '/home/jenkins/hive/clouds.yaml', description: '', name: 'CLOUDS'),
  50         string(defaultValue: 'Default', description: '', name: 'INSTALLER'),
  51     ])
  52 ])
  53
  54
  55 ////////////////////////////////////////////////////////////////////////////////////////
  56 // Helper Functions
  57 ////////////////////////////////////////////////////////////////////////////////////////
  58 def run_robot_systest(tagName,testName,osmHostname,prometheusHostname,prometheus_port=null,envfile=null,kubeconfig=null,clouds=null,hostfile=null,jujuPassword=null) {
  59     tempdir = sh(returnStdout: true, script: "mktemp -d").trim()
  60     if ( !envfile )
  61     {
  62         sh(script: "touch ${tempdir}/env")
  63         envfile="${tempdir}/env"
  64     }
  65     PROMETHEUS_PORT_VAR = ""
  66     if ( prometheusPort != null) {
  67         PROMETHEUS_PORT_VAR = "--env PROMETHEUS_PORT="+prometheusPort
  68     }
  69     hostfilemount=""
  70     if ( hostfile ) {
  71         hostfilemount="-v "+hostfile+":/etc/hosts"
  72     }
  73
  74     JUJU_PASSWORD_VAR = ""
  75     if ( jujuPassword != null) {
  76         JUJU_PASSWORD_VAR = "--env JUJU_PASSWORD="+jujuPassword
  77     }
  78
  79     try {
  80         sh "docker run --env OSM_HOSTNAME=${osmHostname} --env PROMETHEUS_HOSTNAME=${prometheusHostname} ${PROMETHEUS_PORT_VAR} ${JUJU_PASSWORD_VAR} --env-file ${envfile} -v ${clouds}:/etc/openstack/clouds.yaml -v ${kubeconfig}:/root/.kube/config -v ${tempdir}:/robot-systest/reports ${hostfilemount} opensourcemano/tests:${tagName} -c -t ${testName}"
  81     } finally {
  82         sh "cp ${tempdir}/* ."
  83         outputDirectory = sh(returnStdout: true, script: "pwd").trim()
  84         println ("Present Directory is : ${outputDirectory}")
  85         step([
  86             $class : 'RobotPublisher',
  87             outputPath : "${outputDirectory}",
  88             outputFileName : "*.xml",
  89             disableArchiveOutput : false,
  90             reportFileName : "report.html",
  91             logFileName : "log.html",
  92             passThreshold : 0,
  93             unstableThreshold: 0,
  94             otherFiles : "*.png",
  95         ])
  96     }
  97 }
  98
  99 def archive_logs(remote) {
 100
 101     sshCommand remote: remote, command: '''mkdir -p logs'''
 102     if (useCharmedInstaller) {
 103         sshCommand remote: remote, command: '''
 104             for container in `kubectl get pods -n osm | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 105                 logfile=`echo $container | cut -d- -f1`
 106                 echo "Extracting log for $logfile"
 107                 kubectl logs -n osm $container --timestamps=true 2>&1 > logs/$logfile.log
 108             done
 109         '''
 110     } else {
 111         sshCommand remote: remote, command: '''
 112             for deployment in `kubectl -n osm get deployments | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 113                 echo "Extracting log for $deployment"
 114                 kubectl -n osm logs deployments/$deployment --timestamps=true --all-containers 2>&1 > logs/$deployment.log
 115             done
 116         '''
 117         sshCommand remote: remote, command: '''
 118             for statefulset in `kubectl -n osm get statefulsets | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 119                 echo "Extracting log for $statefulset"
 120                 kubectl -n osm logs statefulsets/$statefulset --timestamps=true --all-containers 2>&1 > logs/$statefulset.log
 121             done
 122         '''
 123     }
 124
 125     sh "rm -rf logs"
 126     sshCommand remote: remote, command: '''ls -al logs'''
 127     sshGet remote: remote, from: 'logs', into: '.', override: true
 128     sh "cp logs/* ."
 129     archiveArtifacts artifacts: '*.log'
 130 }
 131
 132 def get_value(key, output) {
 133     for (String line : output.split( '\n' )) {
 134         data = line.split( '\\|' )
 135         if (data.length > 1) {
 136             if ( data[1].trim() == key ) {
 137                 return data[2].trim()
 138             }
 139         }
 140     }
 141 }
 142
 143 ////////////////////////////////////////////////////////////////////////////////////////
 144 // Main Script
 145 ////////////////////////////////////////////////////////////////////////////////////////
 146 node("${params.NODE}") {
 147
 148     INTERNAL_DOCKER_REGISTRY = 'osm.etsi.org:5050/devops/cicd/'
 149     INTERNAL_DOCKER_PROXY = 'http://172.21.1.1:5000'
 150     SSH_KEY = '~/hive/cicd_rsa'
 151     sh 'env'
 152
 153     tag_or_branch = params.GERRIT_BRANCH.replaceAll(/\./,"")
 154
 155     stage("Checkout") {
 156         checkout scm
 157     }
 158
 159     ci_helper = load "jenkins/ci-pipelines/ci_helper.groovy"
 160
 161     def upstream_main_job = params.UPSTREAM_SUFFIX
 162
 163     // upstream jobs always use merged artifacts
 164     upstream_main_job += '-merge'
 165     container_name_prefix = "osm-${tag_or_branch}"
 166     container_name = "${container_name_prefix}"
 167
 168     keep_artifacts = false
 169     if ( JOB_NAME.contains('merge') ) {
 170         container_name += "-merge"
 171
 172         // On a merge job, we keep artifacts on smoke success
 173         keep_artifacts = params.SAVE_ARTIFACTS_ON_SMOKE_SUCCESS
 174     }
 175     container_name += "-${BUILD_NUMBER}"
 176
 177     server_id = null
 178     http_server_name = null
 179     devopstempdir = null
 180     useCharmedInstaller = params.INSTALLER.equalsIgnoreCase("charmed")
 181
 182     try {
 183         builtModules = [:]
 184 ///////////////////////////////////////////////////////////////////////////////////////
 185 // Fetch stage 2 .deb artifacts
 186 ///////////////////////////////////////////////////////////////////////////////////////
 187         stage("Copy Artifacts") {
 188             // cleanup any previous repo
 189             sh 'rm -rf repo'
 190             dir("repo") {
 191                 packageList = []
 192                 dir("${RELEASE}") {
 193                     RELEASE_DIR = sh(returnStdout:true,  script: 'pwd').trim()
 194
 195                     // check if an upstream artifact based on specific build number has been requested
 196                     // This is the case of a merge build and the upstream merge build is not yet complete (it is not deemed
 197                     // a successful build yet). The upstream job is calling this downstream job (with the its build artifiact)
 198                     def upstreamComponent=""
 199                     if ( params.UPSTREAM_JOB_NAME ) {
 200                         println("Fetching upstream job artifact from ${params.UPSTREAM_JOB_NAME}")
 201
 202                         step ([$class: 'CopyArtifact',
 203                                projectName: "${params.UPSTREAM_JOB_NAME}",
 204                                selector: [$class: 'SpecificBuildSelector',
 205                                buildNumber: "${params.UPSTREAM_JOB_NUMBER}"]
 206                               ])
 207
 208                         upstreamComponent = ci_helper.get_mdg_from_project(
 209                             ci_helper.get_env_value('build.env','GERRIT_PROJECT'))
 210                         def buildNumber = ci_helper.get_env_value('build.env','BUILD_NUMBER')
 211                         dir("$upstreamComponent") {
 212                             // the upstream job name contains suffix with the project. Need this stripped off
 213                             def project_without_branch = params.UPSTREAM_JOB_NAME.split('/')[0]
 214                             def packages = ci_helper.get_archive(params.ARTIFACTORY_SERVER,
 215                                 upstreamComponent,
 216                                 GERRIT_BRANCH,
 217                                 "${project_without_branch} :: ${GERRIT_BRANCH}",
 218                                 buildNumber)
 219
 220                             packageList.addAll(packages)
 221                             println("Fetched pre-merge ${params.UPSTREAM_JOB_NAME}: ${packages}")
 222                         }
 223                     }
 224
 225                     parallelSteps = [:]
 226                     def list = ["RO", "osmclient", "IM", "devops", "MON", "N2VC", "NBI", "common", "LCM", "POL", "NG-UI", "PLA", "tests"]
 227                     if (upstreamComponent.length()>0) {
 228                         println("Skipping upstream fetch of "+upstreamComponent)
 229                         list.remove(upstreamComponent)
 230                     }
 231                     for (buildStep in list) {
 232                         def component = buildStep
 233                         parallelSteps[component] = {
 234                             dir("$component") {
 235                                 println("Fetching artifact for ${component}")
 236                                 step ([$class: 'CopyArtifact',
 237                                        projectName: "${component}${upstream_main_job}/${GERRIT_BRANCH}"])
 238
 239                                 // grab the archives from the stage_2 builds (ie. this will be the artifacts stored based on a merge)
 240                                 def packages = ci_helper.get_archive(params.ARTIFACTORY_SERVER,
 241                                     component,
 242                                     GERRIT_BRANCH,
 243                                     "${component}${upstream_main_job} :: ${GERRIT_BRANCH}",
 244                                     ci_helper.get_env_value('build.env','BUILD_NUMBER'))
 245                                 packageList.addAll(packages)
 246                                 println("Fetched ${component}: ${packages}")
 247                                 sh "rm -rf dists"
 248                             }
 249                         }
 250                     }
 251                     parallel parallelSteps
 252
 253 ///////////////////////////////////////////////////////////////////////////////////////
 254 // Create APT repository
 255 ///////////////////////////////////////////////////////////////////////////////////////
 256                     sh "mkdir -p pool"
 257                     for (component in [ "devops", "IM", "osmclient" ]) {
 258                         sh "ls -al ${component}/pool/"
 259                         sh "cp -r ${component}/pool/* pool/"
 260                         sh "dpkg-sig --sign builder -k ${GPG_KEY_NAME} pool/${component}/*"
 261                         sh "mkdir -p dists/${params.REPO_DISTRO}/${component}/binary-amd64/"
 262                         sh "apt-ftparchive packages pool/${component} > dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 263                         sh "gzip -9fk dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 264                     }
 265                     // create and sign the release file
 266                     sh "apt-ftparchive release dists/${params.REPO_DISTRO} > dists/${params.REPO_DISTRO}/Release"
 267                     sh "gpg --yes -abs -u ${GPG_KEY_NAME} -o dists/${params.REPO_DISTRO}/Release.gpg dists/${params.REPO_DISTRO}/Release"
 268
 269                     // copy the public key into the release folder
 270                     // this pulls the key from the home dir of the current user (jenkins)
 271                     sh "cp ~/${REPO_KEY_NAME} 'OSM ETSI Release Key.gpg'"
 272                     sh "cp ~/${REPO_KEY_NAME} ."
 273                 }
 274
 275                 // start an apache server to serve up the packages
 276                 http_server_name = "${container_name}-apache"
 277
 278                 pwd = sh(returnStdout:true,  script: 'pwd').trim()
 279                 repo_port = sh(script: 'echo $(python -c \'import socket; s=socket.socket(); s.bind(("", 0)); print(s.getsockname()[1]); s.close()\');', returnStdout: true).trim()
 280                 repo_base_url = ci_helper.start_http_server(pwd,http_server_name,repo_port)
 281                 NODE_IP_ADDRESS=sh(returnStdout: true, script:
 282                     "echo ${SSH_CONNECTION} | awk '{print \$3}'").trim()
 283             }
 284
 285             // Unpack devops package into temporary location so that we use it from upstream if it was part of a patch
 286             osm_devops_dpkg = sh(returnStdout: true, script: "find ./repo/release/pool/ -name osm-devops*.deb").trim()
 287             devopstempdir = sh(returnStdout: true, script: "mktemp -d").trim()
 288             println("Extracting local devops package ${osm_devops_dpkg} into ${devopstempdir} for docker build step")
 289             sh "dpkg -x ${osm_devops_dpkg} ${devopstempdir}"
 290             OSM_DEVOPS="${devopstempdir}/usr/share/osm-devops"
 291             // Convert URLs from stage 2 packages to arguments that can be passed to docker build
 292             for (remotePath in packageList) {
 293                 packageName=remotePath.substring(remotePath.lastIndexOf('/')+1)
 294                 packageName=packageName.substring(0,packageName.indexOf('_'))
 295                 builtModules[packageName]=remotePath
 296             }
 297         }
 298
 299 ///////////////////////////////////////////////////////////////////////////////////////
 300 // Build docker containers
 301 ///////////////////////////////////////////////////////////////////////////////////////
 302         dir(OSM_DEVOPS) {
 303             def remote = [:]
 304             error = null
 305             if ( params.DO_BUILD ) {
 306                 withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'gitlab-registry',
 307                                 usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
 308                     sh "docker login ${INTERNAL_DOCKER_REGISTRY} -u ${USERNAME} -p ${PASSWORD}"
 309                 }
 310                 moduleBuildArgs = ""
 311                 for (packageName in builtModules.keySet()) {
 312                     envName=packageName.replaceAll("-","_").toUpperCase()+"_URL"
 313                     moduleBuildArgs += " --build-arg ${envName}=" + builtModules[packageName]
 314                 }
 315                 dir ("docker") {
 316                     stage("Build") {
 317                         containerList = sh(returnStdout: true, script:
 318                             "find . -name Dockerfile -printf '%h\\n' | sed 's|\\./||'")
 319                         containerList=Arrays.asList(containerList.split("\n"))
 320                         print(containerList)
 321                         parallelSteps = [:]
 322                         for (buildStep in containerList) {
 323                             def module = buildStep
 324                             def moduleName = buildStep.toLowerCase()
 325                             def moduleTag = container_name
 326                             parallelSteps[module] = {
 327                                 dir("$module") {
 328                                     sh "docker build -t opensourcemano/${moduleName}:${moduleTag} ${moduleBuildArgs} ."
 329                                     println("Tagging ${moduleName}:${moduleTag}")
 330                                     sh "docker tag opensourcemano/${moduleName}:${moduleTag} ${INTERNAL_DOCKER_REGISTRY}opensourcemano/${moduleName}:${moduleTag}"
 331                                     sh "docker push ${INTERNAL_DOCKER_REGISTRY}opensourcemano/${moduleName}:${moduleTag}"
 332                                 }
 333                             }
 334                         }
 335                         parallel parallelSteps
 336                     }
 337                 }
 338             } // if ( params.DO_BUILD )
 339
 340             if ( params.DO_INSTALL ) {
 341 ///////////////////////////////////////////////////////////////////////////////////////
 342 // Launch VM
 343 ///////////////////////////////////////////////////////////////////////////////////////
 344                 stage("Spawn Remote VM") {
 345                     println("Launching new VM")
 346                     output=sh(returnStdout: true, script: """#!/bin/sh -e
 347                         for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 348                         openstack server create --flavor osm.sanity \
 349                                                 --image ubuntu18.04 \
 350                                                 --key-name CICD \
 351                                                 --property build_url="${BUILD_URL}" \
 352                                                 --nic net-id=osm-ext \
 353                                                 ${container_name}
 354                     """).trim()
 355
 356                     server_id = get_value('id', output)
 357
 358                     if (server_id == null) {
 359                         println("VM launch output: ")
 360                         println(output)
 361                         throw new Exception("VM Launch failed")
 362                     }
 363                     println("Target VM is ${server_id}, waiting for IP address to be assigned")
 364
 365                     IP_ADDRESS = ""
 366
 367                     while (IP_ADDRESS == "") {
 368                         output=sh(returnStdout: true, script: """#!/bin/sh -e
 369                             for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 370                             openstack server show ${server_id}
 371                         """).trim()
 372                         IP_ADDRESS = get_value('addresses', output)
 373                     }
 374                     IP_ADDRESS = IP_ADDRESS.split('=')[1]
 375                     println("Waiting for VM at ${IP_ADDRESS} to be reachable")
 376
 377                     alive = false
 378                     while (! alive) {
 379                         output=sh(returnStdout: true, script: "sleep 1 ; nc -zv ${IP_ADDRESS} 22 2>&1 || true").trim()
 380                         println("output is [$output]")
 381                         alive = output.contains("succeeded")
 382                     }
 383                     println("VM is ready and accepting ssh connections")
 384                 } // stage("Spawn Remote VM")
 385
 386 ///////////////////////////////////////////////////////////////////////////////////////
 387 // Installation
 388 ///////////////////////////////////////////////////////////////////////////////////////
 389                 stage("Install") {
 390                     commit_id = ''
 391                     repo_distro = ''
 392                     repo_key_name = ''
 393                     release = ''
 394
 395                     if ( params.COMMIT_ID )
 396                     {
 397                         commit_id = "-b ${params.COMMIT_ID}"
 398                     }
 399
 400                     if ( params.REPO_DISTRO )
 401                     {
 402                         repo_distro = "-r ${params.REPO_DISTRO}"
 403                     }
 404
 405                     if ( params.REPO_KEY_NAME )
 406                     {
 407                         repo_key_name = "-k ${params.REPO_KEY_NAME}"
 408                     }
 409
 410                     if ( params.RELEASE )
 411                     {
 412                         release = "-R ${params.RELEASE}"
 413                     }
 414
 415                     if ( params.REPOSITORY_BASE )
 416                     {
 417                         repo_base_url = "-u ${params.REPOSITORY_BASE}"
 418                     }
 419                     else
 420                     {
 421                         repo_base_url = "-u http://${NODE_IP_ADDRESS}:${repo_port}"
 422                     }
 423
 424                     remote.name = container_name
 425                     remote.host = IP_ADDRESS
 426                     remote.user = 'ubuntu'
 427                     remote.identityFile = SSH_KEY
 428                     remote.allowAnyHosts = true
 429                     remote.logLevel = 'INFO'
 430                     remote.pty = true
 431
 432                     sshCommand remote: remote, command: """
 433                         wget https://osm-download.etsi.org/ftp/osm-9.0-nine/install_osm.sh
 434                         chmod +x ./install_osm.sh
 435                         sed -i '1 i\\export PATH=/snap/bin:\${PATH}' ~/.bashrc
 436                     """
 437
 438                     if ( useCharmedInstaller ) {
 439                         // Use local proxy for docker hub
 440                         sshCommand remote: remote, command: '''
 441                             sudo snap install microk8s --classic --channel=1.19/stable
 442                             sudo sed -i "s|https://registry-1.docker.io|http://172.21.1.1:5000|" /var/snap/microk8s/current/args/containerd-template.toml
 443                             sudo systemctl restart snap.microk8s.daemon-containerd.service
 444                             sudo snap alias microk8s.kubectl kubectl
 445                         '''
 446
 447                         withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'gitlab-registry',
 448                                         usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
 449                             sshCommand remote: remote, command: """
 450                                 ./install_osm.sh -y \
 451                                     ${repo_base_url} \
 452                                     ${repo_key_name} \
 453                                     ${release} -r unstable \
 454                                     --charmed  \
 455                                     --registry ${USERNAME}:${PASSWORD}@${INTERNAL_DOCKER_REGISTRY} \
 456                                     --tag ${container_name}
 457                             """
 458                         }
 459                         prometheusHostname = "prometheus."+IP_ADDRESS+".nip.io"
 460                         prometheusPort = 80
 461                         osmHostname = "nbi."+IP_ADDRESS+".nip.io:443"
 462                     } else {
 463                         // Run -k8s installer here specifying internal docker registry and docker proxy
 464                         withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'gitlab-registry',
 465                                         usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
 466                             sshCommand remote: remote, command: """
 467                                 ./install_osm.sh -y \
 468                                     ${repo_base_url} \
 469                                     ${repo_key_name} \
 470                                     ${release} -r unstable \
 471                                     -d ${USERNAME}:${PASSWORD}@${INTERNAL_DOCKER_REGISTRY} \
 472                                     -p ${INTERNAL_DOCKER_PROXY} \
 473                                     -t ${container_name}
 474                             """
 475                         }
 476                         prometheusHostname = IP_ADDRESS
 477                         prometheusPort = 9091
 478                         osmHostname = IP_ADDRESS
 479                     }
 480                 } // stage("Install")
 481             } // if ( params.DO_INSTALL )
 482
 483 ///////////////////////////////////////////////////////////////////////////////////////
 484 // Health check of installed OSM in remote vm
 485 ///////////////////////////////////////////////////////////////////////////////////////
 486             if ( params.DO_SMOKE ) {
 487                 stage("OSM Health") {
 488                     stackName = "osm"
 489                     sshCommand remote: remote, command: """
 490                         /usr/share/osm-devops/installers/osm_health.sh -k -s ${stackName}
 491                     """
 492                 }
 493             }
 494
 495 ///////////////////////////////////////////////////////////////////////////////////////
 496 // Execute Robot tests
 497 ///////////////////////////////////////////////////////////////////////////////////////
 498             stage_archive = false
 499             if ( params.DO_STAGE_4 ) {
 500                 try {
 501                     stage("System Integration Test") {
 502                         if ( params.DO_ROBOT ) {
 503                             if( useCharmedInstaller ) {
 504                                 tempdir = sh(returnStdout: true, script: "mktemp -d").trim()
 505                                 sh(script: "touch ${tempdir}/hosts")
 506                                 hostfile="${tempdir}/hosts"
 507                                 sh """cat << EOF > ${hostfile}
 508 127.0.0.1           localhost
 509 ${remote.host}      prometheus.${remote.host}.nip.io nbi.${remote.host}.nip.io
 510 EOF"""
 511                             } else {
 512                                 hostfile=null
 513                             }
 514
 515                             jujuPassword=sshCommand remote: remote, command: """
 516                                 echo `juju gui 2>&1 | grep password | cut -d: -f2`
 517                             """
 518
 519                             run_robot_systest(
 520                                 container_name,
 521                                 params.TEST_NAME,
 522                                 osmHostname,
 523                                 prometheusHostname,
 524                                 prometheusPort,
 525                                 params.ROBOT_VIM,
 526                                 params.KUBECONFIG,
 527                                 params.CLOUDS,
 528                                 hostfile,
 529                                 jujuPassword)
 530                         }
 531                     } // stage("System Integration Test")
 532                 } finally {
 533                     stage("Archive Container Logs") {
 534                         // Archive logs to containers_logs.txt
 535                         archive_logs(remote)
 536                         if ( ! currentBuild.result.equals('UNSTABLE') && ! currentBuild.result.equals('FAILURE')) {
 537                             stage_archive = keep_artifacts
 538                         } else {
 539                             println ("Systest test failed, throwing error")
 540                             error = new Exception("Systest test failed")
 541                             currentBuild.result = 'FAILURE'
 542                             throw error
 543                         }
 544                     }
 545                 }
 546             } // if ( params.DO_STAGE_4 )
 547
 548             if ( params.SAVE_ARTIFACTS_OVERRIDE || stage_archive ) {
 549                 stage("Archive") {
 550                     sh "echo ${container_name} > build_version.txt"
 551                     archiveArtifacts artifacts: "build_version.txt", fingerprint: true
 552
 553                     // Archive the tested repo
 554                     dir("${RELEASE_DIR}") {
 555                         ci_helper.archive(params.ARTIFACTORY_SERVER,RELEASE,GERRIT_BRANCH,'tested')
 556                     }
 557                     if ( params.DO_DOCKERPUSH ) {
 558                         stage("Publish to Dockerhub") {
 559                             parallelSteps = [:]
 560                             for (buildStep in containerList) {
 561                                 def module = buildStep
 562                                 def moduleName = buildStep.toLowerCase()
 563                                 def dockerTag = params.DOCKER_TAG
 564                                 def moduleTag = container_name
 565
 566                                 parallelSteps[module] = {
 567                                     dir("$module") {
 568                                         sh "docker tag opensourcemano/${moduleName}:${moduleTag} opensourcemano/${moduleName}:${dockerTag}"
 569                                         sh "docker push opensourcemano/${moduleName}:${dockerTag}"
 570                                     }
 571                                 }
 572                             }
 573                             parallel parallelSteps
 574                         }
 575
 576                         stage("Snap promotion") {
 577                             def snaps = ["osmclient"]
 578                             sh "snapcraft login --with ~/.snapcraft/config"
 579                             for (snap in snaps) {
 580                                 channel="latest/"
 581                                 if (BRANCH_NAME.startsWith("v")) {
 582                                     channel=BRANCH_NAME.substring(1)+"/"
 583                                 } else if (BRANCH_NAME!="master") {
 584                                     channel+="/"+BRANCH_NAME.replaceAll('/','-')
 585                                 }
 586                                 track=channel+"edge\\*"
 587                                 edge_rev=sh(returnStdout: true,
 588                                     script: "snapcraft revisions $snap | " +
 589                                     "grep \"$track\" | tail -1 | awk '{print \$1}'").trim()
 590                                 print "edge rev is $edge_rev"
 591                                 track=channel+"beta\\*"
 592                                 beta_rev=sh(returnStdout: true,
 593                                     script: "snapcraft revisions $snap | " +
 594                                     "grep \"$track\" | tail -1 | awk '{print \$1}'").trim()
 595                                 print "beta rev is $beta_rev"
 596
 597                                 if ( edge_rev != beta_rev ) {
 598                                     print "Promoting $edge_rev to beta in place of $beta_rev"
 599                                     beta_track=channel+"beta"
 600                                     sh "snapcraft release $snap $edge_rev $beta_track"
 601                                 }
 602                             }
 603                         } // stage("Snap promotion")
 604                     } // if ( params.DO_DOCKERPUSH )
 605                 } // stage("Archive")
 606             } // if ( params.SAVE_ARTIFACTS_OVERRIDE || stage_archive )
 607         } // dir(OSM_DEVOPS)
 608     } finally {
 609         if ( params.DO_INSTALL && server_id != null) {
 610             delete_vm = true
 611             if (error && params.SAVE_CONTAINER_ON_FAIL ) {
 612                 delete_vm = false
 613             }
 614             if (!error && params.SAVE_CONTAINER_ON_PASS ) {
 615                 delete_vm = false
 616             }
 617
 618             if ( delete_vm ) {
 619                 if (server_id != null) {
 620                     println("Deleting VM: $server_id")
 621                     sh """#!/bin/sh -e
 622                         for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 623                         openstack server delete ${server_id}
 624                     """
 625                 } else {
 626                     println("Saved VM $server_id in ETSI VIM")
 627                 }
 628             }
 629         }
 630         if ( http_server_name != null ) {
 631             sh "docker stop ${http_server_name} || true"
 632             sh "docker rm ${http_server_name} || true"
 633         }
 634
 635         if ( devopstempdir != null ) {
 636             sh "rm -rf ${devopstempdir}"
 637         }
 638     }
 639 }