jenkins/ci-pipelines/ci_stage_3.groovy

   1 /* Copyright ETSI Contributors and Others
   2  *
   3  * All Rights Reserved.
   4  *
   5  *   Licensed under the Apache License, Version 2.0 (the "License"); you may
   6  *   not use this file except in compliance with the License. You may obtain
   7  *   a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *   Unless required by applicable law or agreed to in writing, software
  12  *   distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  13  *   WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  14  *   License for the specific language governing permissions and limitations
  15  *   under the License.
  16  */
  17
  18 properties([
  19     parameters([
  20         string(defaultValue: env.GERRIT_BRANCH, description: '', name: 'GERRIT_BRANCH'),
  21         string(defaultValue: 'system', description: '', name: 'NODE'),
  22         string(defaultValue: '', description: '', name: 'BUILD_FROM_SOURCE'),
  23         string(defaultValue: 'unstable', description: '', name: 'REPO_DISTRO'),
  24         string(defaultValue: '', description: '', name: 'COMMIT_ID'),
  25         string(defaultValue: '-stage_2', description: '', name: 'UPSTREAM_SUFFIX'),
  26         string(defaultValue: 'pubkey.asc', description: '', name: 'REPO_KEY_NAME'),
  27         string(defaultValue: 'release', description: '', name: 'RELEASE'),
  28         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NAME'),
  29         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  30         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  31         string(defaultValue: 'OSMETSI', description: '', name: 'GPG_KEY_NAME'),
  32         string(defaultValue: 'artifactory-osm', description: '', name: 'ARTIFACTORY_SERVER'),
  33         string(defaultValue: 'osm-stage_4', description: '', name: 'DOWNSTREAM_STAGE_NAME'),
  34         string(defaultValue: 'testing-daily', description: '', name: 'DOCKER_TAG'),
  35         string(defaultValue: 'ubuntu20.04', description: '', name: 'OPENSTACK_BASE_IMAGE'),
  36         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_FAIL'),
  37         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_PASS'),
  38         booleanParam(defaultValue: true, description: '', name: 'SAVE_ARTIFACTS_ON_SMOKE_SUCCESS'),
  39         booleanParam(defaultValue: true, description: '',  name: 'DO_BUILD'),
  40         booleanParam(defaultValue: true, description: '', name: 'DO_INSTALL'),
  41         booleanParam(defaultValue: true, description: '', name: 'DO_DOCKERPUSH'),
  42         booleanParam(defaultValue: false, description: '', name: 'SAVE_ARTIFACTS_OVERRIDE'),
  43         string(defaultValue: '/home/jenkins/hive/openstack-etsi.rc', description: '', name: 'HIVE_VIM_1'),
  44         booleanParam(defaultValue: true, description: '', name: 'DO_ROBOT'),
  45         string(defaultValue: 'sanity', description: 'sanity/regression/daily are the common options', name: 'ROBOT_TAG_NAME'),
  46         string(defaultValue: '/home/jenkins/hive/robot-systest.cfg', description: '', name: 'ROBOT_VIM'),
  47         string(defaultValue: '/home/jenkins/hive/port-mapping-etsi-vim.yaml', description: 'Port mapping file for SDN assist in ETSI VIM', name: 'ROBOT_PORT_MAPPING_VIM'),
  48         string(defaultValue: '/home/jenkins/hive/kubeconfig.yaml', description: '', name: 'KUBECONFIG'),
  49         string(defaultValue: '/home/jenkins/hive/clouds.yaml', description: '', name: 'CLOUDS'),
  50         string(defaultValue: 'Default', description: '', name: 'INSTALLER'),
  51         string(defaultValue: '100.0', description: '% passed Robot tests to mark the build as passed', name: 'ROBOT_PASS_THRESHOLD'),
  52         string(defaultValue: '80.0', description: '% passed Robot tests to mark the build as unstable (if lower, it will be failed)', name: 'ROBOT_UNSTABLE_THRESHOLD'),
  53     ])
  54 ])
  55
  56
  57 ////////////////////////////////////////////////////////////////////////////////////////
  58 // Helper Functions
  59 ////////////////////////////////////////////////////////////////////////////////////////
  60 void run_robot_systest(String tagName,
  61                        String testName,
  62                        String osmHostname,
  63                        String prometheusHostname,
  64                        Integer prometheusPort=null,
  65                        String envfile=null,
  66                        String portmappingfile=null,
  67                        String kubeconfig=null,
  68                        String clouds=null,
  69                        String hostfile=null,
  70                        String jujuPassword=null,
  71                        String osmRSAfile=null,
  72                        String pass_th='0.0',
  73                        String unstable_th='0.0') {
  74     tempdir = sh(returnStdout: true, script: 'mktemp -d').trim()
  75     if ( !envfile ) {
  76         sh(script: "touch ${tempdir}/env")
  77         envfile="${tempdir}/env"
  78     }
  79     PROMETHEUS_PORT_VAR = ""
  80     if ( prometheusPort != null) {
  81         PROMETHEUS_PORT_VAR = "--env PROMETHEUS_PORT="+prometheusPort
  82     }
  83     hostfilemount=""
  84     if ( hostfile ) {
  85         hostfilemount="-v "+hostfile+":/etc/hosts"
  86     }
  87
  88     JUJU_PASSWORD_VAR = ""
  89     if ( jujuPassword != null) {
  90         JUJU_PASSWORD_VAR = "--env JUJU_PASSWORD="+jujuPassword
  91     }
  92
  93     try {
  94         sh "docker run --env OSM_HOSTNAME=${osmHostname} --env PROMETHEUS_HOSTNAME=${prometheusHostname} ${PROMETHEUS_PORT_VAR} ${JUJU_PASSWORD_VAR} --env-file ${envfile} -v ${clouds}:/etc/openstack/clouds.yaml -v ${osmRSAfile}:/root/osm_id_rsa -v ${kubeconfig}:/root/.kube/config -v ${tempdir}:/robot-systest/reports -v ${portmappingfile}:/root/port-mapping.yaml ${hostfilemount} opensourcemano/tests:${tagName} -c -t ${testName}"
  95     } finally {
  96         sh "cp ${tempdir}/* ."
  97         outputDirectory = sh(returnStdout: true, script: "pwd").trim()
  98         println ("Present Directory is : ${outputDirectory}")
  99         step([
 100             $class : 'RobotPublisher',
 101             outputPath : "${outputDirectory}",
 102             outputFileName : "*.xml",
 103             disableArchiveOutput : false,
 104             reportFileName : "report.html",
 105             logFileName : "log.html",
 106             passThreshold : pass_th,
 107             unstableThreshold: unstable_th,
 108             otherFiles : "*.png",
 109         ])
 110     }
 111 }
 112
 113 def archive_logs(remote) {
 114
 115     sshCommand remote: remote, command: '''mkdir -p logs'''
 116     if (useCharmedInstaller) {
 117         sshCommand remote: remote, command: '''
 118             for container in `kubectl get pods -n osm | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 119                 logfile=`echo $container | cut -d- -f1`
 120                 echo "Extracting log for $logfile"
 121                 kubectl logs -n osm $container --timestamps=true 2>&1 > logs/$logfile.log
 122             done
 123         '''
 124     } else {
 125         sshCommand remote: remote, command: '''
 126             for deployment in `kubectl -n osm get deployments | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 127                 echo "Extracting log for $deployment"
 128                 kubectl -n osm logs deployments/$deployment --timestamps=true --all-containers 2>&1 > logs/$deployment.log
 129             done
 130         '''
 131         sshCommand remote: remote, command: '''
 132             for statefulset in `kubectl -n osm get statefulsets | grep -v operator | grep -v NAME| awk '{print $1}'`; do
 133                 echo "Extracting log for $statefulset"
 134                 kubectl -n osm logs statefulsets/$statefulset --timestamps=true --all-containers 2>&1 > logs/$statefulset.log
 135             done
 136         '''
 137     }
 138
 139     sh "rm -rf logs"
 140     sshCommand remote: remote, command: '''ls -al logs'''
 141     sshGet remote: remote, from: 'logs', into: '.', override: true
 142     sh "cp logs/* ."
 143     archiveArtifacts artifacts: '*.log'
 144 }
 145
 146 def get_value(key, output) {
 147     for (String line : output.split( '\n' )) {
 148         data = line.split( '\\|' )
 149         if (data.length > 1) {
 150             if ( data[1].trim() == key ) {
 151                 return data[2].trim()
 152             }
 153         }
 154     }
 155 }
 156
 157 ////////////////////////////////////////////////////////////////////////////////////////
 158 // Main Script
 159 ////////////////////////////////////////////////////////////////////////////////////////
 160 node("${params.NODE}") {
 161
 162     INTERNAL_DOCKER_REGISTRY = 'osm.etsi.org:5050/devops/cicd/'
 163     INTERNAL_DOCKER_PROXY = 'http://172.21.1.1:5000'
 164     APT_PROXY="http://172.21.1.1:3142"
 165     SSH_KEY = '~/hive/cicd_rsa'
 166     sh 'env'
 167
 168     tag_or_branch = params.GERRIT_BRANCH.replaceAll(/\./,"")
 169
 170     stage("Checkout") {
 171         checkout scm
 172     }
 173
 174     ci_helper = load "jenkins/ci-pipelines/ci_helper.groovy"
 175
 176     def upstream_main_job = params.UPSTREAM_SUFFIX
 177
 178     // upstream jobs always use merged artifacts
 179     upstream_main_job += '-merge'
 180     container_name_prefix = "osm-${tag_or_branch}"
 181     container_name = "${container_name_prefix}"
 182
 183     keep_artifacts = false
 184     if ( JOB_NAME.contains('merge') ) {
 185         container_name += "-merge"
 186
 187         // On a merge job, we keep artifacts on smoke success
 188         keep_artifacts = params.SAVE_ARTIFACTS_ON_SMOKE_SUCCESS
 189     }
 190     container_name += "-${BUILD_NUMBER}"
 191
 192     server_id = null
 193     http_server_name = null
 194     devopstempdir = null
 195     useCharmedInstaller = params.INSTALLER.equalsIgnoreCase("charmed")
 196
 197     try {
 198         builtModules = [:]
 199 ///////////////////////////////////////////////////////////////////////////////////////
 200 // Fetch stage 2 .deb artifacts
 201 ///////////////////////////////////////////////////////////////////////////////////////
 202         stage("Copy Artifacts") {
 203             // cleanup any previous repo
 204             sh 'rm -rf repo'
 205             dir("repo") {
 206                 packageList = []
 207                 dir("${RELEASE}") {
 208                     RELEASE_DIR = sh(returnStdout:true,  script: 'pwd').trim()
 209
 210                     // check if an upstream artifact based on specific build number has been requested
 211                     // This is the case of a merge build and the upstream merge build is not yet complete (it is not deemed
 212                     // a successful build yet). The upstream job is calling this downstream job (with the its build artifiact)
 213                     def upstreamComponent=""
 214                     if ( params.UPSTREAM_JOB_NAME ) {
 215                         println("Fetching upstream job artifact from ${params.UPSTREAM_JOB_NAME}")
 216
 217                         step ([$class: 'CopyArtifact',
 218                                projectName: "${params.UPSTREAM_JOB_NAME}",
 219                                selector: [$class: 'SpecificBuildSelector',
 220                                buildNumber: "${params.UPSTREAM_JOB_NUMBER}"]
 221                               ])
 222
 223                         upstreamComponent = ci_helper.get_mdg_from_project(
 224                             ci_helper.get_env_value('build.env','GERRIT_PROJECT'))
 225                         def buildNumber = ci_helper.get_env_value('build.env','BUILD_NUMBER')
 226                         dir("$upstreamComponent") {
 227                             // the upstream job name contains suffix with the project. Need this stripped off
 228                             def project_without_branch = params.UPSTREAM_JOB_NAME.split('/')[0]
 229                             def packages = ci_helper.get_archive(params.ARTIFACTORY_SERVER,
 230                                 upstreamComponent,
 231                                 GERRIT_BRANCH,
 232                                 "${project_without_branch} :: ${GERRIT_BRANCH}",
 233                                 buildNumber)
 234
 235                             packageList.addAll(packages)
 236                             println("Fetched pre-merge ${params.UPSTREAM_JOB_NAME}: ${packages}")
 237                         }
 238                     }
 239
 240                     parallelSteps = [:]
 241                     def list = ["RO", "osmclient", "IM", "devops", "MON", "N2VC", "NBI", "common", "LCM", "POL", "NG-UI", "PLA", "tests"]
 242                     if (upstreamComponent.length()>0) {
 243                         println("Skipping upstream fetch of "+upstreamComponent)
 244                         list.remove(upstreamComponent)
 245                     }
 246                     for (buildStep in list) {
 247                         def component = buildStep
 248                         parallelSteps[component] = {
 249                             dir("$component") {
 250                                 println("Fetching artifact for ${component}")
 251                                 step ([$class: 'CopyArtifact',
 252                                        projectName: "${component}${upstream_main_job}/${GERRIT_BRANCH}"])
 253
 254                                 // grab the archives from the stage_2 builds (ie. this will be the artifacts stored based on a merge)
 255                                 def packages = ci_helper.get_archive(params.ARTIFACTORY_SERVER,
 256                                     component,
 257                                     GERRIT_BRANCH,
 258                                     "${component}${upstream_main_job} :: ${GERRIT_BRANCH}",
 259                                     ci_helper.get_env_value('build.env','BUILD_NUMBER'))
 260                                 packageList.addAll(packages)
 261                                 println("Fetched ${component}: ${packages}")
 262                                 sh "rm -rf dists"
 263                             }
 264                         }
 265                     }
 266                     parallel parallelSteps
 267
 268 ///////////////////////////////////////////////////////////////////////////////////////
 269 // Create Devops APT repository
 270 ///////////////////////////////////////////////////////////////////////////////////////
 271                     sh "mkdir -p pool"
 272                     for (component in [ "devops", "IM", "osmclient" ]) {
 273                         sh "ls -al ${component}/pool/"
 274                         sh "cp -r ${component}/pool/* pool/"
 275                         sh "dpkg-sig --sign builder -k ${GPG_KEY_NAME} pool/${component}/*"
 276                         sh "mkdir -p dists/${params.REPO_DISTRO}/${component}/binary-amd64/"
 277                         sh "apt-ftparchive packages pool/${component} > dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 278                         sh "gzip -9fk dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 279                     }
 280
 281                     // create and sign the release file
 282                     sh "apt-ftparchive release dists/${params.REPO_DISTRO} > dists/${params.REPO_DISTRO}/Release"
 283                     sh "gpg --yes -abs -u ${GPG_KEY_NAME} -o dists/${params.REPO_DISTRO}/Release.gpg dists/${params.REPO_DISTRO}/Release"
 284
 285                     // copy the public key into the release folder
 286                     // this pulls the key from the home dir of the current user (jenkins)
 287                     sh "cp ~/${REPO_KEY_NAME} 'OSM ETSI Release Key.gpg'"
 288                     sh "cp ~/${REPO_KEY_NAME} ."
 289                 }
 290
 291                 // start an apache server to serve up the packages
 292                 http_server_name = "${container_name}-apache"
 293
 294                 pwd = sh(returnStdout:true,  script: 'pwd').trim()
 295                 repo_port = sh(script: 'echo $(python -c \'import socket; s=socket.socket(); s.bind(("", 0)); print(s.getsockname()[1]); s.close()\');', returnStdout: true).trim()
 296                 repo_base_url = ci_helper.start_http_server(pwd,http_server_name,repo_port)
 297                 NODE_IP_ADDRESS=sh(returnStdout: true, script:
 298                     "echo ${SSH_CONNECTION} | awk '{print \$3}'").trim()
 299             }
 300
 301             // Unpack devops package into temporary location so that we use it from upstream if it was part of a patch
 302             osm_devops_dpkg = sh(returnStdout: true, script: "find ./repo/release/pool/ -name osm-devops*.deb").trim()
 303             devopstempdir = sh(returnStdout: true, script: "mktemp -d").trim()
 304             println("Extracting local devops package ${osm_devops_dpkg} into ${devopstempdir} for docker build step")
 305             sh "dpkg -x ${osm_devops_dpkg} ${devopstempdir}"
 306             OSM_DEVOPS="${devopstempdir}/usr/share/osm-devops"
 307             // Convert URLs from stage 2 packages to arguments that can be passed to docker build
 308             for (remotePath in packageList) {
 309                 packageName=remotePath.substring(remotePath.lastIndexOf('/')+1)
 310                 packageName=packageName.substring(0,packageName.indexOf('_'))
 311                 builtModules[packageName]=remotePath
 312             }
 313         }
 314
 315 ///////////////////////////////////////////////////////////////////////////////////////
 316 // Build docker containers
 317 ///////////////////////////////////////////////////////////////////////////////////////
 318         dir(OSM_DEVOPS) {
 319             def remote = [:]
 320             error = null
 321             if ( params.DO_BUILD ) {
 322                 withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'gitlab-registry',
 323                                 usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
 324                     sh "docker login ${INTERNAL_DOCKER_REGISTRY} -u ${USERNAME} -p ${PASSWORD}"
 325                 }
 326                 datetime = sh(returnStdout: true, script: "date +%Y-%m-%d:%H:%M:%S").trim()
 327                 moduleBuildArgs = " --build-arg CACHE_DATE=${datetime}"
 328                 for (packageName in builtModules.keySet()) {
 329                     envName=packageName.replaceAll("-","_").toUpperCase()+"_URL"
 330                     moduleBuildArgs += " --build-arg ${envName}=" + builtModules[packageName]
 331                 }
 332                 dir ("docker") {
 333                     stage("Build") {
 334                         containerList = sh(returnStdout: true, script:
 335                             "find . -name Dockerfile -printf '%h\\n' | sed 's|\\./||'")
 336                         containerList=Arrays.asList(containerList.split("\n"))
 337                         print(containerList)
 338                         parallelSteps = [:]
 339                         for (buildStep in containerList) {
 340                             def module = buildStep
 341                             def moduleName = buildStep.toLowerCase()
 342                             def moduleTag = container_name
 343                             parallelSteps[module] = {
 344                                 dir("$module") {
 345                                     sh "docker build --build-arg APT_PROXY=${APT_PROXY} -t opensourcemano/${moduleName}:${moduleTag} ${moduleBuildArgs} ."
 346                                     println("Tagging ${moduleName}:${moduleTag}")
 347                                     sh "docker tag opensourcemano/${moduleName}:${moduleTag} ${INTERNAL_DOCKER_REGISTRY}opensourcemano/${moduleName}:${moduleTag}"
 348                                     sh "docker push ${INTERNAL_DOCKER_REGISTRY}opensourcemano/${moduleName}:${moduleTag}"
 349                                 }
 350                             }
 351                         }
 352                         parallel parallelSteps
 353                     }
 354                 }
 355             } // if ( params.DO_BUILD )
 356
 357             if ( params.DO_INSTALL ) {
 358 ///////////////////////////////////////////////////////////////////////////////////////
 359 // Launch VM
 360 ///////////////////////////////////////////////////////////////////////////////////////
 361                 stage("Spawn Remote VM") {
 362                     println("Launching new VM")
 363                     output=sh(returnStdout: true, script: """#!/bin/sh -e
 364                         for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 365                         openstack server create --flavor osm.sanity \
 366                                                 --image ${OPENSTACK_BASE_IMAGE} \
 367                                                 --key-name CICD \
 368                                                 --property build_url="${BUILD_URL}" \
 369                                                 --nic net-id=osm-ext \
 370                                                 ${container_name}
 371                     """).trim()
 372
 373                     server_id = get_value('id', output)
 374
 375                     if (server_id == null) {
 376                         println("VM launch output: ")
 377                         println(output)
 378                         throw new Exception("VM Launch failed")
 379                     }
 380                     println("Target VM is ${server_id}, waiting for IP address to be assigned")
 381
 382                     IP_ADDRESS = ""
 383
 384                     while (IP_ADDRESS == "") {
 385                         output=sh(returnStdout: true, script: """#!/bin/sh -e
 386                             for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 387                             openstack server show ${server_id}
 388                         """).trim()
 389                         IP_ADDRESS = get_value('addresses', output)
 390                     }
 391                     IP_ADDRESS = IP_ADDRESS.split('=')[1]
 392                     println("Waiting for VM at ${IP_ADDRESS} to be reachable")
 393
 394                     alive = false
 395                     while (! alive) {
 396                         output=sh(returnStdout: true, script: "sleep 1 ; nc -zv ${IP_ADDRESS} 22 2>&1 || true").trim()
 397                         println("output is [$output]")
 398                         alive = output.contains("succeeded")
 399                     }
 400                     println("VM is ready and accepting ssh connections")
 401                 } // stage("Spawn Remote VM")
 402
 403 ///////////////////////////////////////////////////////////////////////////////////////
 404 // Installation
 405 ///////////////////////////////////////////////////////////////////////////////////////
 406                 stage("Install") {
 407                     commit_id = ''
 408                     repo_distro = ''
 409                     repo_key_name = ''
 410                     release = ''
 411
 412                     if ( params.COMMIT_ID )
 413                     {
 414                         commit_id = "-b ${params.COMMIT_ID}"
 415                     }
 416
 417                     if ( params.REPO_DISTRO )
 418                     {
 419                         repo_distro = "-r ${params.REPO_DISTRO}"
 420                     }
 421
 422                     if ( params.REPO_KEY_NAME )
 423                     {
 424                         repo_key_name = "-k ${params.REPO_KEY_NAME}"
 425                     }
 426
 427                     if ( params.RELEASE )
 428                     {
 429                         release = "-R ${params.RELEASE}"
 430                     }
 431
 432                     if ( params.REPOSITORY_BASE )
 433                     {
 434                         repo_base_url = "-u ${params.REPOSITORY_BASE}"
 435                     }
 436                     else
 437                     {
 438                         repo_base_url = "-u http://${NODE_IP_ADDRESS}:${repo_port}"
 439                     }
 440
 441                     remote.name = container_name
 442                     remote.host = IP_ADDRESS
 443                     remote.user = 'ubuntu'
 444                     remote.identityFile = SSH_KEY
 445                     remote.allowAnyHosts = true
 446                     remote.logLevel = 'INFO'
 447                     remote.pty = true
 448
 449                     sshCommand remote: remote, command: """
 450                         echo "Acquire::http::Proxy \\"$APT_PROXY\\";" | sudo tee /etc/apt/apt.conf.d/proxy.conf
 451                         echo "Acquire::https::Proxy \\"$APT_PROXY\\";" | sudo tee -a /etc/apt/apt.conf.d/proxy.conf
 452                         cat /etc/apt/apt.conf.d/proxy.conf
 453                     """
 454                     // Force time sync to avoid clock drift and invalid certificates
 455                     sshCommand remote: remote, command: """
 456                         sudo apt update
 457                         sudo apt install -y ntp
 458                         sudo service ntp stop
 459                         sudo ntpd -gq
 460                         sudo service ntp start
 461                     """
 462
 463                     sshCommand remote: remote, command: """
 464                         wget https://osm-download.etsi.org/ftp/osm-11.0-eleven/install_osm.sh
 465                         chmod +x ./install_osm.sh
 466                         sed -i '1 i\\export PATH=/snap/bin:\${PATH}' ~/.bashrc
 467                     """
 468
 469                     if ( useCharmedInstaller ) {
 470                         // Use local proxy for docker hub
 471                         sshCommand remote: remote, command: '''
 472                             sudo snap install microk8s --classic --channel=1.19/stable
 473                             sudo sed -i "s|https://registry-1.docker.io|http://172.21.1.1:5000|" /var/snap/microk8s/current/args/containerd-template.toml
 474                             sudo systemctl restart snap.microk8s.daemon-containerd.service
 475                             sudo snap alias microk8s.kubectl kubectl
 476                         '''
 477
 478                         withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'gitlab-registry',
 479                                         usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
 480                             sshCommand remote: remote, command: """
 481                                 ./install_osm.sh -y \
 482                                     ${repo_base_url} \
 483                                     ${repo_key_name} \
 484                                     ${release} -r unstable \
 485                                     --charmed  \
 486                                     --registry ${USERNAME}:${PASSWORD}@${INTERNAL_DOCKER_REGISTRY} \
 487                                     --tag ${container_name}
 488                             """
 489                         }
 490                         prometheusHostname = "prometheus."+IP_ADDRESS+".nip.io"
 491                         prometheusPort = 80
 492                         osmHostname = "nbi."+IP_ADDRESS+".nip.io:443"
 493                     } else {
 494                         // Run -k8s installer here specifying internal docker registry and docker proxy
 495                         withCredentials([[$class: 'UsernamePasswordMultiBinding', credentialsId: 'gitlab-registry',
 496                                         usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD']]) {
 497                             sshCommand remote: remote, command: """
 498                                 ./install_osm.sh -y \
 499                                     ${repo_base_url} \
 500                                     ${repo_key_name} \
 501                                     ${release} -r unstable \
 502                                     -d ${USERNAME}:${PASSWORD}@${INTERNAL_DOCKER_REGISTRY} \
 503                                     -p ${INTERNAL_DOCKER_PROXY} \
 504                                     -t ${container_name}
 505                             """
 506                         }
 507                         prometheusHostname = IP_ADDRESS
 508                         prometheusPort = 9091
 509                         osmHostname = IP_ADDRESS
 510                     }
 511                 } // stage("Install")
 512 ///////////////////////////////////////////////////////////////////////////////////////
 513 // Health check of installed OSM in remote vm
 514 ///////////////////////////////////////////////////////////////////////////////////////
 515                 stage("OSM Health") {
 516                     stackName = "osm"
 517                     sshCommand remote: remote, command: """
 518                         /usr/share/osm-devops/installers/osm_health.sh -k -s ${stackName}
 519                     """
 520                 } // stage("OSM Health")
 521             } // if ( params.DO_INSTALL )
 522
 523
 524 ///////////////////////////////////////////////////////////////////////////////////////
 525 // Execute Robot tests
 526 ///////////////////////////////////////////////////////////////////////////////////////
 527             stage_archive = false
 528             if ( params.DO_ROBOT ) {
 529                 try {
 530                     stage("System Integration Test") {
 531                         if ( useCharmedInstaller ) {
 532                             tempdir = sh(returnStdout: true, script: "mktemp -d").trim()
 533                             sh(script: "touch ${tempdir}/hosts")
 534                             hostfile="${tempdir}/hosts"
 535                             sh """cat << EOF > ${hostfile}
 536 127.0.0.1           localhost
 537 ${remote.host}      prometheus.${remote.host}.nip.io nbi.${remote.host}.nip.io
 538 EOF"""
 539                         } else {
 540                             hostfile=null
 541                         }
 542
 543                         jujuPassword=sshCommand remote: remote, command: """
 544                             echo `juju gui 2>&1 | grep password | cut -d: -f2`
 545                         """
 546
 547                         run_robot_systest(
 548                             container_name,
 549                             params.ROBOT_TAG_NAME,
 550                             osmHostname,
 551                             prometheusHostname,
 552                             prometheusPort,
 553                             params.ROBOT_VIM,
 554                             params.ROBOT_PORT_MAPPING_VIM,
 555                             params.KUBECONFIG,
 556                             params.CLOUDS,
 557                             hostfile,
 558                             jujuPassword,
 559                             SSH_KEY,
 560                             params.ROBOT_PASS_THRESHOLD,
 561                             params.ROBOT_UNSTABLE_THRESHOLD
 562                         )
 563                     } // stage("System Integration Test")
 564                 } finally {
 565                     stage("Archive Container Logs") {
 566                         // Archive logs to containers_logs.txt
 567                         archive_logs(remote)
 568                         if ( ! currentBuild.result.equals('FAILURE') ) {
 569                             stage_archive = keep_artifacts
 570                         } else {
 571                             println ("Systest test failed, throwing error")
 572                             error = new Exception("Systest test failed")
 573                             currentBuild.result = 'FAILURE'
 574                             throw error
 575                         }
 576                     }
 577                 }
 578             } // if ( params.DO_ROBOT )
 579
 580             if ( params.SAVE_ARTIFACTS_OVERRIDE || stage_archive ) {
 581                 stage("Archive") {
 582                     sh "echo ${container_name} > build_version.txt"
 583                     archiveArtifacts artifacts: "build_version.txt", fingerprint: true
 584
 585                     // Archive the tested repo
 586                     dir("${RELEASE_DIR}") {
 587                         ci_helper.archive(params.ARTIFACTORY_SERVER,RELEASE,GERRIT_BRANCH,'tested')
 588                     }
 589                     if ( params.DO_DOCKERPUSH ) {
 590                         stage("Publish to Dockerhub") {
 591                             parallelSteps = [:]
 592                             for (buildStep in containerList) {
 593                                 def module = buildStep
 594                                 def moduleName = buildStep.toLowerCase()
 595                                 def dockerTag = params.DOCKER_TAG
 596                                 def moduleTag = container_name
 597
 598                                 parallelSteps[module] = {
 599                                     dir("$module") {
 600                                         sh "docker tag opensourcemano/${moduleName}:${moduleTag} opensourcemano/${moduleName}:${dockerTag}"
 601                                         sh "docker push opensourcemano/${moduleName}:${dockerTag}"
 602                                     }
 603                                 }
 604                             }
 605                             parallel parallelSteps
 606                         }
 607
 608                         stage("Snap promotion") {
 609                             def snaps = ["osmclient"]
 610                             sh "snapcraft login --with ~/.snapcraft/config"
 611                             for (snap in snaps) {
 612                                 channel="latest/"
 613                                 if (BRANCH_NAME.startsWith("v")) {
 614                                     channel=BRANCH_NAME.substring(1)+"/"
 615                                 } else if (BRANCH_NAME!="master") {
 616                                     channel+="/"+BRANCH_NAME.replaceAll('/','-')
 617                                 }
 618                                 track=channel+"edge\\*"
 619                                 edge_rev=sh(returnStdout: true,
 620                                     script: "snapcraft revisions $snap | " +
 621                                     "grep \"$track\" | tail -1 | awk '{print \$1}'").trim()
 622                                 print "edge rev is $edge_rev"
 623                                 track=channel+"beta\\*"
 624                                 beta_rev=sh(returnStdout: true,
 625                                     script: "snapcraft revisions $snap | " +
 626                                     "grep \"$track\" | tail -1 | awk '{print \$1}'").trim()
 627                                 print "beta rev is $beta_rev"
 628
 629                                 if ( edge_rev != beta_rev ) {
 630                                     print "Promoting $edge_rev to beta in place of $beta_rev"
 631                                     beta_track=channel+"beta"
 632                                     sh "snapcraft release $snap $edge_rev $beta_track"
 633                                 }
 634                             }
 635                         } // stage("Snap promotion")
 636                     } // if ( params.DO_DOCKERPUSH )
 637                 } // stage("Archive")
 638             } // if ( params.SAVE_ARTIFACTS_OVERRIDE || stage_archive )
 639         } // dir(OSM_DEVOPS)
 640     } finally {
 641         if ( params.DO_INSTALL && server_id != null) {
 642             delete_vm = true
 643             if (error && params.SAVE_CONTAINER_ON_FAIL ) {
 644                 delete_vm = false
 645             }
 646             if (!error && params.SAVE_CONTAINER_ON_PASS ) {
 647                 delete_vm = false
 648             }
 649
 650             if ( delete_vm ) {
 651                 if (server_id != null) {
 652                     println("Deleting VM: $server_id")
 653                     sh """#!/bin/sh -e
 654                         for line in `grep OS ~/hive/robot-systest.cfg | grep -v OS_CLOUD` ; do export \$line ; done
 655                         openstack server delete ${server_id}
 656                     """
 657                 } else {
 658                     println("Saved VM $server_id in ETSI VIM")
 659                 }
 660             }
 661         }
 662         if ( http_server_name != null ) {
 663             sh "docker stop ${http_server_name} || true"
 664             sh "docker rm ${http_server_name} || true"
 665         }
 666
 667         if ( devopstempdir != null ) {
 668             sh "rm -rf ${devopstempdir}"
 669         }
 670     }
 671 }