robot-systest/testsuite/heal_01-volume_vdu_healing.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation   [HEAL-01] Healing of a multi-volume VDU
  15
  16 Library   OperatingSystem
  17 Library   String
  18 Library   Collections
  19 Library   Process
  20 Library   SSHLibrary
  21
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  23 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnf_lib.robot
  24 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  25 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  26 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  27 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/openstack_lib.robot
  28
  29 Force Tags   heal_01   cluster_main   daily   regression
  30
  31
  32 Suite Teardown   Run Keyword And Ignore Error   Suite Cleanup
  33
  34
  35 *** Variables ***
  36 # NS and VNF descriptor package folder and ids
  37 ${vnfd_volumes_pkg}   several_volumes_vnf
  38 ${vnfd_volumes_name}   several_volumes-vnf
  39 ${vdu_volumes_name}   several_volumes-VM
  40 ${vnf_several_index}   several_volumes_vnf
  41 ${vnfd_charm_pkg}   charm-packages/native_manual_scale_charm_vnf
  42 ${vnfd_charm_name}   native_manual_scale_charm-vnf
  43 ${nsd_pkg}   volumes_nativecharm_ns
  44 ${nsd_name}   volumes_nativecharm-ns
  45
  46 # NS instance name and configuration
  47 ${ns_name}   heal_01
  48 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  49
  50 # SSH keys and username to be used
  51 ${publickey}   %{HOME}/.ssh/id_rsa.pub
  52 ${privatekey}   %{HOME}/.ssh/id_rsa
  53 ${username}   ubuntu
  54 ${password}   ${EMPTY}
  55
  56 ${success_return_code}   0
  57
  58
  59 *** Test Cases ***
  60 Create VNF Descriptors
  61     [Tags]   prepare
  62     Create VNFD   '%{PACKAGES_FOLDER}/${vnfd_charm_pkg}'
  63     Create VNFD   '%{PACKAGES_FOLDER}/${vnfd_volumes_pkg}'
  64
  65
  66 Create NS Descriptor
  67     [Tags]   prepare
  68     Create NSD   '%{PACKAGES_FOLDER}/${nsd_pkg}'
  69
  70
  71 Network Service Instance Test
  72     [Tags]   prepare
  73     ${id}=   Create Network Service   ${nsd_name}   %{VIM_TARGET}   ${ns_name}   ${ns_config}   ${publickey}
  74     Set Suite Variable   ${ns_id}   ${id}
  75
  76
  77 Get NS Id
  78     [Tags]   verify   cleanup
  79     ${variables}   Get Variables
  80     IF   not "\${ns_id}" in "${variables}"
  81         ${id}=   Get Ns Id   ${ns_name}
  82         Set Suite Variable   ${ns_id}   ${id}
  83     END
  84
  85
  86 Get Volume VNF Info
  87     [Tags]   verify
  88     Variable Should Exist   ${ns_id}   msg=NS is not available
  89     ${ip_addr}=   Get Vnf Management Ip Address   ${ns_id}   ${vnf_several_index}
  90     log   ${ip_addr}
  91     Set Suite Variable   ${vnf_volumes_ip_addr}   ${ip_addr}
  92
  93     ${vnf_id}=   Get Vnf Id   ${ns_id}   ${vnf_several_index}
  94     Set Suite Variable   ${vnf_volumes_id}   ${vnf_id}
  95     ${id}=   Get VNF VIM ID   ${vnf_id}
  96     Set Suite Variable   ${vdu_volumes_id}   ${id}
  97     log   ${vdu_volumes_id}
  98
  99     @{volumes_ip_list}=   Get Vnf Vdur IPs   ${vnf_volumes_id}
 100     Set Suite Variable   @{volumes_ip_list}   @{volumes_ip_list}
 101     log   @{volumes_ip_list}
 102
 103
 104 Get Volumes Info
 105     [Tags]   verify
 106     ${rc}   ${stdout}=   Run and Return RC and Output   osm vnfpkg-show ${vnfd_volumes_name} --literal | yq '.vdu[0]."virtual-storage-desc" | length'
 107     Should Be Equal As Integers   ${rc}   ${success_return_code}   msg=${stdout}   values=False
 108     ${num_virtual_storage}=   Convert To Integer   ${stdout}
 109     Set Suite Variable   ${vnf_num_volumes}   ${num_virtual_storage}
 110     log   ${vnf_num_volumes}
 111     ${volumes_attached}=   Get Server Property   ${vdu_volumes_id}   volumes_attached
 112     ${match}=   Get Regexp Matches   ${volumes_attached}   '([0-9a-f\-]+)'   1
 113     Set Suite Variable   ${volume_id}   ${match}[0]
 114
 115
 116 Check VDU Disks
 117     [Tags]   verify
 118     Variable Should Exist   ${vnf_volumes_ip_addr}   msg=VNF is not available
 119     Sleep   30 seconds   Wait for SSH daemon to be up
 120     ${stdout}=   Execute Remote Command Check Rc Return Output   ${vnf_volumes_ip_addr}   ${username}   ${password}   ${privatekey}   sudo lsblk -l
 121     log   ${stdout}
 122     ${lines}=   Get Lines Containing String   ${stdout}   disk
 123     ${num_lines}=   Get Line Count   ${lines}
 124     Run Keyword If   ${num_lines} < ${vnf_num_volumes}   Fail   msg=Number of disks (${num_lines}) is less than specified in VDU (${vnf_num_volumes})
 125
 126
 127 Delete Persistent Volume VDU
 128     [Tags]   verify
 129     Variable Should Exist   ${vdu_volumes_id}   msg=VDU is not available
 130     Delete Server   ${vdu_volumes_id}
 131     Sleep   20
 132
 133
 134 Heal Persistent Volume VDU
 135     [Tags]   verify
 136     Variable Should Exist   ${vnf_volumes_id}   msg=VNF is not available
 137     Heal Network Service   ${ns_id}   --vnf ${vnf_volumes_id} --cause "Heal VM of volumes_vnf" --vdu ${vdu_volumes_name}
 138
 139
 140 Check VNF After Healing
 141     [Tags]   verify
 142     Variable Should Exist   ${vnf_volumes_id}   msg=VNF is not available
 143
 144     @{ip_list}=   Get Vnf Vdur IPs   ${vnf_volumes_id}
 145     log   @{ip_list}
 146     Should Be Equal   ${ip_list}   ${volumes_ip_list}   IP addresses have changed after healing
 147
 148     ${id}=   Get VNF VIM ID   ${vnf_volumes_id}
 149     log   ${id}
 150     Should Not Be Equal   ${id}   ${vdu_volumes_id}   VDU id has not changed after healing
 151
 152     ${volumes_attached}=   Get Server Property   ${id}   volumes_attached
 153     ${match}=   Get Regexp Matches   ${volumes_attached}   '([0-9a-f\-]+)'   1
 154     Should Be Equal   ${match}[0]   ${volume_id}   Volume id has changed after healing
 155
 156     Sleep   30 seconds   Wait for SSH daemon to be up
 157     ${stdout}=   Execute Remote Command Check Rc Return Output   ${vnf_volumes_ip_addr}   ${username}   ${password}   ${privatekey}   sudo lsblk -l
 158     log   ${stdout}
 159     ${lines}=   Get Lines Containing String   ${stdout}   disk
 160     ${num_lines}=   Get Line Count   ${lines}
 161     Run Keyword If   ${num_lines} < ${vnf_num_volumes}   Fail   msg=Number of disks (${num_lines}) is less than specified in VDU (${vnf_num_volumes})
 162
 163
 164 Delete NS Instance
 165     [Tags]   cleanup
 166     Delete NS   ${ns_name}
 167
 168
 169 Delete NS Descriptor
 170     [Tags]   cleanup
 171     Delete NSD   ${nsd_name}
 172
 173
 174 Delete VNF Descriptors
 175     [Tags]   cleanup
 176     Delete VNFD   ${vnfd_volumes_name}
 177     Delete VNFD   ${vnfd_charm_name}
 178
 179
 180 *** Keywords ***
 181 Suite Cleanup
 182     [Documentation]   Test Suit Cleanup: Deleting Descriptor, instance and vim
 183
 184     Run Keyword If Any Tests Failed   Delete NS   ${ns_name}
 185     Run Keyword If Any Tests Failed   Delete NSD   ${nsd_name}
 186     Run Keyword If Any Tests Failed   Delete VNFD   ${vnfd_volumes_name}
 187     Run Keyword If Any Tests Failed   Delete VNFD   ${vnfd_charm_name}