jenkins/ci-pipelines/ci_stage_3.groovy

   1 /* Copyright ETSI Contributors and Others
   2  *
   3  * All Rights Reserved.
   4  *
   5  *   Licensed under the Apache License, Version 2.0 (the "License"); you may
   6  *   not use this file except in compliance with the License. You may obtain
   7  *   a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *   Unless required by applicable law or agreed to in writing, software
  12  *   distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  13  *   WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  14  *   License for the specific language governing permissions and limitations
  15  *   under the License.
  16  */
  17
  18 properties([
  19     parameters([
  20         string(defaultValue: env.GERRIT_BRANCH, description: '', name: 'GERRIT_BRANCH'),
  21         string(defaultValue: 'system', description: '', name: 'NODE'),
  22         string(defaultValue: '', description: '', name: 'BUILD_FROM_SOURCE'),
  23         string(defaultValue: 'unstable', description: '', name: 'REPO_DISTRO'),
  24         string(defaultValue: '', description: '', name: 'COMMIT_ID'),
  25         string(defaultValue: '-stage_2', description: '', name: 'UPSTREAM_SUFFIX'),
  26         string(defaultValue: 'pubkey.asc', description: '', name: 'REPO_KEY_NAME'),
  27         string(defaultValue: 'release', description: '', name: 'RELEASE'),
  28         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NAME'),
  29         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  30         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  31         string(defaultValue: 'OSMETSI', description: '', name: 'GPG_KEY_NAME'),
  32         string(defaultValue: 'artifactory-osm', description: '', name: 'ARTIFACTORY_SERVER'),
  33         string(defaultValue: 'osm-stage_4', description: '', name: 'DOWNSTREAM_STAGE_NAME'),
  34         string(defaultValue: 'testing-daily', description: '', name: 'DOCKER_TAG'),
  35         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_FAIL'),
  36         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_PASS'),
  37         booleanParam(defaultValue: true, description: '', name: 'SAVE_ARTIFACTS_ON_SMOKE_SUCCESS'),
  38         booleanParam(defaultValue: true, description: '', name: 'DO_STAGE_4'),
  39         booleanParam(defaultValue: true, description: '',  name: 'DO_BUILD'),
  40         booleanParam(defaultValue: true, description: '', name: 'DO_INSTALL'),
  41         booleanParam(defaultValue: true, description: '', name: 'DO_SMOKE'),
  42         booleanParam(defaultValue: true, description: '', name: 'DO_DOCKERPUSH'),
  43         booleanParam(defaultValue: false, description: '', name: 'SAVE_ARTIFACTS_OVERRIDE'),
  44         string(defaultValue: '/home/jenkins/hive/openstack-etsi.rc', description: '', name: 'HIVE_VIM_1'),
  45         booleanParam(defaultValue: false, description: '', name: 'DO_ROBOT'),
  46         string(defaultValue: 'sanity', description: 'sanity/regression are the options', name: 'TEST_NAME'),
  47         string(defaultValue: '/home/jenkins/hive/robot-systest.cfg', description: '', name: 'ROBOT_VIM'),
  48         string(defaultValue: '/home/jenkins/hive/kubeconfig.yaml', description: '', name: 'KUBECONFIG'),
  49         string(defaultValue: '/home/jenkins/hive/clouds.yaml', description: '', name: 'CLOUDS'),
  50         string(defaultValue: 'Default', description: '', name: 'INSTALLER'),
  51     ])
  52 ])
  53
  54
  55 ////////////////////////////////////////////////////////////////////////////////////////
  56 // Helper Functions
  57 ////////////////////////////////////////////////////////////////////////////////////////
  58 def run_robot_systest(tagName,testName,osmHostname,prometheusHostname,prometheus_port=null,envfile=null,kubeconfig=null,clouds=null,hostfile=null,jujuPassword=null) {
  59     tempdir = sh(returnStdout: true, script: "mktemp -d").trim()
  60     if ( !envfile )
  61     {
  62         sh(script: "touch ${tempdir}/env")
  63         envfile="${tempdir}/env"
  64     }
  65     PROMETHEUS_PORT_VAR = ""
  66     if ( prometheusPort != null) {
  67         PROMETHEUS_PORT_VAR = "--env PROMETHEUS_PORT="+prometheusPort
  68     }
  69     hostfilemount=""
  70     if ( hostfile ) {
  71         hostfilemount="-v "+hostfile+":/etc/hosts"
  72     }
  73
  74     JUJU_PASSWORD_VAR = ""
  75     if ( jujuPassword != null) {
  76         JUJU_PASSWORD_VAR = "--env JUJU_PASSWORD="+jujuPassword
  77     }
  78
  79     try {
  80         sh "docker run --env OSM_HOSTNAME=${osmHostname} --env PROMETHEUS_HOSTNAME=${prometheusHostname} ${PROMETHEUS_PORT_VAR} ${JUJU_PASSWORD_VAR} --env-file ${envfile} -v ${clouds}:/etc/openstack/clouds.yaml -v ${kubeconfig}:/root/.kube/config -v ${tempdir}:/robot-systest/reports ${hostfilemount} opensourcemano/tests:${tagName} -c -t ${testName}"
  81     } finally {
  82         sh "cp ${tempdir}/* ."
  83         outputDirectory = sh(returnStdout: true, script: "pwd").trim()
  84         println ("Present Directory is : ${outputDirectory}")
  85         step([
  86             $class : 'RobotPublisher',
  87             outputPath : "${outputDirectory}",
  88             outputFileName : "*.xml",
  89             disableArchiveOutput : false,
  90             reportFileName : "report.html",
  91             logFileName : "log.html",
  92             passThreshold : 0,
  93             unstableThreshold: 0,
  94             otherFiles : "*.png",
  95         ])
  96     }
  97 }
  98
  99 def archive_logs(remote) {
 100
 101     sshCommand remote: remote, command: '''mkdir -p logs'''
 102     if (useCharmedInstaller) {
 103         sshCommand remote: remote, command: '''
 104             for container in `kubectl get pods -n osm | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 105                 logfile=`echo $container | cut -d- -f1`
 106                 echo "Extracting log for $logfile"
 107                 kubectl logs -n osm $container --timestamps=true 2>&1 > logs/$logfile.log
 108             done
 109         '''
 110     } else {
 111         sshCommand remote: remote, command: '''
 112             for deployment in `kubectl -n osm get deployments | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 113                 echo "Extracting log for $deployment"
 114                 kubectl -n osm logs deployments/$deployment --timestamps=true --all-containers 2>&1 > logs/$deployment.log
 115             done
 116         '''
 117         sshCommand remote: remote, command: '''
 118             for statefulset in `kubectl -n osm get statefulsets | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 119                 echo "Extracting log for $statefulset"
 120                 kubectl -n osm logs statefulsets/$statefulset --timestamps=true --all-containers 2>&1 > logs/$statefulset.log
 121             done
 122         '''
 123     }
 124
 125     sh "rm -rf logs"
 126     sshCommand remote: remote, command: '''ls -al logs'''
 127     sshGet remote: remote, from: 'logs', into: '.', override: true
 128     sh "cp logs/* ."
 129     archiveArtifacts artifacts: '*.log'
 130 }
 131
 132 def get_value(key, output) {
 133     for (String line : output.split( '\n' )) {
 134         data = line.split( '\\|' )
 135         if (data.length > 1) {
 136             if ( data[1].trim() == key ) {
 137                 return data[2].trim()
 138             }
 139         }
 140     }
 141 }
 142
 143 ////////////////////////////////////////////////////////////////////////////////////////
 144 // Main Script
 145 ////////////////////////////////////////////////////////////////////////////////////////
 146 node("${params.NODE}") {
 147
 148     INTERNAL_DOCKER_REGISTRY = 'osm.etsi.org:5050/devops/cicd/'
 149     INTERNAL_DOCKER_PROXY = 'http://172.21.1.1:5000'
 150     SSH_KEY = '~/hive/cicd_rsa'
 151     sh 'env'
 152
 153     tag_or_branch = params.GERRIT_BRANCH.replaceAll(/\./,"")
 154
 155     stage("Checkout") {
 156         checkout scm
 157     }
 158
 159     ci_helper = load "jenkins/ci-pipelines/ci_helper.groovy"
 160
 161     def upstream_main_job = params.UPSTREAM_SUFFIX
 162
 163     // upstream jobs always use merged artifacts
 164     upstream_main_job += '-merge'
 165     container_name_prefix = "osm-${tag_or_branch}"
 166     container_name = "${container_name_prefix}"
 167
 168     keep_artifacts = false
 169     if ( JOB_NAME.contains('merge') ) {
 170         container_name += "-merge"
 171
 172         // On a merge job, we keep artifacts on smoke success
 173         keep_artifacts = params.SAVE_ARTIFACTS_ON_SMOKE_SUCCESS
 174     }
 175     container_name += "-${BUILD_NUMBER}"
 176
 177     server_id = null
 178     http_server_name = null
 179     devopstempdir = null
 180     useCharmedInstaller = params.INSTALLER.equalsIgnoreCase("charmed")
 181
 182     try {
 183         builtModules = [:]
 184 ///////////////////////////////////////////////////////////////////////////////////////
 185 // Fetch stage 2 .deb artifacts
 186 ///////////////////////////////////////////////////////////////////////////////////////
 187         stage("Copy Artifacts") {
 188             // cleanup any previous repo
 189             sh 'rm -rf repo'
 190             dir("repo") {
 191                 packageList = []
 192                 dir("${RELEASE}") {
 193                     RELEASE_DIR = sh(returnStdout:true,  script: 'pwd').trim()
 194
 195                     // check if an upstream artifact based on specific build number has been requested
 196                     // This is the case of a merge build and the upstream merge build is not yet complete (it is not deemed
 197                     // a successful build yet). The upstream job is calling this downstream job (with the its build artifiact)
 198                     def upstreamComponent=""
 199                     if ( params.UPSTREAM_JOB_NAME ) {
 200                         println("Fetching upstream job artifact from ${params.UPSTREAM_JOB_NAME}")
 201
 202                         step ([$class: 'CopyArtifact',
 203                                projectName: "${params.UPSTREAM_JOB_NAME}",
 204                                selector: [$class: 'SpecificBuildSelector', buildNumber: "${params.UPSTREAM_JOB_NUMBER}"]
 205                               ])
 206
 207                         upstreamComponent = ci_helper.get_mdg_from_project(ci_helper.get_env_value('build.env','GERRIT_PROJECT'))
 208
 209                         // the upstream job name contains suffix with the project. Need this stripped off
 210                         def project_without_branch = params.UPSTREAM_JOB_NAME.split('/')[0]
 211                         def packages = ci_helper.get_archive(params.ARTIFACTORY_SERVER,
 212                             upstreamComponent,
 213                             GERRIT_BRANCH,
 214                             "${project_without_branch} :: ${GERRIT_BRANCH}",
 215                             ci_helper.get_env_value('build.env','BUILD_NUMBER'))
 216
 217                         packageList.addAll(packages)
 218                         println("${params.UPSTREAM_JOB_NAME}: ${packages}")
 219                     }
 220
 221                     parallelSteps = [:]
 222                     def list = ["RO", "openvim", "osmclient", "IM", "devops", "MON", "N2VC", "NBI", "common", "LCM", "POL", "LW-UI", "NG-UI", "PLA", "tests"]
 223                     if (upstreamComponent.length()>0) {
 224                         println("Skipping upstream fetch of "+upstreamComponent)
 225                         list.remove(upstreamComponent)
 226                     }
 227                     for (buildStep in list) {
 228                         def component = buildStep
 229                         parallelSteps[component] = {
 230                             dir("$component") {
 231                                 println("Fetching artifact for ${component}")
 232                                 step ([$class: 'CopyArtifact',
 233                                        projectName: "${component}${upstream_main_job}/${GERRIT_BRANCH}"])
 234
 235                                 // grab the archives from the stage_2 builds (ie. this will be the artifacts stored based on a merge)
 236                                 def packages = ci_helper.get_archive(params.ARTIFACTORY_SERVER,
 237                                     component,
 238                                     GERRIT_BRANCH,
 239                                     "${component}${upstream_main_job} :: ${GERRIT_BRANCH}",
 240                                     ci_helper.get_env_value('build.env','BUILD_NUMBER'))
 241                                 packageList.addAll(packages)
 242                                 println("Fetched ${component}: ${packages}")
 243                                 sh "rm -rf dists"
 244                             }
 245                         }
 246                     }
 247                     parallel parallelSteps
 248
 249 ///////////////////////////////////////////////////////////////////////////////////////
 250 // Create APT repository
 251 ///////////////////////////////////////////////////////////////////////////////////////
 252                     for ( component in [ "devops" ] ) {
 253                         sh "mv ${component}/pool/${component} pool"
 254                         sh "dpkg-sig --sign builder -k ${GPG_KEY_NAME} pool/${component}/*"
 255                         sh "mkdir -p dists/${params.REPO_DISTRO}/${component}/binary-amd64/"
 256                         sh "apt-ftparchive packages pool/${component} > dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 257                         sh "gzip -9fk dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 258                     }
 259                     // create and sign the release file
 260                     sh "apt-ftparchive release dists/${params.REPO_DISTRO} > dists/${params.REPO_DISTRO}/Release"
 261                     sh "gpg --yes -abs -u ${GPG_KEY_NAME} -o dists/${params.REPO_DISTRO}/Release.gpg dists/${params.REPO_DISTRO}/Release"
 262
 263                     // copy the public key into the release folder
 264                     // this pulls the key from the home dir of the current user (jenkins)
 265                     sh "cp ~/${REPO_KEY_NAME} 'OSM ETSI Release Key.gpg'"
 266                     sh "cp ~/${REPO_KEY_NAME} ."
 267                 }
 268
 269                 // start an apache server to serve up the packages
 270                 http_server_name = "${container_name}-apache"
 271
 272                 pwd = sh(returnStdout:true,  script: 'pwd').trim()
 273                 repo_port = sh(script: 'echo $(python -c \'import socket; s=socket.socket(); s.bind(("", 0)); print(s.getsockname()[1]); s.close()\');', returnStdout: true).trim()
 274                 repo_base_url = ci_helper.start_http_server(pwd,http_server_name,repo_port)
 275                 NODE_IP_ADDRESS=sh(returnStdout: true, script:
 276                     "echo ${SSH_CONNECTION} | awk '{print \$3}'").trim()
 277             }
 278
 279             // Unpack devops package into temporary location so that we use it from upstream if it was part of a patch
 280             osm_devops_dpkg = sh(returnStdout: true, script: "find ./repo/release/pool/ -name osm-devops*.deb").trim()
 281             devopstempdir = sh(returnStdout: true, script: "mktemp -d").trim()
 282             println("Extracting local devops package ${osm_devops_dpkg} into ${devopstempdir} for docker build step")
 283             sh "dpkg -x ${osm_devops_dpkg} ${devopstempdir}"
 284             OSM_DEVOPS="${devopstempdir}/usr/share/osm-devops"
 285             // Convert URLs from stage 2 packages to arguments that can be passed to docker build
 286             for (remotePath in packageList) {
 287                 packageName=remotePath.substring(remotePath.lastIndexOf('/')+1)
 288                 packageName=packageName.substring(0,packageName.indexOf('_'))
 289                 builtModules[packageName]=remotePath
 290             }
 291         }
 292
 293 ///////////////////////////////////////////////////////////////////////////////////////
 294 // Build docker containers
 295 ///////////////////////////////////////////////////////////////////////////////////////
 296         dir(OSM_DEVOPS) {
 297             def remote = [:]
 298             error = null
 299             if ( params.DO_BUILD ) {
 300                 withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'gitlab-registry',
 301                                 usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
 302                     sh "docker login ${INTERNAL_DOCKER_REGISTRY} -u ${USERNAME} -p ${PASSWORD}"
 303                 }
 304                 moduleBuildArgs = ""
 305                 for (packageName in builtModules.keySet()) {
 306                     envName=packageName.replaceAll("-","_").toUpperCase()+"_URL"
 307                     moduleBuildArgs += " --build-arg ${envName}=" + builtModules[packageName]
 308                 }
 309                 dir ("docker") {
 310                     stage("Build") {
 311                         containerList = sh(returnStdout: true, script:
 312                             "find . -name Dockerfile -printf '%h\\n' | sed 's|\\./||'")
 313                         containerList=Arrays.asList(containerList.split("\n"))
 314                         print(containerList)
 315                         parallelSteps = [:]
 316                         for (buildStep in containerList) {
 317                             def module = buildStep
 318                             def moduleName = buildStep.toLowerCase()
 319                             def moduleTag = container_name
 320                             parallelSteps[module] = {
 321                                 dir("$module") {
 322                                     sh "docker build -t opensourcemano/${moduleName}:${moduleTag} ${moduleBuildArgs} ."
 323                                     println("Tagging ${moduleName}:${moduleTag}")
 324                                     sh "docker tag opensourcemano/${moduleName}:${moduleTag} ${INTERNAL_DOCKER_REGISTRY}opensourcemano/${moduleName}:${moduleTag}"
 325                                     sh "docker push ${INTERNAL_DOCKER_REGISTRY}opensourcemano/${moduleName}:${moduleTag}"
 326                                 }
 327                             }
 328                         }
 329                         parallel parallelSteps
 330                     }
 331                 }
 332             } // if ( params.DO_BUILD )
 333
 334             if ( params.DO_INSTALL ) {
 335 ///////////////////////////////////////////////////////////////////////////////////////
 336 // Launch VM
 337 ///////////////////////////////////////////////////////////////////////////////////////
 338                 stage("Spawn Remote VM") {
 339                     println("Launching new VM")
 340                     output=sh(returnStdout: true, script: """#!/bin/sh -e
 341                         for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 342                         openstack server create --flavor osm.sanity \
 343                                                 --image ubuntu18.04 \
 344                                                 --key-name CICD \
 345                                                 --property build_url="${BUILD_URL}" \
 346                                                 --nic net-id=osm-ext \
 347                                                 ${container_name}
 348                     """).trim()
 349
 350                     server_id = get_value('id', output)
 351
 352                     if (server_id == null) {
 353                         println("VM launch output: ")
 354                         println(output)
 355                         throw new Exception("VM Launch failed")
 356                     }
 357                     println("Target VM is ${server_id}, waiting for IP address to be assigned")
 358
 359                     IP_ADDRESS = ""
 360
 361                     while (IP_ADDRESS == "") {
 362                         output=sh(returnStdout: true, script: """#!/bin/sh -e
 363                             for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 364                             openstack server show ${server_id}
 365                         """).trim()
 366                         IP_ADDRESS = get_value('addresses', output)
 367                     }
 368                     IP_ADDRESS = IP_ADDRESS.split('=')[1]
 369                     println("Waiting for VM at ${IP_ADDRESS} to be reachable")
 370
 371                     alive = false
 372                     while (! alive) {
 373                         output=sh(returnStdout: true, script: "sleep 1 ; nc -zv ${IP_ADDRESS} 22 2>&1 || true").trim()
 374                         println("output is [$output]")
 375                         alive = output.contains("succeeded")
 376                     }
 377                     println("VM is ready and accepting ssh connections")
 378                 } // stage("Spawn Remote VM")
 379
 380 ///////////////////////////////////////////////////////////////////////////////////////
 381 // Installation
 382 ///////////////////////////////////////////////////////////////////////////////////////
 383                 stage("Install") {
 384                     commit_id = ''
 385                     repo_distro = ''
 386                     repo_key_name = ''
 387                     release = ''
 388
 389                     if ( params.COMMIT_ID )
 390                     {
 391                         commit_id = "-b ${params.COMMIT_ID}"
 392                     }
 393
 394                     if ( params.REPO_DISTRO )
 395                     {
 396                         repo_distro = "-r ${params.REPO_DISTRO}"
 397                     }
 398
 399                     if ( params.REPO_KEY_NAME )
 400                     {
 401                         repo_key_name = "-k ${params.REPO_KEY_NAME}"
 402                     }
 403
 404                     if ( params.RELEASE )
 405                     {
 406                         release = "-R ${params.RELEASE}"
 407                     }
 408
 409                     if ( params.REPOSITORY_BASE )
 410                     {
 411                         repo_base_url = "-u ${params.REPOSITORY_BASE}"
 412                     }
 413                     else
 414                     {
 415                         repo_base_url = "-u http://${NODE_IP_ADDRESS}:${repo_port}"
 416                     }
 417
 418                     remote.name = container_name
 419                     remote.host = IP_ADDRESS
 420                     remote.user = 'ubuntu'
 421                     remote.identityFile = SSH_KEY
 422                     remote.allowAnyHosts = true
 423                     remote.logLevel = 'INFO'
 424                     remote.pty = true
 425
 426                     sshCommand remote: remote, command: """
 427                         wget https://osm-download.etsi.org/ftp/osm-9.0-nine/install_osm.sh
 428                         chmod +x ./install_osm.sh
 429                         sed -i '1 i\\export PATH=/snap/bin:\${PATH}' ~/.bashrc
 430                     """
 431
 432                     if ( useCharmedInstaller ) {
 433                         // Use local proxy for docker hub
 434                         sshCommand remote: remote, command: '''
 435                             sudo snap install microk8s --classic --channel=1.19/stable
 436                             sudo sed -i "s|https://registry-1.docker.io|http://172.21.1.1:5000|" /var/snap/microk8s/current/args/containerd-template.toml
 437                             sudo systemctl restart snap.microk8s.daemon-containerd.service
 438                             sudo snap alias microk8s.kubectl kubectl
 439                         '''
 440
 441                         withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'gitlab-registry',
 442                                         usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
 443                             sshCommand remote: remote, command: """
 444                                 ./install_osm.sh -y \
 445                                     ${repo_base_url} \
 446                                     ${repo_key_name} \
 447                                     ${release} -r unstable \
 448                                     --charmed  \
 449                                     --registry ${USERNAME}:${PASSWORD}@${INTERNAL_DOCKER_REGISTRY} \
 450                                     --tag ${container_name}
 451                             """
 452                         }
 453                         prometheusHostname = "prometheus."+IP_ADDRESS+".xip.io"
 454                         prometheusPort = 80
 455                         osmHostname = "nbi."+IP_ADDRESS+".xip.io:443"
 456                     } else {
 457                         // Run -k8s installer here specifying internal docker registry and docker proxy
 458                         withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'gitlab-registry',
 459                                         usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
 460                             sshCommand remote: remote, command: """
 461                                 ./install_osm.sh -y \
 462                                     ${repo_base_url} \
 463                                     ${repo_key_name} \
 464                                     ${release} -r unstable \
 465                                     -d ${USERNAME}:${PASSWORD}@${INTERNAL_DOCKER_REGISTRY} \
 466                                     -p ${INTERNAL_DOCKER_PROXY} \
 467                                     -t ${container_name}
 468                             """
 469                         }
 470                         prometheusHostname = IP_ADDRESS
 471                         prometheusPort = 9091
 472                         osmHostname = IP_ADDRESS
 473                     }
 474                 } // stage("Install")
 475             } // if ( params.DO_INSTALL )
 476
 477 ///////////////////////////////////////////////////////////////////////////////////////
 478 // Health check of installed OSM in remote vm
 479 ///////////////////////////////////////////////////////////////////////////////////////
 480             if ( params.DO_SMOKE ) {
 481                 stage("OSM Health") {
 482                     stackName = "osm"
 483                     sshCommand remote: remote, command: """
 484                         /usr/share/osm-devops/installers/osm_health.sh -k -s ${stackName}
 485                     """
 486                 }
 487             }
 488
 489 ///////////////////////////////////////////////////////////////////////////////////////
 490 // Execute Robot tests
 491 ///////////////////////////////////////////////////////////////////////////////////////
 492             stage_archive = false
 493             if ( params.DO_STAGE_4 ) {
 494                 try {
 495                     stage("System Integration Test") {
 496                         if ( params.DO_ROBOT ) {
 497                             if( useCharmedInstaller ) {
 498                                 tempdir = sh(returnStdout: true, script: "mktemp -d").trim()
 499                                 sh(script: "touch ${tempdir}/hosts")
 500                                 hostfile="${tempdir}/hosts"
 501                                 sh """cat << EOF > ${hostfile}
 502 127.0.0.1           localhost
 503 ${remote.host}      prometheus.${remote.host}.xip.io nbi.${remote.host}.xip.io
 504 EOF"""
 505                             } else {
 506                                 hostfile=null
 507                             }
 508
 509                             jujuPassword=sshCommand remote: remote, command: """
 510                                 echo `juju gui 2>&1 | grep password | cut -d: -f2`
 511                             """
 512
 513                             run_robot_systest(
 514                                 container_name,
 515                                 params.TEST_NAME,
 516                                 osmHostname,
 517                                 prometheusHostname,
 518                                 prometheusPort,
 519                                 params.ROBOT_VIM,
 520                                 params.KUBECONFIG,
 521                                 params.CLOUDS,
 522                                 hostfile,
 523                                 jujuPassword)
 524                         }
 525                     } // stage("System Integration Test")
 526                 } finally {
 527                     stage("Archive Container Logs") {
 528                         // Archive logs to containers_logs.txt
 529                         archive_logs(remote)
 530                         if ( ! currentBuild.result.equals('UNSTABLE') && ! currentBuild.result.equals('FAILURE')) {
 531                             stage_archive = keep_artifacts
 532                         } else {
 533                             println ("Systest test failed, throwing error")
 534                             error = new Exception("Systest test failed")
 535                             currentBuild.result = 'FAILURE'
 536                             throw error
 537                         }
 538                     }
 539                 }
 540             } // if ( params.DO_STAGE_4 )
 541
 542             if ( params.SAVE_ARTIFACTS_OVERRIDE || stage_archive ) {
 543                 stage("Archive") {
 544                     sh "echo ${container_name} > build_version.txt"
 545                     archiveArtifacts artifacts: "build_version.txt", fingerprint: true
 546
 547                     // Archive the tested repo
 548                     dir("${RELEASE_DIR}") {
 549                         ci_helper.archive(params.ARTIFACTORY_SERVER,RELEASE,GERRIT_BRANCH,'tested')
 550                     }
 551                     if ( params.DO_DOCKERPUSH ) {
 552                         stage("Publish to Dockerhub") {
 553                             parallelSteps = [:]
 554                             for (buildStep in containerList) {
 555                                 def module = buildStep
 556                                 def moduleName = buildStep.toLowerCase()
 557                                 def moduleTag = params.DOCKER_TAG
 558                                 parallelSteps[module] = {
 559                                     dir("$module") {
 560                                         sh "docker tag opensourcemano/${moduleName}:${moduleTag} opensourcemano/${moduleName}:${moduleTag}"
 561                                         sh "docker push opensourcemano/${moduleName}:${moduleTag}"
 562                                     }
 563                                 }
 564                             }
 565                             parallel parallelSteps
 566                         }
 567
 568                         stage("Snap promotion") {
 569                             def snaps = ["osmclient"]
 570                             sh "snapcraft login --with ~/.snapcraft/config"
 571                             for (snap in snaps) {
 572                                 channel="latest/"
 573                                 if (BRANCH_NAME.startsWith("v")) {
 574                                     channel=BRANCH_NAME.substring(1)+"/"
 575                                 } else if (BRANCH_NAME!="master") {
 576                                     channel+="/"+BRANCH_NAME.replaceAll('/','-')
 577                                 }
 578                                 track=channel+"edge\\*"
 579                                 edge_rev=sh(returnStdout: true,
 580                                     script: "snapcraft revisions $snap | " +
 581                                     "grep \"$track\" | tail -1 | awk '{print \$1}'").trim()
 582                                 print "edge rev is $edge_rev"
 583                                 track=channel+"beta\\*"
 584                                 beta_rev=sh(returnStdout: true,
 585                                     script: "snapcraft revisions $snap | " +
 586                                     "grep \"$track\" | tail -1 | awk '{print \$1}'").trim()
 587                                 print "beta rev is $beta_rev"
 588
 589                                 if ( edge_rev != beta_rev ) {
 590                                     print "Promoting $edge_rev to beta in place of $beta_rev"
 591                                     beta_track=channel+"beta"
 592                                     sh "snapcraft release $snap $edge_rev $beta_track"
 593                                 }
 594                             }
 595                         } // stage("Snap promotion")
 596                     } // if ( params.DO_DOCKERPUSH )
 597                 } // stage("Archive")
 598             } // if ( params.SAVE_ARTIFACTS_OVERRIDE || stage_archive )
 599         } // dir(OSM_DEVOPS)
 600     } finally {
 601         if ( params.DO_INSTALL && server_id != null) {
 602             delete_vm = true
 603             if (error && params.SAVE_CONTAINER_ON_FAIL ) {
 604                 delete_vm = false
 605             }
 606             if (!error && params.SAVE_CONTAINER_ON_PASS ) {
 607                 delete_vm = false
 608             }
 609
 610             if ( delete_vm ) {
 611                 if (server_id != null) {
 612                     println("Deleting VM: $server_id")
 613                     sh """#!/bin/sh -e
 614                         for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 615                         openstack server delete ${server_id}
 616                     """
 617                 } else {
 618                     println("Saved VM $server_id in ETSI VIM")
 619                 }
 620             }
 621         }
 622         if ( http_server_name != null ) {
 623             sh "docker stop ${http_server_name} || true"
 624             sh "docker rm ${http_server_name} || true"
 625         }
 626
 627         if ( devopstempdir != null ) {
 628             sh "rm -rf ${devopstempdir}"
 629         }
 630     }
 631 }