jenkins/ci-pipelines/ci_stage_3.groovy

   1 /* Copyright 2017 Sandvine
   2  *
   3  * All Rights Reserved.
   4  *
   5  *   Licensed under the Apache License, Version 2.0 (the "License"); you may
   6  *   not use this file except in compliance with the License. You may obtain
   7  *   a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *   Unless required by applicable law or agreed to in writing, software
  12  *   distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  13  *   WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  14  *   License for the specific language governing permissions and limitations
  15  *   under the License.
  16  */
  17
  18 properties([
  19     parameters([
  20         string(defaultValue: env.GERRIT_BRANCH, description: '', name: 'GERRIT_BRANCH'),
  21         string(defaultValue: 'system', description: '', name: 'NODE'),
  22         string(defaultValue: '', description: '', name: 'BUILD_FROM_SOURCE'),
  23         string(defaultValue: 'unstable', description: '', name: 'REPO_DISTRO'),
  24         string(defaultValue: '', description: '', name: 'COMMIT_ID'),
  25         string(defaultValue: '-stage_2', description: '', name: 'UPSTREAM_SUFFIX'),
  26         string(defaultValue: 'pubkey.asc', description: '', name: 'REPO_KEY_NAME'),
  27         string(defaultValue: 'release', description: '', name: 'RELEASE'),
  28         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NAME'),
  29         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  30         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  31         string(defaultValue: 'dpkg1', description: '', name: 'GPG_KEY_NAME'),
  32         string(defaultValue: 'artifactory-osm', description: '', name: 'ARTIFACTORY_SERVER'),
  33         string(defaultValue: 'osm-stage_4', description: '', name: 'DOWNSTREAM_STAGE_NAME'),
  34         string(defaultValue: 'releasesix-daily', description: '', name: 'DOCKER_TAG'),
  35         booleanParam(defaultValue: true, description: '', name: 'SAVE_CONTAINER_ON_FAIL'),
  36         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_PASS'),
  37         booleanParam(defaultValue: true, description: '', name: 'SAVE_ARTIFACTS_ON_SMOKE_SUCCESS'),
  38         booleanParam(defaultValue: true, description: '', name: 'DO_STAGE_4'),
  39         booleanParam(defaultValue: true, description: '',  name: 'DO_BUILD'),
  40         booleanParam(defaultValue: true, description: '', name: 'DO_INSTALL'),
  41         booleanParam(defaultValue: true, description: '', name: 'DO_SMOKE'),
  42         booleanParam(defaultValue: true, description: '', name: 'DO_DOCKERPUSH'),
  43         booleanParam(defaultValue: false, description: '', name: 'SAVE_ARTIFACTS_OVERRIDE'),
  44         string(defaultValue: '/home/jenkins/hive/openstack-etsi.rc', description: '', name: 'HIVE_VIM_1'),
  45     ])
  46 ])
  47
  48 def uninstall_osm(stackName) {
  49     sh """
  50          export OSM_USE_LOCAL_DEVOPS=true
  51          export PATH=$PATH:/snap/bin
  52          installers/full_install_osm.sh -y -w /tmp/osm -t ${stackName} -s ${stackName} --test --nolxd --nodocker --nojuju --nohostports --nohostclient --uninstall
  53        """
  54 }
  55
  56 def run_systest(stackName,tagName,testName,envfile=null) {
  57     tempdir = sh(returnStdout: true, script: "mktemp -d").trim()
  58     if ( !envfile )
  59     {
  60         sh(script: "touch ${tempdir}/env")
  61         envfile="${tempdir}/env"
  62     }
  63     sh "docker run --network net${stackName} --env-file ${envfile} -v ${tempdir}:/usr/share/osm-devops/systest/reports opensourcemano/osmclient:${tagName} make -C /usr/share/osm-devops/systest ${testName}"
  64     sh "cp ${tempdir}/* ."
  65     junit  '*.xml'
  66 }
  67
  68 node("${params.NODE}") {
  69
  70     sh 'env'
  71
  72     tag_or_branch = params.GERRIT_BRANCH.replaceAll(/\./,"")
  73
  74     stage("Checkout") {
  75         checkout scm
  76     }
  77
  78     ci_helper = load "jenkins/ci-pipelines/ci_helper.groovy"
  79
  80     def upstream_main_job = params.UPSTREAM_SUFFIX
  81
  82     // upstream jobs always use merged artifacts
  83     upstream_main_job += '-merge'
  84     container_name_prefix = "osm-${tag_or_branch}"
  85     container_name = "${container_name_prefix}"
  86
  87     keep_artifacts = false
  88     if ( JOB_NAME.contains('merge') ) {
  89         container_name += "-merge"
  90
  91         // On a merge job, we keep artifacts on smoke success
  92         keep_artifacts = params.SAVE_ARTIFACTS_ON_SMOKE_SUCCESS
  93     }
  94     container_name += "-${BUILD_NUMBER}"
  95
  96     // Copy the artifacts from the upstream jobs
  97     stage("Copy Artifacts") {
  98         // cleanup any previous repo
  99         sh 'rm -rf repo'
 100         dir("repo") {
 101             // grab all stable upstream builds based on the
 102
 103             dir("${RELEASE}") {
 104                 def list = ["RO", "openvim", "osmclient", "IM", "devops", "MON", "N2VC", "NBI", "common", "LCM", "POL", "LW-UI"]
 105                 for (component in list) {
 106                     step ([$class: 'CopyArtifact',
 107                            projectName: "${component}${upstream_main_job}/${GERRIT_BRANCH}"])
 108
 109                     // grab the build name/number
 110                     //options = get_env_from_build('build.env')
 111                     build_num = ci_helper.get_env_value('build.env','BUILD_NUMBER')
 112
 113                     // grab the archives from the stage_2 builds (ie. this will be the artifacts stored based on a merge)
 114                     ci_helper.get_archive(params.ARTIFACTORY_SERVER,component,GERRIT_BRANCH, "${component}${upstream_main_job} :: ${GERRIT_BRANCH}", build_num)
 115
 116                     // cleanup any prevously defined dists
 117                     sh "rm -rf dists"
 118                 }
 119
 120                 // check if an upstream artifact based on specific build number has been requested
 121                 // This is the case of a merge build and the upstream merge build is not yet complete (it is not deemed
 122                 // a successful build yet). The upstream job is calling this downstream job (with the its build artifiact)
 123                 if ( params.UPSTREAM_JOB_NAME ) {
 124                     step ([$class: 'CopyArtifact',
 125                            projectName: "${params.UPSTREAM_JOB_NAME}",
 126                            selector: [$class: 'SpecificBuildSelector', buildNumber: "${params.UPSTREAM_JOB_NUMBER}"]
 127                           ])
 128
 129                     //options = get_env_from_build('build.env')
 130                     // grab the build name/number
 131                     //build_num = sh(returnStdout:true,  script: "cat build.env | awk -F= '/BUILD_NUMBER/{print \$2}'").trim()
 132                     build_num = ci_helper.get_env_value('build.env','BUILD_NUMBER')
 133                     component = ci_helper.get_mdg_from_project(ci_helper.get_env_value('build.env','GERRIT_PROJECT'))
 134
 135                     // the upstream job name contains suffix with the project. Need this stripped off
 136                     def project_without_branch = params.UPSTREAM_JOB_NAME.split('/')[0]
 137
 138                     // Remove the previous artifact for this component. Use the new upstream artifact
 139                     sh "rm -rf pool/${component}"
 140
 141                     ci_helper.get_archive(params.ARTIFACTORY_SERVER,component,GERRIT_BRANCH, "${project_without_branch} :: ${GERRIT_BRANCH}", build_num)
 142
 143                     sh "rm -rf dists"
 144                 }
 145
 146                 // sign all the components
 147                 for (component in list) {
 148                     sh "dpkg-sig --sign builder -k ${GPG_KEY_NAME} pool/${component}/*"
 149                 }
 150
 151                 // now create the distro
 152                 for (component in list) {
 153                     sh "mkdir -p dists/${params.REPO_DISTRO}/${component}/binary-amd64/"
 154                     sh "apt-ftparchive packages pool/${component} > dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 155                     sh "gzip -9fk dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 156                 }
 157
 158                 // create and sign the release file
 159                 sh "apt-ftparchive release dists/${params.REPO_DISTRO} > dists/${params.REPO_DISTRO}/Release"
 160                 sh "gpg --yes -abs -u ${GPG_KEY_NAME} -o dists/${params.REPO_DISTRO}/Release.gpg dists/${params.REPO_DISTRO}/Release"
 161
 162                 // copy the public key into the release folder
 163                 // this pulls the key from the home dir of the current user (jenkins)
 164                 sh "cp ~/${REPO_KEY_NAME} ."
 165
 166                 // merge the change logs
 167                 sh """
 168                    rm -f changelog/changelog-osm.html
 169                    [ ! -d changelog ] || for mdgchange in \$(ls changelog); do cat changelog/\$mdgchange >> changelog/changelog-osm.html; done
 170                    """
 171                 RELEASE_DIR = sh(returnStdout:true,  script: 'pwd').trim()
 172             }
 173             // start an apache server to serve up the images
 174             http_server_name = "${container_name}-apache"
 175
 176             pwd = sh(returnStdout:true,  script: 'pwd').trim()
 177             repo_base_url = ci_helper.start_http_server(pwd,http_server_name)
 178         }
 179
 180         // now pull the devops package and install in temporary location
 181         tempdir = sh(returnStdout: true, script: "mktemp -d").trim()
 182         osm_devops_dpkg = sh(returnStdout: true, script: "find . -name osm-devops*.deb").trim()
 183         sh "dpkg -x ${osm_devops_dpkg} ${tempdir}"
 184         OSM_DEVOPS="${tempdir}/usr/share/osm-devops"
 185     }
 186
 187     dir(OSM_DEVOPS) {
 188         error = null
 189         if ( params.DO_BUILD ) {
 190             stage("Build") {
 191                 sh "make -C docker clean"
 192                 sh "make -C docker Q= CMD_DOCKER_ARGS= TAG=${container_name} RELEASE=${params.RELEASE} REPOSITORY_BASE=${repo_base_url} REPOSITORY_KEY=${params.REPO_KEY_NAME} REPOSITORY=${params.REPO_DISTRO}"
 193             }
 194         }
 195
 196         try {
 197             if ( params.DO_INSTALL ) {
 198                 stage("Install") {
 199
 200                     //will by default always delete containers on complete
 201                     //sh "jenkins/system/delete_old_containers.sh ${container_name_prefix}"
 202
 203                     commit_id = ''
 204                     repo_distro = ''
 205                     repo_key_name = ''
 206                     release = ''
 207
 208                     if ( params.COMMIT_ID )
 209                     {
 210                         commit_id = "-b ${params.COMMIT_ID}"
 211                     }
 212
 213                     if ( params.REPO_DISTRO )
 214                     {
 215                         repo_distro = "-r ${params.REPO_DISTRO}"
 216                     }
 217
 218                     if ( params.REPO_KEY_NAME )
 219                     {
 220                         repo_key_name = "-k ${params.REPO_KEY_NAME}"
 221                     }
 222
 223                     if ( params.RELEASE )
 224                     {
 225                         release = "-R ${params.RELEASE}"
 226                     }
 227
 228                     if ( params.REPOSITORY_BASE )
 229                     {
 230                         repo_base_url = "-u ${params.REPOSITORY_BASE}"
 231                     }
 232                     sh "docker stack list |  awk '{ print \$1 }'| xargs docker stack rm"
 233                     sh """
 234                         export PATH=$PATH:/snap/bin
 235                         installers/full_install_osm.sh -y -s ${container_name} --test --nolxd --nodocker --nojuju --nohostports --nohostclient \
 236                                                         --nodockerbuild -t ${container_name} \
 237                                                         -w /tmp/osm \
 238                                                         ${commit_id} \
 239                                                         ${repo_distro} \
 240                                                         ${repo_base_url} \
 241                                                         ${repo_key_name} \
 242                                                         ${release} \
 243                                                         ${params.BUILD_FROM_SOURCE}
 244                        """
 245                 }
 246             }
 247
 248             stage_archive = false
 249             if ( params.DO_SMOKE ) {
 250                 stage("OSM Health") {
 251                     sh "installers/osm_health.sh -s ${container_name}"
 252                 }
 253                 stage("Smoke") {
 254                     run_systest(container_name,container_name,"smoke")
 255                     // archive smoke success until stage_4 is ready
 256
 257                     if ( ! currentBuild.result.equals('UNSTABLE') ) {
 258                         stage_archive = keep_artifacts
 259                     }
 260                 }
 261             }
 262
 263             if ( params.DO_STAGE_4 ) {
 264                 // override stage_archive to only archive on stable
 265                 stage_archive = false
 266                 stage("stage_4") {
 267                     run_systest(container_name,container_name,"openstack_stage_4",params.HIVE_VIM_1)
 268
 269                     if ( ! currentBuild.result.equals('UNSTABLE') ) {
 270                         stage_archive = keep_artifacts
 271                     }
 272                 }
 273             }
 274
 275             // override to save the artifacts
 276             if ( params.SAVE_ARTIFACTS_OVERRIDE || stage_archive ) {
 277                 stage("Archive") {
 278                     sh "echo ${container_name} > build_version.txt"
 279                     archiveArtifacts artifacts: "build_version.txt", fingerprint: true
 280
 281                     // Archive the tested repo
 282                     dir("${RELEASE_DIR}") {
 283                         ci_helper.archive(params.ARTIFACTORY_SERVER,RELEASE,GERRIT_BRANCH,'tested')
 284                     }
 285                     if ( params.DO_DOCKERPUSH ) {
 286                         stage("Docker Push") {
 287                             sh "make -C docker push INPUT_TAG=${container_name} TAG=${params.DOCKER_TAG}"
 288                         }
 289                     }
 290                 }
 291             }
 292         }
 293         catch(caughtError) {
 294             println("Caught error!")
 295             error = caughtError
 296             currentBuild.result = 'FAILURE'
 297         }
 298         finally {
 299             sh "docker stop ${http_server_name}"
 300             sh "docker rm ${http_server_name}"
 301
 302             if ( params.DO_INSTALL ) {
 303                 if (error) {
 304                     if ( !params.SAVE_CONTAINER_ON_FAIL ) {
 305                         uninstall_osm container_name
 306                     }
 307                     throw error
 308                 }
 309                 else {
 310                     if ( !params.SAVE_CONTAINER_ON_PASS ) {
 311                         uninstall_osm container_name
 312                     }
 313                 }
 314             }
 315         }
 316     }
 317 }