jenkins/ci-pipelines/ci_stage_3.groovy

   1 /* Copyright ETSI Contributors and Others
   2  *
   3  * All Rights Reserved.
   4  *
   5  *   Licensed under the Apache License, Version 2.0 (the "License"); you may
   6  *   not use this file except in compliance with the License. You may obtain
   7  *   a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *   Unless required by applicable law or agreed to in writing, software
  12  *   distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  13  *   WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  14  *   License for the specific language governing permissions and limitations
  15  *   under the License.
  16  */
  17
  18 properties([
  19     parameters([
  20         string(defaultValue: env.GERRIT_BRANCH, description: '', name: 'GERRIT_BRANCH'),
  21         string(defaultValue: 'system', description: '', name: 'NODE'),
  22         string(defaultValue: '', description: '', name: 'BUILD_FROM_SOURCE'),
  23         string(defaultValue: 'unstable', description: '', name: 'REPO_DISTRO'),
  24         string(defaultValue: '', description: '', name: 'COMMIT_ID'),
  25         string(defaultValue: '-stage_2', description: '', name: 'UPSTREAM_SUFFIX'),
  26         string(defaultValue: 'pubkey.asc', description: '', name: 'REPO_KEY_NAME'),
  27         string(defaultValue: 'release', description: '', name: 'RELEASE'),
  28         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NAME'),
  29         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  30         string(defaultValue: 'OSMETSI', description: '', name: 'GPG_KEY_NAME'),
  31         string(defaultValue: 'artifactory-osm', description: '', name: 'ARTIFACTORY_SERVER'),
  32         string(defaultValue: 'osm-stage_4', description: '', name: 'DOWNSTREAM_STAGE_NAME'),
  33         string(defaultValue: 'testing-daily', description: '', name: 'DOCKER_TAG'),
  34         string(defaultValue: 'ubuntu20.04', description: '', name: 'OPENSTACK_BASE_IMAGE'),
  35         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_FAIL'),
  36         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_PASS'),
  37         booleanParam(defaultValue: true, description: '', name: 'SAVE_ARTIFACTS_ON_SMOKE_SUCCESS'),
  38         booleanParam(defaultValue: true, description: '',  name: 'DO_BUILD'),
  39         booleanParam(defaultValue: true, description: '', name: 'DO_INSTALL'),
  40         booleanParam(defaultValue: true, description: '', name: 'DO_DOCKERPUSH'),
  41         booleanParam(defaultValue: false, description: '', name: 'SAVE_ARTIFACTS_OVERRIDE'),
  42         string(defaultValue: '/home/jenkins/hive/openstack-etsi.rc', description: '', name: 'HIVE_VIM_1'),
  43         booleanParam(defaultValue: true, description: '', name: 'DO_ROBOT'),
  44         string(defaultValue: 'sanity', description: 'sanity/regression/daily are the common options',
  45                name: 'ROBOT_TAG_NAME'),
  46         string(defaultValue: '/home/jenkins/hive/robot-systest.cfg', description: '', name: 'ROBOT_VIM'),
  47         string(defaultValue: '/home/jenkins/hive/port-mapping-etsi-vim.yaml',
  48                description: 'Port mapping file for SDN assist in ETSI VIM',
  49                name: 'ROBOT_PORT_MAPPING_VIM'),
  50         string(defaultValue: '/home/jenkins/hive/kubeconfig.yaml', description: '', name: 'KUBECONFIG'),
  51         string(defaultValue: '/home/jenkins/hive/clouds.yaml', description: '', name: 'CLOUDS'),
  52         string(defaultValue: 'Default', description: '', name: 'INSTALLER'),
  53         string(defaultValue: '100.0', description: '% passed Robot tests to mark the build as passed',
  54                name: 'ROBOT_PASS_THRESHOLD'),
  55         string(defaultValue: '80.0', description: '% passed Robot tests to mark the build as unstable ' +
  56                '(if lower, it will be failed)', name: 'ROBOT_UNSTABLE_THRESHOLD'),
  57     ])
  58 ])
  59
  60 ////////////////////////////////////////////////////////////////////////////////////////
  61 // Helper Functions
  62 ////////////////////////////////////////////////////////////////////////////////////////
  63 void run_robot_systest(String tagName,
  64                        String testName,
  65                        String osmHostname,
  66                        String prometheusHostname,
  67                        Integer prometheusPort=null,
  68                        String envfile=null,
  69                        String portmappingfile=null,
  70                        String kubeconfig=null,
  71                        String clouds=null,
  72                        String hostfile=null,
  73                        String jujuPassword=null,
  74                        String osmRSAfile=null,
  75                        String passThreshold='0.0',
  76                        String unstableThreshold='0.0') {
  77     tempdir = sh(returnStdout: true, script: 'mktemp -d').trim()
  78     String environmentFile = ''
  79     if (envfile) {
  80         environmentFile = envfile
  81     } else {
  82         sh(script: "touch ${tempdir}/env")
  83         environmentFile = "${tempdir}/env"
  84     }
  85     PROMETHEUS_PORT_VAR = ''
  86     if (prometheusPort != null) {
  87         PROMETHEUS_PORT_VAR = "--env PROMETHEUS_PORT=${prometheusPort}"
  88     }
  89     hostfilemount = ''
  90     if (hostfile) {
  91         hostfilemount = "-v ${hostfile}:/etc/hosts"
  92     }
  93
  94     JUJU_PASSWORD_VAR = ''
  95     if (jujuPassword != null) {
  96         JUJU_PASSWORD_VAR = "--env JUJU_PASSWORD=${jujuPassword}"
  97     }
  98
  99     try {
 100         sh("""docker run --env OSM_HOSTNAME=${osmHostname} --env PROMETHEUS_HOSTNAME=${prometheusHostname} \
 101            ${PROMETHEUS_PORT_VAR} ${JUJU_PASSWORD_VAR} --env-file ${environmentFile} \
 102            -v ${clouds}:/etc/openstack/clouds.yaml \
 103            -v ${osmRSAfile}:/root/osm_id_rsa -v ${kubeconfig}:/root/.kube/config -v ${tempdir}:/robot-systest/reports \
 104            -v ${portmappingfile}:/root/port-mapping.yaml ${hostfilemount} opensourcemano/tests:${tagName} \
 105            -c -t ${testName}""")
 106     } finally {
 107         sh("cp ${tempdir}/* .")
 108         outputDirectory = sh(returnStdout: true, script: 'pwd').trim()
 109         println("Present Directory is : ${outputDirectory}")
 110         step([
 111             $class : 'RobotPublisher',
 112             outputPath : "${outputDirectory}",
 113             outputFileName : '*.xml',
 114             disableArchiveOutput : false,
 115             reportFileName : 'report.html',
 116             logFileName : 'log.html',
 117             passThreshold : passThreshold,
 118             unstableThreshold: unstableThreshold,
 119             otherFiles : '*.png',
 120         ])
 121     }
 122 }
 123
 124 void archive_logs(Map remote) {
 125
 126     sshCommand remote: remote, command: '''mkdir -p logs'''
 127     if (useCharmedInstaller) {
 128         sshCommand remote: remote, command: '''
 129             for container in `kubectl get pods -n osm | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 130                 logfile=`echo $container | cut -d- -f1`
 131                 echo "Extracting log for $logfile"
 132                 kubectl logs -n osm $container --timestamps=true 2>&1 > logs/$logfile.log
 133             done
 134         '''
 135     } else {
 136         sshCommand remote: remote, command: '''
 137             for deployment in `kubectl -n osm get deployments | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 138                 echo "Extracting log for $deployment"
 139                 kubectl -n osm logs deployments/$deployment --timestamps=true --all-containers 2>&1 \
 140                 > logs/$deployment.log
 141             done
 142         '''
 143         sshCommand remote: remote, command: '''
 144             for statefulset in `kubectl -n osm get statefulsets | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 145                 echo "Extracting log for $statefulset"
 146                 kubectl -n osm logs statefulsets/$statefulset --timestamps=true --all-containers 2>&1 \
 147                 > logs/$statefulset.log
 148             done
 149         '''
 150     }
 151
 152     sh 'rm -rf logs'
 153     sshCommand remote: remote, command: '''ls -al logs'''
 154     sshGet remote: remote, from: 'logs', into: '.', override: true
 155     sh 'cp logs/* .'
 156     archiveArtifacts artifacts: '*.log'
 157 }
 158
 159 String get_value(String key, String output) {
 160     for (String line : output.split( '\n' )) {
 161         data = line.split( '\\|' )
 162         if (data.length > 1) {
 163             if ( data[1].trim() == key ) {
 164                 return data[2].trim()
 165             }
 166         }
 167     }
 168 }
 169
 170 ////////////////////////////////////////////////////////////////////////////////////////
 171 // Main Script
 172 ////////////////////////////////////////////////////////////////////////////////////////
 173 node("${params.NODE}") {
 174
 175     INTERNAL_DOCKER_REGISTRY = 'osm.etsi.org:5050/devops/cicd/'
 176     INTERNAL_DOCKER_PROXY = 'http://172.21.1.1:5000'
 177     APT_PROXY = 'http://172.21.1.1:3142'
 178     SSH_KEY = '~/hive/cicd_rsa'
 179     sh 'env'
 180
 181     tag_or_branch = params.GERRIT_BRANCH.replaceAll(/\./, '')
 182
 183     stage('Checkout') {
 184         checkout scm
 185     }
 186
 187     ci_helper = load 'jenkins/ci-pipelines/ci_helper.groovy'
 188
 189     def upstreamMainJob = params.UPSTREAM_SUFFIX
 190
 191     // upstream jobs always use merged artifacts
 192     upstreamMainJob += '-merge'
 193     containerNamePrefix = "osm-${tag_or_branch}"
 194     containerName = "${containerNamePrefix}"
 195
 196     keep_artifacts = false
 197     if ( JOB_NAME.contains('merge') ) {
 198         containerName += '-merge'
 199
 200         // On a merge job, we keep artifacts on smoke success
 201         keep_artifacts = params.SAVE_ARTIFACTS_ON_SMOKE_SUCCESS
 202     }
 203     containerName += "-${BUILD_NUMBER}"
 204
 205     server_id = null
 206     http_server_name = null
 207     devopstempdir = null
 208     useCharmedInstaller = params.INSTALLER.equalsIgnoreCase('charmed')
 209
 210     try {
 211         builtModules = [:]
 212 ///////////////////////////////////////////////////////////////////////////////////////
 213 // Fetch stage 2 .deb artifacts
 214 ///////////////////////////////////////////////////////////////////////////////////////
 215         stage('Copy Artifacts') {
 216             // cleanup any previous repo
 217             sh 'rm -rf repo'
 218             dir('repo') {
 219                 packageList = []
 220                 dir("${RELEASE}") {
 221                     RELEASE_DIR = sh(returnStdout:true,  script: 'pwd').trim()
 222
 223                     // check if an upstream artifact based on specific build number has been requested
 224                     // This is the case of a merge build and the upstream merge build is not yet complete
 225                     // (it is not deemed a successful build yet). The upstream job is calling this downstream
 226                     // job (with the its build artifact)
 227                     def upstreamComponent = ''
 228                     if (params.UPSTREAM_JOB_NAME) {
 229                         println("Fetching upstream job artifact from ${params.UPSTREAM_JOB_NAME}")
 230                         lock('Artifactory') {
 231                             step ([$class: 'CopyArtifact',
 232                                 projectName: "${params.UPSTREAM_JOB_NAME}",
 233                                 selector: [$class: 'SpecificBuildSelector',
 234                                 buildNumber: "${params.UPSTREAM_JOB_NUMBER}"]
 235                                 ])
 236
 237                             upstreamComponent = ci_helper.get_mdg_from_project(
 238                                 ci_helper.get_env_value('build.env','GERRIT_PROJECT'))
 239                             def buildNumber = ci_helper.get_env_value('build.env','BUILD_NUMBER')
 240                             dir("$upstreamComponent") {
 241                                 // the upstream job name contains suffix with the project. Need this stripped off
 242                                 project_without_branch = params.UPSTREAM_JOB_NAME.split('/')[0]
 243                                 packages = ci_helper.get_archive(params.ARTIFACTORY_SERVER,
 244                                     upstreamComponent,
 245                                     GERRIT_BRANCH,
 246                                     "${project_without_branch} :: ${GERRIT_BRANCH}",
 247                                     buildNumber)
 248
 249                                 packageList.addAll(packages)
 250                                 println("Fetched pre-merge ${params.UPSTREAM_JOB_NAME}: ${packages}")
 251                             }
 252                         } // lock artifactory
 253                     }
 254
 255                     parallelSteps = [:]
 256                     list = ['RO', 'osmclient', 'IM', 'devops', 'MON', 'N2VC', 'NBI',
 257                             'common', 'LCM', 'POL', 'NG-UI', 'PLA', 'tests']
 258                     if (upstreamComponent.length() > 0) {
 259                         println("Skipping upstream fetch of ${upstreamComponent}")
 260                         list.remove(upstreamComponent)
 261                     }
 262                     for (buildStep in list) {
 263                         def component = buildStep
 264                         parallelSteps[component] = {
 265                             dir("$component") {
 266                                 println("Fetching artifact for ${component}")
 267                                 step([$class: 'CopyArtifact',
 268                                        projectName: "${component}${upstreamMainJob}/${GERRIT_BRANCH}"])
 269
 270                                 // grab the archives from the stage_2 builds
 271                                 // (ie. this will be the artifacts stored based on a merge)
 272                                 packages = ci_helper.get_archive(params.ARTIFACTORY_SERVER,
 273                                     component,
 274                                     GERRIT_BRANCH,
 275                                     "${component}${upstreamMainJob} :: ${GERRIT_BRANCH}",
 276                                     ci_helper.get_env_value('build.env', 'BUILD_NUMBER'))
 277                                 packageList.addAll(packages)
 278                                 println("Fetched ${component}: ${packages}")
 279                                 sh 'rm -rf dists'
 280                             }
 281                         }
 282                     }
 283                     lock('Artifactory') {
 284                         parallel parallelSteps
 285                     }
 286
 287 ///////////////////////////////////////////////////////////////////////////////////////
 288 // Create Devops APT repository
 289 ///////////////////////////////////////////////////////////////////////////////////////
 290                     sh 'mkdir -p pool'
 291                     for (component in [ 'devops', 'IM', 'osmclient' ]) {
 292                         sh "ls -al ${component}/pool/"
 293                         sh "cp -r ${component}/pool/* pool/"
 294                         sh "dpkg-sig --sign builder -k ${GPG_KEY_NAME} pool/${component}/*"
 295                         sh "mkdir -p dists/${params.REPO_DISTRO}/${component}/binary-amd64/"
 296                         sh("""apt-ftparchive packages pool/${component} \
 297                            > dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages""")
 298                         sh "gzip -9fk dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 299                     }
 300
 301                     // create and sign the release file
 302                     sh "apt-ftparchive release dists/${params.REPO_DISTRO} > dists/${params.REPO_DISTRO}/Release"
 303                     sh("""gpg --yes -abs -u ${GPG_KEY_NAME} \
 304                        -o dists/${params.REPO_DISTRO}/Release.gpg dists/${params.REPO_DISTRO}/Release""")
 305
 306                     // copy the public key into the release folder
 307                     // this pulls the key from the home dir of the current user (jenkins)
 308                     sh "cp ~/${REPO_KEY_NAME} 'OSM ETSI Release Key.gpg'"
 309                     sh "cp ~/${REPO_KEY_NAME} ."
 310                 }
 311
 312                 // start an apache server to serve up the packages
 313                 http_server_name = "${containerName}-apache"
 314
 315                 pwd = sh(returnStdout:true,  script: 'pwd').trim()
 316                 repo_port = sh(script: 'echo $(python -c \'import socket; s=socket.socket(); s.bind(("", 0));' +
 317                                'print(s.getsockname()[1]); s.close()\');',
 318                                returnStdout: true).trim()
 319                 repo_base_url = ci_helper.start_http_server(pwd, http_server_name, repo_port)
 320                 NODE_IP_ADDRESS = sh(returnStdout: true, script:
 321                     "echo ${SSH_CONNECTION} | awk '{print \$3}'").trim()
 322             }
 323
 324             // Unpack devops package into temporary location so that we use it from upstream if it was part of a patch
 325             osm_devops_dpkg = sh(returnStdout: true, script: 'find ./repo/release/pool/ -name osm-devops*.deb').trim()
 326             devopstempdir = sh(returnStdout: true, script: 'mktemp -d').trim()
 327             println("Extracting local devops package ${osm_devops_dpkg} into ${devopstempdir} for docker build step")
 328             sh "dpkg -x ${osm_devops_dpkg} ${devopstempdir}"
 329             OSM_DEVOPS = "${devopstempdir}/usr/share/osm-devops"
 330             // Convert URLs from stage 2 packages to arguments that can be passed to docker build
 331             for (remotePath in packageList) {
 332                 packageName = remotePath[remotePath.lastIndexOf('/') + 1 .. -1]
 333                 packageName = packageName[0 .. packageName.indexOf('_') - 1]
 334                 builtModules[packageName] = remotePath
 335             }
 336         }
 337
 338 ///////////////////////////////////////////////////////////////////////////////////////
 339 // Build docker containers
 340 ///////////////////////////////////////////////////////////////////////////////////////
 341         dir(OSM_DEVOPS) {
 342             Map remote = [:]
 343             error = null
 344             if ( params.DO_BUILD ) {
 345                 withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'gitlab-registry',
 346                                 usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
 347                     sh "docker login ${INTERNAL_DOCKER_REGISTRY} -u ${USERNAME} -p ${PASSWORD}"
 348                 }
 349                 datetime = sh(returnStdout: true, script: 'date +%Y-%m-%d:%H:%M:%S').trim()
 350                 moduleBuildArgs = " --build-arg CACHE_DATE=${datetime}"
 351                 for (packageName in builtModules.keySet()) {
 352                     envName = packageName.replaceAll('-', '_').toUpperCase() + '_URL'
 353                     moduleBuildArgs += " --build-arg ${envName}=" + builtModules[packageName]
 354                 }
 355                 dir('docker') {
 356                     stage('Build') {
 357                         containerList = sh(returnStdout: true, script:
 358                             "find . -name Dockerfile -printf '%h\\n' | sed 's|\\./||'")
 359                         containerList = Arrays.asList(containerList.split('\n'))
 360                         print(containerList)
 361                         parallelSteps = [:]
 362                         for (buildStep in containerList) {
 363                             def module = buildStep
 364                             def moduleName = buildStep.toLowerCase()
 365                             def moduleTag = containerName
 366                             parallelSteps[module] = {
 367                                 dir("$module") {
 368                                     sh("""docker build --build-arg APT_PROXY=${APT_PROXY} \
 369                                     -t opensourcemano/${moduleName}:${moduleTag} ${moduleBuildArgs} .""")
 370                                     println("Tagging ${moduleName}:${moduleTag}")
 371                                     sh("""docker tag opensourcemano/${moduleName}:${moduleTag} \
 372                                     ${INTERNAL_DOCKER_REGISTRY}opensourcemano/${moduleName}:${moduleTag}""")
 373                                     sh("""docker push \
 374                                     ${INTERNAL_DOCKER_REGISTRY}opensourcemano/${moduleName}:${moduleTag}""")
 375                                 }
 376                             }
 377                         }
 378                         parallel parallelSteps
 379                     }
 380                 }
 381             } // if (params.DO_BUILD)
 382
 383             if (params.DO_INSTALL) {
 384 ///////////////////////////////////////////////////////////////////////////////////////
 385 // Launch VM
 386 ///////////////////////////////////////////////////////////////////////////////////////
 387                 stage('Spawn Remote VM') {
 388                     println('Launching new VM')
 389                     output = sh(returnStdout: true, script: """#!/bin/sh -e
 390                         for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 391                         openstack server create --flavor osm.sanity \
 392                                                 --image ${OPENSTACK_BASE_IMAGE} \
 393                                                 --key-name CICD \
 394                                                 --property build_url="${BUILD_URL}" \
 395                                                 --nic net-id=osm-ext \
 396                                                 ${containerName}
 397                     """).trim()
 398
 399                     server_id = get_value('id', output)
 400
 401                     if (server_id == null) {
 402                         println('VM launch output: ')
 403                         println(output)
 404                         throw new Exception('VM Launch failed')
 405                     }
 406                     println("Target VM is ${server_id}, waiting for IP address to be assigned")
 407
 408                     IP_ADDRESS = ''
 409
 410                     while (IP_ADDRESS == '') {
 411                         output = sh(returnStdout: true, script: """#!/bin/sh -e
 412                             for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 413                             openstack server show ${server_id}
 414                         """).trim()
 415                         IP_ADDRESS = get_value('addresses', output)
 416                     }
 417                     IP_ADDRESS = IP_ADDRESS.split('=')[1]
 418                     println("Waiting for VM at ${IP_ADDRESS} to be reachable")
 419
 420                     alive = false
 421                     timeout(time: 1, unit: 'MINUTES') {
 422                         while (!alive) {
 423                             output = sh(
 424                                 returnStatus: true,
 425                                 script: "ssh -T -i ${SSH_KEY} " +
 426                                     "-o StrictHostKeyChecking=no " +
 427                                     "-o UserKnownHostsFile=/dev/null " +
 428                                     "-o ConnectTimeout=5 ubuntu@${IP_ADDRESS} 'echo Alive'")
 429                             alive = (output == 0)
 430                         }
 431                     }
 432                     println('VM is ready and accepting ssh connections')
 433                 } // stage("Spawn Remote VM")
 434
 435 ///////////////////////////////////////////////////////////////////////////////////////
 436 // Installation
 437 ///////////////////////////////////////////////////////////////////////////////////////
 438                 stage('Install') {
 439                     commit_id = ''
 440                     repo_distro = ''
 441                     repo_key_name = ''
 442                     release = ''
 443
 444                     if (params.COMMIT_ID) {
 445                         commit_id = "-b ${params.COMMIT_ID}"
 446                     }
 447                     if (params.REPO_DISTRO) {
 448                         repo_distro = "-r ${params.REPO_DISTRO}"
 449                     }
 450                     if (params.REPO_KEY_NAME) {
 451                         repo_key_name = "-k ${params.REPO_KEY_NAME}"
 452                     }
 453                     if (params.RELEASE) {
 454                         release = "-R ${params.RELEASE}"
 455                     }
 456                     if (params.REPOSITORY_BASE) {
 457                         repo_base_url = "-u ${params.REPOSITORY_BASE}"
 458                     } else {
 459                         repo_base_url = "-u http://${NODE_IP_ADDRESS}:${repo_port}"
 460                     }
 461
 462                     remote = [
 463                         name: containerName,
 464                         host: IP_ADDRESS,
 465                         user: 'ubuntu',
 466                         identityFile: SSH_KEY,
 467                         allowAnyHosts: true,
 468                         logLevel: 'INFO',
 469                         pty: true
 470                     ]
 471
 472                     // Force time sync to avoid clock drift and invalid certificates
 473                     sshCommand remote: remote, command: '''
 474                         sudo apt update
 475                         sudo apt install -y ntp
 476                         sudo service ntp stop
 477                         sudo ntpd -gq
 478                         sudo service ntp start
 479                     '''
 480
 481                     sshCommand remote: remote, command: '''
 482                         wget https://osm-download.etsi.org/ftp/osm-11.0-eleven/install_osm.sh
 483                         chmod +x ./install_osm.sh
 484                         sed -i '1 i\\export PATH=/snap/bin:\$PATH' ~/.bashrc
 485                     '''
 486
 487                     Map gitlabCredentialsMap = [$class: 'UsernamePasswordMultiBinding',
 488                                                 credentialsId: 'gitlab-registry',
 489                                                 usernameVariable: 'USERNAME',
 490                                                 passwordVariable: 'PASSWORD']
 491                     if (useCharmedInstaller) {
 492                         // Use local proxy for docker hub
 493                         sshCommand remote: remote, command: '''
 494                             sudo snap install microk8s --classic --channel=1.19/stable
 495                             sudo sed -i "s|https://registry-1.docker.io|http://172.21.1.1:5000|" \
 496                             /var/snap/microk8s/current/args/containerd-template.toml
 497                             sudo systemctl restart snap.microk8s.daemon-containerd.service
 498                             sudo snap alias microk8s.kubectl kubectl
 499                         '''
 500
 501                         withCredentials([gitlabCredentialsMap]) {
 502                             sshCommand remote: remote, command: """
 503                                 ./install_osm.sh -y \
 504                                     ${repo_base_url} \
 505                                     ${repo_key_name} \
 506                                     ${release} -r unstable \
 507                                     --charmed  \
 508                                     --registry ${USERNAME}:${PASSWORD}@${INTERNAL_DOCKER_REGISTRY} \
 509                                     --tag ${containerName}
 510                             """
 511                         }
 512                         prometheusHostname = "prometheus.${IP_ADDRESS}.nip.io"
 513                         prometheusPort = 80
 514                         osmHostname = "nbi.${IP_ADDRESS}.nip.io:443"
 515                     } else {
 516                         // Run -k8s installer here specifying internal docker registry and docker proxy
 517                         withCredentials([gitlabCredentialsMap]) {
 518                             sshCommand remote: remote, command: """
 519                                 ./install_osm.sh -y \
 520                                     ${repo_base_url} \
 521                                     ${repo_key_name} \
 522                                     ${release} -r unstable \
 523                                     -d ${USERNAME}:${PASSWORD}@${INTERNAL_DOCKER_REGISTRY} \
 524                                     -p ${INTERNAL_DOCKER_PROXY} \
 525                                     -t ${containerName}
 526                             """
 527                         }
 528                         prometheusHostname = IP_ADDRESS
 529                         prometheusPort = 9091
 530                         osmHostname = IP_ADDRESS
 531                     }
 532                 } // stage("Install")
 533 ///////////////////////////////////////////////////////////////////////////////////////
 534 // Health check of installed OSM in remote vm
 535 ///////////////////////////////////////////////////////////////////////////////////////
 536                 stage('OSM Health') {
 537                     stackName = 'osm'
 538                     sshCommand remote: remote, command: """
 539                         /usr/share/osm-devops/installers/osm_health.sh -k -s ${stackName}
 540                     """
 541                 } // stage("OSM Health")
 542             } // if ( params.DO_INSTALL )
 543
 544
 545 ///////////////////////////////////////////////////////////////////////////////////////
 546 // Execute Robot tests
 547 ///////////////////////////////////////////////////////////////////////////////////////
 548             stage_archive = false
 549             if ( params.DO_ROBOT ) {
 550                 try {
 551                     stage('System Integration Test') {
 552                         if (useCharmedInstaller) {
 553                             tempdir = sh(returnStdout: true, script: 'mktemp -d').trim()
 554                             sh(script: "touch ${tempdir}/hosts")
 555                             hostfile = "${tempdir}/hosts"
 556                             sh """cat << EOF > ${hostfile}
 557 127.0.0.1           localhost
 558 ${remote.host}      prometheus.${remote.host}.nip.io nbi.${remote.host}.nip.io
 559 EOF"""
 560                         } else {
 561                             hostfile = null
 562                         }
 563
 564                         jujuPassword = sshCommand remote: remote, command: '''
 565                             echo `juju gui 2>&1 | grep password | cut -d: -f2`
 566                         '''
 567
 568                         run_robot_systest(
 569                             containerName,
 570                             params.ROBOT_TAG_NAME,
 571                             osmHostname,
 572                             prometheusHostname,
 573                             prometheusPort,
 574                             params.ROBOT_VIM,
 575                             params.ROBOT_PORT_MAPPING_VIM,
 576                             params.KUBECONFIG,
 577                             params.CLOUDS,
 578                             hostfile,
 579                             jujuPassword,
 580                             SSH_KEY,
 581                             params.ROBOT_PASS_THRESHOLD,
 582                             params.ROBOT_UNSTABLE_THRESHOLD
 583                         )
 584                     } // stage("System Integration Test")
 585                 } finally {
 586                     stage('Archive Container Logs') {
 587                         // Archive logs to containers_logs.txt
 588                         archive_logs(remote)
 589                         if (currentBuild.result != 'FAILURE') {
 590                             stage_archive = keep_artifacts
 591                         } else {
 592                             println('Systest test failed, throwing error')
 593                             error = new Exception('Systest test failed')
 594                             currentBuild.result = 'FAILURE'
 595                             throw error
 596                         }
 597                     }
 598                 }
 599             } // if ( params.DO_ROBOT )
 600
 601             if (params.SAVE_ARTIFACTS_OVERRIDE || stage_archive) {
 602                 stage('Archive') {
 603                     sh "echo ${containerName} > build_version.txt"
 604                     archiveArtifacts artifacts: 'build_version.txt', fingerprint: true
 605
 606                     // Archive the tested repo
 607                     dir("${RELEASE_DIR}") {
 608                         ci_helper.archive(params.ARTIFACTORY_SERVER, RELEASE, GERRIT_BRANCH, 'tested')
 609                     }
 610                     if (params.DO_DOCKERPUSH) {
 611                         stage('Publish to Dockerhub') {
 612                             parallelSteps = [:]
 613                             for (buildStep in containerList) {
 614                                 def module = buildStep
 615                                 def moduleName = buildStep.toLowerCase()
 616                                 def dockerTag = params.DOCKER_TAG
 617                                 def moduleTag = containerName
 618
 619                                 parallelSteps[module] = {
 620                                     dir("$module") {
 621                                         sh("""docker tag opensourcemano/${moduleName}:${moduleTag} \
 622                                            opensourcemano/${moduleName}:${dockerTag}""")
 623                                         sh "docker push opensourcemano/${moduleName}:${dockerTag}"
 624                                     }
 625                                 }
 626                             }
 627                             parallel parallelSteps
 628                         }
 629
 630                         stage('Snap promotion') {
 631                             snaps = ['osmclient']
 632                             sh 'snapcraft login --with ~/.snapcraft/config'
 633                             for (snap in snaps) {
 634                                 channel = 'latest/'
 635                                 if (BRANCH_NAME.startsWith('v')) {
 636                                     channel = BRANCH_NAME.substring(1) + '/'
 637                                 } else if (BRANCH_NAME != 'master') {
 638                                     channel += '/' + BRANCH_NAME.replaceAll('/', '-')
 639                                 }
 640                                 track = channel + 'edge\\*'
 641                                 edge_rev = sh(returnStdout: true,
 642                                     script: "snapcraft revisions $snap | " +
 643                                     "grep \"$track\" | tail -1 | awk '{print \$1}'").trim()
 644                                 print "edge rev is $edge_rev"
 645                                 track = channel + 'beta\\*'
 646                                 beta_rev = sh(returnStdout: true,
 647                                     script: "snapcraft revisions $snap | " +
 648                                     "grep \"$track\" | tail -1 | awk '{print \$1}'").trim()
 649                                 print "beta rev is $beta_rev"
 650
 651                                 if (edge_rev != beta_rev) {
 652                                     print "Promoting $edge_rev to beta in place of $beta_rev"
 653                                     beta_track = channel + 'beta'
 654                                     sh "snapcraft release $snap $edge_rev $beta_track"
 655                                 }
 656                             }
 657                         } // stage('Snap promotion')
 658                     } // if (params.DO_DOCKERPUSH)
 659                 } // stage('Archive')
 660             } // if (params.SAVE_ARTIFACTS_OVERRIDE || stage_archive)
 661         } // dir(OSM_DEVOPS)
 662     } finally {
 663         if ( params.DO_INSTALL && server_id != null) {
 664             delete_vm = true
 665             if (error && params.SAVE_CONTAINER_ON_FAIL ) {
 666                 delete_vm = false
 667             }
 668             if (!error && params.SAVE_CONTAINER_ON_PASS ) {
 669                 delete_vm = false
 670             }
 671
 672             if ( delete_vm ) {
 673                 if (server_id != null) {
 674                     println("Deleting VM: $server_id")
 675                     sh """#!/bin/sh -e
 676                         for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 677                         openstack server delete ${server_id}
 678                     """
 679                 } else {
 680                     println("Saved VM $server_id in ETSI VIM")
 681                 }
 682             }
 683         }
 684         if ( http_server_name != null ) {
 685             sh "docker stop ${http_server_name} || true"
 686             sh "docker rm ${http_server_name} || true"
 687         }
 688
 689         if ( devopstempdir != null ) {
 690             sh "rm -rf ${devopstempdir}"
 691         }
 692     }
 693 }