jenkins/ci-pipelines/ci_stage_3.groovy

   1 /* Copyright ETSI Contributors and Others
   2  *
   3  * All Rights Reserved.
   4  *
   5  *   Licensed under the Apache License, Version 2.0 (the "License"); you may
   6  *   not use this file except in compliance with the License. You may obtain
   7  *   a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *   Unless required by applicable law or agreed to in writing, software
  12  *   distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  13  *   WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  14  *   License for the specific language governing permissions and limitations
  15  *   under the License.
  16  */
  17
  18 properties([
  19     parameters([
  20         string(defaultValue: env.GERRIT_BRANCH, description: '', name: 'GERRIT_BRANCH'),
  21         string(defaultValue: 'system', description: '', name: 'NODE'),
  22         string(defaultValue: '', description: '', name: 'BUILD_FROM_SOURCE'),
  23         string(defaultValue: 'unstable', description: '', name: 'REPO_DISTRO'),
  24         string(defaultValue: '', description: '', name: 'COMMIT_ID'),
  25         string(defaultValue: '-stage_2', description: '', name: 'UPSTREAM_SUFFIX'),
  26         string(defaultValue: 'pubkey.asc', description: '', name: 'REPO_KEY_NAME'),
  27         string(defaultValue: 'release', description: '', name: 'RELEASE'),
  28         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NAME'),
  29         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  30         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  31         string(defaultValue: 'OSMETSI', description: '', name: 'GPG_KEY_NAME'),
  32         string(defaultValue: 'artifactory-osm', description: '', name: 'ARTIFACTORY_SERVER'),
  33         string(defaultValue: 'osm-stage_4', description: '', name: 'DOWNSTREAM_STAGE_NAME'),
  34         string(defaultValue: 'testing-daily', description: '', name: 'DOCKER_TAG'),
  35         string(defaultValue: 'ubuntu18.04', description: '', name: 'OPENSTACK_BASE_IMAGE'),
  36         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_FAIL'),
  37         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_PASS'),
  38         booleanParam(defaultValue: true, description: '', name: 'SAVE_ARTIFACTS_ON_SMOKE_SUCCESS'),
  39         booleanParam(defaultValue: true, description: '',  name: 'DO_BUILD'),
  40         booleanParam(defaultValue: true, description: '', name: 'DO_INSTALL'),
  41         booleanParam(defaultValue: true, description: '', name: 'DO_DOCKERPUSH'),
  42         booleanParam(defaultValue: false, description: '', name: 'SAVE_ARTIFACTS_OVERRIDE'),
  43         string(defaultValue: '/home/jenkins/hive/openstack-etsi.rc', description: '', name: 'HIVE_VIM_1'),
  44         booleanParam(defaultValue: true, description: '', name: 'DO_ROBOT'),
  45         string(defaultValue: 'sanity', description: 'sanity/regression/daily are the common options', name: 'ROBOT_TAG_NAME'),
  46         string(defaultValue: '/home/jenkins/hive/robot-systest.cfg', description: '', name: 'ROBOT_VIM'),
  47         string(defaultValue: '/home/jenkins/hive/port-mapping-etsi-vim.yaml', description: 'Port mapping file for SDN assist in ETSI VIM', name: 'ROBOT_PORT_MAPPING_VIM'),
  48         string(defaultValue: '/home/jenkins/hive/kubeconfig.yaml', description: '', name: 'KUBECONFIG'),
  49         string(defaultValue: '/home/jenkins/hive/clouds.yaml', description: '', name: 'CLOUDS'),
  50         string(defaultValue: 'Default', description: '', name: 'INSTALLER'),
  51         string(defaultValue: '100.0', description: '% passed Robot tests to mark the build as passed', name: 'ROBOT_PASS_THRESHOLD'),
  52         string(defaultValue: '80.0', description: '% passed Robot tests to mark the build as unstable (if lower, it will be failed)', name: 'ROBOT_UNSTABLE_THRESHOLD'),
  53     ])
  54 ])
  55
  56
  57 ////////////////////////////////////////////////////////////////////////////////////////
  58 // Helper Functions
  59 ////////////////////////////////////////////////////////////////////////////////////////
  60 void run_robot_systest(String tagName,
  61                        String testName,
  62                        String osmHostname,
  63                        String prometheusHostname,
  64                        Integer prometheusPort=null,
  65                        String envfile=null,
  66                        String portmappingfile=null,
  67                        String kubeconfig=null,
  68                        String clouds=null,
  69                        String hostfile=null,
  70                        String jujuPassword=null,
  71                        String osmRSAfile=null,
  72                        String pass_th='0.0',
  73                        String unstable_th='0.0') {
  74     tempdir = sh(returnStdout: true, script: 'mktemp -d').trim()
  75     if ( !envfile ) {
  76         sh(script: "touch ${tempdir}/env")
  77         envfile="${tempdir}/env"
  78     }
  79     PROMETHEUS_PORT_VAR = ""
  80     if ( prometheusPort != null) {
  81         PROMETHEUS_PORT_VAR = "--env PROMETHEUS_PORT="+prometheusPort
  82     }
  83     hostfilemount=""
  84     if ( hostfile ) {
  85         hostfilemount="-v "+hostfile+":/etc/hosts"
  86     }
  87
  88     JUJU_PASSWORD_VAR = ""
  89     if ( jujuPassword != null) {
  90         JUJU_PASSWORD_VAR = "--env JUJU_PASSWORD="+jujuPassword
  91     }
  92
  93     try {
  94         sh "docker run --env OSM_HOSTNAME=${osmHostname} --env PROMETHEUS_HOSTNAME=${prometheusHostname} ${PROMETHEUS_PORT_VAR} ${JUJU_PASSWORD_VAR} --env-file ${envfile} -v ${clouds}:/etc/openstack/clouds.yaml -v ${osmRSAfile}:/root/osm_id_rsa -v ${kubeconfig}:/root/.kube/config -v ${tempdir}:/robot-systest/reports -v ${portmappingfile}:/root/port-mapping.yaml ${hostfilemount} opensourcemano/tests:${tagName} -c -t ${testName}"
  95     } finally {
  96         sh "cp ${tempdir}/* ."
  97         outputDirectory = sh(returnStdout: true, script: "pwd").trim()
  98         println ("Present Directory is : ${outputDirectory}")
  99         step([
 100             $class : 'RobotPublisher',
 101             outputPath : "${outputDirectory}",
 102             outputFileName : "*.xml",
 103             disableArchiveOutput : false,
 104             reportFileName : "report.html",
 105             logFileName : "log.html",
 106             passThreshold : pass_th,
 107             unstableThreshold: unstable_th,
 108             otherFiles : "*.png",
 109         ])
 110     }
 111 }
 112
 113 def archive_logs(remote) {
 114
 115     sshCommand remote: remote, command: '''mkdir -p logs'''
 116     if (useCharmedInstaller) {
 117         sshCommand remote: remote, command: '''
 118             for container in `kubectl get pods -n osm | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 119                 logfile=`echo $container | cut -d- -f1`
 120                 echo "Extracting log for $logfile"
 121                 kubectl logs -n osm $container --timestamps=true 2>&1 > logs/$logfile.log
 122             done
 123         '''
 124     } else {
 125         sshCommand remote: remote, command: '''
 126             for deployment in `kubectl -n osm get deployments | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 127                 echo "Extracting log for $deployment"
 128                 kubectl -n osm logs deployments/$deployment --timestamps=true --all-containers 2>&1 > logs/$deployment.log
 129             done
 130         '''
 131         sshCommand remote: remote, command: '''
 132             for statefulset in `kubectl -n osm get statefulsets | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 133                 echo "Extracting log for $statefulset"
 134                 kubectl -n osm logs statefulsets/$statefulset --timestamps=true --all-containers 2>&1 > logs/$statefulset.log
 135             done
 136         '''
 137     }
 138
 139     sh "rm -rf logs"
 140     sshCommand remote: remote, command: '''ls -al logs'''
 141     sshGet remote: remote, from: 'logs', into: '.', override: true
 142     sh "cp logs/* ."
 143     archiveArtifacts artifacts: '*.log'
 144 }
 145
 146 def get_value(key, output) {
 147     for (String line : output.split( '\n' )) {
 148         data = line.split( '\\|' )
 149         if (data.length > 1) {
 150             if ( data[1].trim() == key ) {
 151                 return data[2].trim()
 152             }
 153         }
 154     }
 155 }
 156
 157 ////////////////////////////////////////////////////////////////////////////////////////
 158 // Main Script
 159 ////////////////////////////////////////////////////////////////////////////////////////
 160 node("${params.NODE}") {
 161
 162     INTERNAL_DOCKER_REGISTRY = 'osm.etsi.org:5050/devops/cicd/'
 163     INTERNAL_DOCKER_PROXY = 'http://172.21.1.1:5000'
 164     SSH_KEY = '~/hive/cicd_rsa'
 165     sh 'env'
 166
 167     tag_or_branch = params.GERRIT_BRANCH.replaceAll(/\./,"")
 168
 169     stage("Checkout") {
 170         checkout scm
 171     }
 172
 173     ci_helper = load "jenkins/ci-pipelines/ci_helper.groovy"
 174
 175     def upstream_main_job = params.UPSTREAM_SUFFIX
 176
 177     // upstream jobs always use merged artifacts
 178     upstream_main_job += '-merge'
 179     container_name_prefix = "osm-${tag_or_branch}"
 180     container_name = "${container_name_prefix}"
 181
 182     keep_artifacts = false
 183     if ( JOB_NAME.contains('merge') ) {
 184         container_name += "-merge"
 185
 186         // On a merge job, we keep artifacts on smoke success
 187         keep_artifacts = params.SAVE_ARTIFACTS_ON_SMOKE_SUCCESS
 188     }
 189     container_name += "-${BUILD_NUMBER}"
 190
 191     server_id = null
 192     http_server_name = null
 193     devopstempdir = null
 194     useCharmedInstaller = params.INSTALLER.equalsIgnoreCase("charmed")
 195
 196     try {
 197         builtModules = [:]
 198 ///////////////////////////////////////////////////////////////////////////////////////
 199 // Fetch stage 2 .deb artifacts
 200 ///////////////////////////////////////////////////////////////////////////////////////
 201         stage("Copy Artifacts") {
 202             // cleanup any previous repo
 203             sh 'rm -rf repo'
 204             dir("repo") {
 205                 packageList = []
 206                 dir("${RELEASE}") {
 207                     RELEASE_DIR = sh(returnStdout:true,  script: 'pwd').trim()
 208
 209                     // check if an upstream artifact based on specific build number has been requested
 210                     // This is the case of a merge build and the upstream merge build is not yet complete (it is not deemed
 211                     // a successful build yet). The upstream job is calling this downstream job (with the its build artifiact)
 212                     def upstreamComponent=""
 213                     if ( params.UPSTREAM_JOB_NAME ) {
 214                         println("Fetching upstream job artifact from ${params.UPSTREAM_JOB_NAME}")
 215
 216                         step ([$class: 'CopyArtifact',
 217                                projectName: "${params.UPSTREAM_JOB_NAME}",
 218                                selector: [$class: 'SpecificBuildSelector',
 219                                buildNumber: "${params.UPSTREAM_JOB_NUMBER}"]
 220                               ])
 221
 222                         upstreamComponent = ci_helper.get_mdg_from_project(
 223                             ci_helper.get_env_value('build.env','GERRIT_PROJECT'))
 224                         def buildNumber = ci_helper.get_env_value('build.env','BUILD_NUMBER')
 225                         dir("$upstreamComponent") {
 226                             // the upstream job name contains suffix with the project. Need this stripped off
 227                             def project_without_branch = params.UPSTREAM_JOB_NAME.split('/')[0]
 228                             def packages = ci_helper.get_archive(params.ARTIFACTORY_SERVER,
 229                                 upstreamComponent,
 230                                 GERRIT_BRANCH,
 231                                 "${project_without_branch} :: ${GERRIT_BRANCH}",
 232                                 buildNumber)
 233
 234                             packageList.addAll(packages)
 235                             println("Fetched pre-merge ${params.UPSTREAM_JOB_NAME}: ${packages}")
 236                         }
 237                     }
 238
 239                     parallelSteps = [:]
 240                     def list = ["RO", "osmclient", "IM", "devops", "MON", "N2VC", "NBI", "common", "LCM", "POL", "NG-UI", "PLA", "tests"]
 241                     if (upstreamComponent.length()>0) {
 242                         println("Skipping upstream fetch of "+upstreamComponent)
 243                         list.remove(upstreamComponent)
 244                     }
 245                     for (buildStep in list) {
 246                         def component = buildStep
 247                         parallelSteps[component] = {
 248                             dir("$component") {
 249                                 println("Fetching artifact for ${component}")
 250                                 step ([$class: 'CopyArtifact',
 251                                        projectName: "${component}${upstream_main_job}/${GERRIT_BRANCH}"])
 252
 253                                 // grab the archives from the stage_2 builds (ie. this will be the artifacts stored based on a merge)
 254                                 def packages = ci_helper.get_archive(params.ARTIFACTORY_SERVER,
 255                                     component,
 256                                     GERRIT_BRANCH,
 257                                     "${component}${upstream_main_job} :: ${GERRIT_BRANCH}",
 258                                     ci_helper.get_env_value('build.env','BUILD_NUMBER'))
 259                                 packageList.addAll(packages)
 260                                 println("Fetched ${component}: ${packages}")
 261                                 sh "rm -rf dists"
 262                             }
 263                         }
 264                     }
 265                     parallel parallelSteps
 266
 267 ///////////////////////////////////////////////////////////////////////////////////////
 268 // Create Devops APT repository
 269 ///////////////////////////////////////////////////////////////////////////////////////
 270                     sh "mkdir -p pool"
 271                     for (component in [ "devops", "IM", "osmclient" ]) {
 272                         sh "ls -al ${component}/pool/"
 273                         sh "cp -r ${component}/pool/* pool/"
 274                         sh "dpkg-sig --sign builder -k ${GPG_KEY_NAME} pool/${component}/*"
 275                         sh "mkdir -p dists/${params.REPO_DISTRO}/${component}/binary-amd64/"
 276                         sh "apt-ftparchive packages pool/${component} > dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 277                         sh "gzip -9fk dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 278                     }
 279
 280                     // create and sign the release file
 281                     sh "apt-ftparchive release dists/${params.REPO_DISTRO} > dists/${params.REPO_DISTRO}/Release"
 282                     sh "gpg --yes -abs -u ${GPG_KEY_NAME} -o dists/${params.REPO_DISTRO}/Release.gpg dists/${params.REPO_DISTRO}/Release"
 283
 284                     // copy the public key into the release folder
 285                     // this pulls the key from the home dir of the current user (jenkins)
 286                     sh "cp ~/${REPO_KEY_NAME} 'OSM ETSI Release Key.gpg'"
 287                     sh "cp ~/${REPO_KEY_NAME} ."
 288                 }
 289
 290                 // start an apache server to serve up the packages
 291                 http_server_name = "${container_name}-apache"
 292
 293                 pwd = sh(returnStdout:true,  script: 'pwd').trim()
 294                 repo_port = sh(script: 'echo $(python -c \'import socket; s=socket.socket(); s.bind(("", 0)); print(s.getsockname()[1]); s.close()\');', returnStdout: true).trim()
 295                 repo_base_url = ci_helper.start_http_server(pwd,http_server_name,repo_port)
 296                 NODE_IP_ADDRESS=sh(returnStdout: true, script:
 297                     "echo ${SSH_CONNECTION} | awk '{print \$3}'").trim()
 298             }
 299
 300             // Unpack devops package into temporary location so that we use it from upstream if it was part of a patch
 301             osm_devops_dpkg = sh(returnStdout: true, script: "find ./repo/release/pool/ -name osm-devops*.deb").trim()
 302             devopstempdir = sh(returnStdout: true, script: "mktemp -d").trim()
 303             println("Extracting local devops package ${osm_devops_dpkg} into ${devopstempdir} for docker build step")
 304             sh "dpkg -x ${osm_devops_dpkg} ${devopstempdir}"
 305             OSM_DEVOPS="${devopstempdir}/usr/share/osm-devops"
 306             // Convert URLs from stage 2 packages to arguments that can be passed to docker build
 307             for (remotePath in packageList) {
 308                 packageName=remotePath.substring(remotePath.lastIndexOf('/')+1)
 309                 packageName=packageName.substring(0,packageName.indexOf('_'))
 310                 builtModules[packageName]=remotePath
 311             }
 312         }
 313
 314 ///////////////////////////////////////////////////////////////////////////////////////
 315 // Build docker containers
 316 ///////////////////////////////////////////////////////////////////////////////////////
 317         dir(OSM_DEVOPS) {
 318             def remote = [:]
 319             error = null
 320             if ( params.DO_BUILD ) {
 321                 withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'gitlab-registry',
 322                                 usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
 323                     sh "docker login ${INTERNAL_DOCKER_REGISTRY} -u ${USERNAME} -p ${PASSWORD}"
 324                 }
 325                 moduleBuildArgs = ""
 326                 for (packageName in builtModules.keySet()) {
 327                     envName=packageName.replaceAll("-","_").toUpperCase()+"_URL"
 328                     moduleBuildArgs += " --build-arg ${envName}=" + builtModules[packageName]
 329                 }
 330                 dir ("docker") {
 331                     stage("Build") {
 332                         containerList = sh(returnStdout: true, script:
 333                             "find . -name Dockerfile -printf '%h\\n' | sed 's|\\./||'")
 334                         containerList=Arrays.asList(containerList.split("\n"))
 335                         print(containerList)
 336                         parallelSteps = [:]
 337                         for (buildStep in containerList) {
 338                             def module = buildStep
 339                             def moduleName = buildStep.toLowerCase()
 340                             def moduleTag = container_name
 341                             parallelSteps[module] = {
 342                                 dir("$module") {
 343                                     sh "docker build -t opensourcemano/${moduleName}:${moduleTag} ${moduleBuildArgs} ."
 344                                     println("Tagging ${moduleName}:${moduleTag}")
 345                                     sh "docker tag opensourcemano/${moduleName}:${moduleTag} ${INTERNAL_DOCKER_REGISTRY}opensourcemano/${moduleName}:${moduleTag}"
 346                                     sh "docker push ${INTERNAL_DOCKER_REGISTRY}opensourcemano/${moduleName}:${moduleTag}"
 347                                 }
 348                             }
 349                         }
 350                         parallel parallelSteps
 351                     }
 352                 }
 353             } // if ( params.DO_BUILD )
 354
 355             if ( params.DO_INSTALL ) {
 356 ///////////////////////////////////////////////////////////////////////////////////////
 357 // Launch VM
 358 ///////////////////////////////////////////////////////////////////////////////////////
 359                 stage("Spawn Remote VM") {
 360                     println("Launching new VM")
 361                     output=sh(returnStdout: true, script: """#!/bin/sh -e
 362                         for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 363                         openstack server create --flavor osm.sanity \
 364                                                 --image ${OPENSTACK_BASE_IMAGE} \
 365                                                 --key-name CICD \
 366                                                 --property build_url="${BUILD_URL}" \
 367                                                 --nic net-id=osm-ext \
 368                                                 ${container_name}
 369                     """).trim()
 370
 371                     server_id = get_value('id', output)
 372
 373                     if (server_id == null) {
 374                         println("VM launch output: ")
 375                         println(output)
 376                         throw new Exception("VM Launch failed")
 377                     }
 378                     println("Target VM is ${server_id}, waiting for IP address to be assigned")
 379
 380                     IP_ADDRESS = ""
 381
 382                     while (IP_ADDRESS == "") {
 383                         output=sh(returnStdout: true, script: """#!/bin/sh -e
 384                             for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 385                             openstack server show ${server_id}
 386                         """).trim()
 387                         IP_ADDRESS = get_value('addresses', output)
 388                     }
 389                     IP_ADDRESS = IP_ADDRESS.split('=')[1]
 390                     println("Waiting for VM at ${IP_ADDRESS} to be reachable")
 391
 392                     alive = false
 393                     while (! alive) {
 394                         output=sh(returnStdout: true, script: "sleep 1 ; nc -zv ${IP_ADDRESS} 22 2>&1 || true").trim()
 395                         println("output is [$output]")
 396                         alive = output.contains("succeeded")
 397                     }
 398                     println("VM is ready and accepting ssh connections")
 399                 } // stage("Spawn Remote VM")
 400
 401 ///////////////////////////////////////////////////////////////////////////////////////
 402 // Installation
 403 ///////////////////////////////////////////////////////////////////////////////////////
 404                 stage("Install") {
 405                     commit_id = ''
 406                     repo_distro = ''
 407                     repo_key_name = ''
 408                     release = ''
 409
 410                     if ( params.COMMIT_ID )
 411                     {
 412                         commit_id = "-b ${params.COMMIT_ID}"
 413                     }
 414
 415                     if ( params.REPO_DISTRO )
 416                     {
 417                         repo_distro = "-r ${params.REPO_DISTRO}"
 418                     }
 419
 420                     if ( params.REPO_KEY_NAME )
 421                     {
 422                         repo_key_name = "-k ${params.REPO_KEY_NAME}"
 423                     }
 424
 425                     if ( params.RELEASE )
 426                     {
 427                         release = "-R ${params.RELEASE}"
 428                     }
 429
 430                     if ( params.REPOSITORY_BASE )
 431                     {
 432                         repo_base_url = "-u ${params.REPOSITORY_BASE}"
 433                     }
 434                     else
 435                     {
 436                         repo_base_url = "-u http://${NODE_IP_ADDRESS}:${repo_port}"
 437                     }
 438
 439                     remote.name = container_name
 440                     remote.host = IP_ADDRESS
 441                     remote.user = 'ubuntu'
 442                     remote.identityFile = SSH_KEY
 443                     remote.allowAnyHosts = true
 444                     remote.logLevel = 'INFO'
 445                     remote.pty = true
 446
 447                     sshCommand remote: remote, command: """
 448                         wget https://osm-download.etsi.org/ftp/osm-11.0-eleven/install_osm.sh
 449                         chmod +x ./install_osm.sh
 450                         sed -i '1 i\\export PATH=/snap/bin:\${PATH}' ~/.bashrc
 451                     """
 452
 453                     if ( useCharmedInstaller ) {
 454                         // Use local proxy for docker hub
 455                         sshCommand remote: remote, command: '''
 456                             sudo snap install microk8s --classic --channel=1.19/stable
 457                             sudo sed -i "s|https://registry-1.docker.io|http://172.21.1.1:5000|" /var/snap/microk8s/current/args/containerd-template.toml
 458                             sudo systemctl restart snap.microk8s.daemon-containerd.service
 459                             sudo snap alias microk8s.kubectl kubectl
 460                         '''
 461
 462                         withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'gitlab-registry',
 463                                         usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
 464                             sshCommand remote: remote, command: """
 465                                 ./install_osm.sh -y \
 466                                     ${repo_base_url} \
 467                                     ${repo_key_name} \
 468                                     ${release} -r unstable \
 469                                     --charmed  \
 470                                     --registry ${USERNAME}:${PASSWORD}@${INTERNAL_DOCKER_REGISTRY} \
 471                                     --tag ${container_name}
 472                             """
 473                         }
 474                         prometheusHostname = "prometheus."+IP_ADDRESS+".nip.io"
 475                         prometheusPort = 80
 476                         osmHostname = "nbi."+IP_ADDRESS+".nip.io:443"
 477                     } else {
 478                         // Run -k8s installer here specifying internal docker registry and docker proxy
 479                         withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'gitlab-registry',
 480                                         usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
 481                             sshCommand remote: remote, command: """
 482                                 ./install_osm.sh -y \
 483                                     ${repo_base_url} \
 484                                     ${repo_key_name} \
 485                                     ${release} -r unstable \
 486                                     -d ${USERNAME}:${PASSWORD}@${INTERNAL_DOCKER_REGISTRY} \
 487                                     -p ${INTERNAL_DOCKER_PROXY} \
 488                                     -t ${container_name}
 489                             """
 490                         }
 491                         prometheusHostname = IP_ADDRESS
 492                         prometheusPort = 9091
 493                         osmHostname = IP_ADDRESS
 494                     }
 495                 } // stage("Install")
 496 ///////////////////////////////////////////////////////////////////////////////////////
 497 // Health check of installed OSM in remote vm
 498 ///////////////////////////////////////////////////////////////////////////////////////
 499                 stage("OSM Health") {
 500                     stackName = "osm"
 501                     sshCommand remote: remote, command: """
 502                         /usr/share/osm-devops/installers/osm_health.sh -k -s ${stackName}
 503                     """
 504                 } // stage("OSM Health")
 505             } // if ( params.DO_INSTALL )
 506
 507
 508 ///////////////////////////////////////////////////////////////////////////////////////
 509 // Execute Robot tests
 510 ///////////////////////////////////////////////////////////////////////////////////////
 511             stage_archive = false
 512             if ( params.DO_ROBOT ) {
 513                 try {
 514                     stage("System Integration Test") {
 515                         if ( useCharmedInstaller ) {
 516                             tempdir = sh(returnStdout: true, script: "mktemp -d").trim()
 517                             sh(script: "touch ${tempdir}/hosts")
 518                             hostfile="${tempdir}/hosts"
 519                             sh """cat << EOF > ${hostfile}
 520 127.0.0.1           localhost
 521 ${remote.host}      prometheus.${remote.host}.nip.io nbi.${remote.host}.nip.io
 522 EOF"""
 523                         } else {
 524                             hostfile=null
 525                         }
 526
 527                         jujuPassword=sshCommand remote: remote, command: """
 528                             echo `juju gui 2>&1 | grep password | cut -d: -f2`
 529                         """
 530
 531                         run_robot_systest(
 532                             container_name,
 533                             params.ROBOT_TAG_NAME,
 534                             osmHostname,
 535                             prometheusHostname,
 536                             prometheusPort,
 537                             params.ROBOT_VIM,
 538                             params.ROBOT_PORT_MAPPING_VIM,
 539                             params.KUBECONFIG,
 540                             params.CLOUDS,
 541                             hostfile,
 542                             jujuPassword,
 543                             SSH_KEY,
 544                             params.ROBOT_PASS_THRESHOLD,
 545                             params.ROBOT_UNSTABLE_THRESHOLD
 546                         )
 547                     } // stage("System Integration Test")
 548                 } finally {
 549                     stage("Archive Container Logs") {
 550                         // Archive logs to containers_logs.txt
 551                         archive_logs(remote)
 552                         if ( ! currentBuild.result.equals('FAILURE') ) {
 553                             stage_archive = keep_artifacts
 554                         } else {
 555                             println ("Systest test failed, throwing error")
 556                             error = new Exception("Systest test failed")
 557                             currentBuild.result = 'FAILURE'
 558                             throw error
 559                         }
 560                     }
 561                 }
 562             } // if ( params.DO_ROBOT )
 563
 564             if ( params.SAVE_ARTIFACTS_OVERRIDE || stage_archive ) {
 565                 stage("Archive") {
 566                     sh "echo ${container_name} > build_version.txt"
 567                     archiveArtifacts artifacts: "build_version.txt", fingerprint: true
 568
 569                     // Archive the tested repo
 570                     dir("${RELEASE_DIR}") {
 571                         ci_helper.archive(params.ARTIFACTORY_SERVER,RELEASE,GERRIT_BRANCH,'tested')
 572                     }
 573                     if ( params.DO_DOCKERPUSH ) {
 574                         stage("Publish to Dockerhub") {
 575                             parallelSteps = [:]
 576                             for (buildStep in containerList) {
 577                                 def module = buildStep
 578                                 def moduleName = buildStep.toLowerCase()
 579                                 def dockerTag = params.DOCKER_TAG
 580                                 def moduleTag = container_name
 581
 582                                 parallelSteps[module] = {
 583                                     dir("$module") {
 584                                         sh "docker tag opensourcemano/${moduleName}:${moduleTag} opensourcemano/${moduleName}:${dockerTag}"
 585                                         sh "docker push opensourcemano/${moduleName}:${dockerTag}"
 586                                     }
 587                                 }
 588                             }
 589                             parallel parallelSteps
 590                         }
 591
 592                         stage("Snap promotion") {
 593                             def snaps = ["osmclient"]
 594                             sh "snapcraft login --with ~/.snapcraft/config"
 595                             for (snap in snaps) {
 596                                 channel="latest/"
 597                                 if (BRANCH_NAME.startsWith("v")) {
 598                                     channel=BRANCH_NAME.substring(1)+"/"
 599                                 } else if (BRANCH_NAME!="master") {
 600                                     channel+="/"+BRANCH_NAME.replaceAll('/','-')
 601                                 }
 602                                 track=channel+"edge\\*"
 603                                 edge_rev=sh(returnStdout: true,
 604                                     script: "snapcraft revisions $snap | " +
 605                                     "grep \"$track\" | tail -1 | awk '{print \$1}'").trim()
 606                                 print "edge rev is $edge_rev"
 607                                 track=channel+"beta\\*"
 608                                 beta_rev=sh(returnStdout: true,
 609                                     script: "snapcraft revisions $snap | " +
 610                                     "grep \"$track\" | tail -1 | awk '{print \$1}'").trim()
 611                                 print "beta rev is $beta_rev"
 612
 613                                 if ( edge_rev != beta_rev ) {
 614                                     print "Promoting $edge_rev to beta in place of $beta_rev"
 615                                     beta_track=channel+"beta"
 616                                     sh "snapcraft release $snap $edge_rev $beta_track"
 617                                 }
 618                             }
 619                         } // stage("Snap promotion")
 620                     } // if ( params.DO_DOCKERPUSH )
 621                 } // stage("Archive")
 622             } // if ( params.SAVE_ARTIFACTS_OVERRIDE || stage_archive )
 623         } // dir(OSM_DEVOPS)
 624     } finally {
 625         if ( params.DO_INSTALL && server_id != null) {
 626             delete_vm = true
 627             if (error && params.SAVE_CONTAINER_ON_FAIL ) {
 628                 delete_vm = false
 629             }
 630             if (!error && params.SAVE_CONTAINER_ON_PASS ) {
 631                 delete_vm = false
 632             }
 633
 634             if ( delete_vm ) {
 635                 if (server_id != null) {
 636                     println("Deleting VM: $server_id")
 637                     sh """#!/bin/sh -e
 638                         for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 639                         openstack server delete ${server_id}
 640                     """
 641                 } else {
 642                     println("Saved VM $server_id in ETSI VIM")
 643                 }
 644             }
 645         }
 646         if ( http_server_name != null ) {
 647             sh "docker stop ${http_server_name} || true"
 648             sh "docker rm ${http_server_name} || true"
 649         }
 650
 651         if ( devopstempdir != null ) {
 652             sh "rm -rf ${devopstempdir}"
 653         }
 654     }
 655 }