robot-systest/testsuite/epa_05-epa_underlay_passthrough.robot

#   Licensed under the Apache License, Version 2.0 (the "License");
#   you may not use this file except in compliance with the License.
#   You may obtain a copy of the License at
#
#       http://www.apache.org/licenses/LICENSE-2.0
#
#   Unless required by applicable law or agreed to in writing, software
#   distributed under the License is distributed on an "AS IS" BASIS,
#   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
#   See the License for the specific language governing permissions and
#   limitations under the License.

*** Settings ***
Documentation     [EPA-05] EPA underlay PASSTHROUGH.

Library   OperatingSystem
Library   String
Library   Collections
Library   SSHLibrary

Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnf_lib.robot
Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
Resource   %{ROBOT_DEVOPS_FOLDER}/lib/openstack_lib.robot

Variables   %{ROBOT_DEVOPS_FOLDER}/resources/epa_05-epa_underlay_passthrough.py

Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup

*** Variables ***
${vnf_member_index_1}   1
${vnf_member_index_2}   2
${username}   ubuntu
${password}   osm4u
${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} , {name: datanet, ip-profile: {ip-version: ipv4, subnet-address: "${datanet_subnet}"}, vnfd-connection-point-ref: [ {member-vnf-index-ref: "1", vnfd-connection-point-ref: vnf-data-ext, ip-address: "${datanet_ip1}"}, {member-vnf-index-ref: "2", vnfd-connection-point-ref: vnf-data-ext, ip-address: "${datanet_ip2}"}]} ] }
${success_return_code}   0


*** Test Cases ***
Create VNF Descriptor
    [Tags]   epa_underlay_passthrough   sanity   regression

    Remove Environment Variable  OVERRIDES
    Create VNFD  '%{PACKAGES_FOLDER}/${vnfd_pkg}'


Create NS Descriptor
    [Tags]   epa_underlay_passthrough   sanity   regression

    Create NSD  '%{PACKAGES_FOLDER}/${nsd_pkg}'


Instantiate Network Service
    [Tags]   epa_underlay_passthrough   sanity   regression

    ${id}=  Create Network Service  ${nsd_name}  %{VIM_TARGET}  ${ns_name}  ${ns_config}  ${publickey}
    Set Suite Variable  ${ns_id}  ${id}


Get Management Ip Addresses
    [Tags]   epa_underlay_passthrough   sanity   regression

    Variable Should Exist  ${ns_id}  msg=Network service instance is not available
    ${ip}  Get Vnf Management Ip Address  ${ns_id}  ${vnf_member_index_1}
    Set Suite Variable  ${ip_mgmt_1}  ${ip}
    log  ${ip_mgmt_1}

    ${ip}  Get Vnf Management Ip Address  ${ns_id}  ${vnf_member_index_2}
    Set Suite Variable  ${ip_mgmt_2}  ${ip}
    log  ${ip_mgmt_2}


Ping from Vnf1 to Vnf2
    [Tags]   epa_underlay_passthrough   sanity   regression

    Variable Should Exist  ${ip_mgmt_1}  msg=IP address of the data VNF '${vnf_member_index_1}' is not available
    Variable Should Exist  ${privatekey}  msg=SSH private key not available
    Sleep   30 seconds   Wait for SSH daemon to be up
    ${stdout}=   Execute Remote Command Check Rc Return Output   ${ip_mgmt_1}   ${username}   ${password}   ${privatekey}   ip addr ; ping -c 5 ${datanet_ip2}
    log  ${stdout}


Ping from Vnf2 to Vnf1
    [Tags]   epa_underlay_passthrough   sanity   regression

    Variable Should Exist  ${ip_mgmt_2}  msg=IP address of the data VNF '${vnf_member_index_2}' is not available
    Variable Should Exist  ${privatekey}  msg=SSH private key not available
    ${stdout}=   Execute Remote Command Check Rc Return Output   ${ip_mgmt_2}   ${username}   ${password}   ${privatekey}   ip addr ; ping -c 5 ${datanet_ip1}
    log  ${stdout}


Delete NS Instance
    [Tags]   epa_underlay_passthrough   sanity   regression  cleanup

    Delete NS  ${ns_name}


Delete NS Descriptor
    [Tags]   epa_underlay_passthrough   sanity   regression  cleanup

    Delete NSD  ${nsd_name}


Delete VNF Descriptor
    [Tags]   epa_underlay_passthrough   sanity   regression  cleanup

    Delete VNFD  ${vnfd_name}



*** Keywords ***
Suite Cleanup
    [Documentation]  Test Suite Cleanup: Deleting descriptors and NS instance

    Run Keyword If Any Tests Failed  Delete NS  ${ns_name}

    Run Keyword If Any Tests Failed  Delete NSD  ${nsd_name}

    Run Keyword If Any Tests Failed  Delete VNFD  ${vnfd_name}