robot-systest/testsuite/basic_06-vnf_with_charm.robot

   1 #   Licensed under the Apache License, Version 2.0 (the "License");
   2 #   you may not use this file except in compliance with the License.
   3 #   You may obtain a copy of the License at
   4 #
   5 #       http://www.apache.org/licenses/LICENSE-2.0
   6 #
   7 #   Unless required by applicable law or agreed to in writing, software
   8 #   distributed under the License is distributed on an "AS IS" BASIS,
   9 #   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  10 #   See the License for the specific language governing permissions and
  11 #   limitations under the License.
  12
  13 *** Settings ***
  14 Documentation     [BASIC-06] VNF with Charm.
  15
  16 Library   OperatingSystem
  17 Library   SSHLibrary
  18
  19 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/vnfd_lib.robot
  20 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/nsd_lib.robot
  21 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ns_lib.robot
  22 Resource   %{ROBOT_DEVOPS_FOLDER}/lib/ssh_lib.robot
  23
  24 Variables   %{ROBOT_DEVOPS_FOLDER}/resources/basic_06-vnf_with_charm_data.py
  25
  26 Suite Teardown   Run Keyword And Ignore Error   Test Cleanup
  27
  28
  29 *** Variables ***
  30 ${username}   ubuntu
  31 ${password}   ${EMPTY}
  32 ${ns_config}   {vld: [ {name: mgmtnet, vim-network-name: %{VIM_MGMT_NET}} ] }
  33 ${action_name}   touch
  34 ${vnf_member_index_1}   1
  35 ${vnf_member_index_2}   2
  36 ${day_1_file_name}   /home/ubuntu/first-touch
  37 ${day_2_file_name_1}   /home/ubuntu/mytouch1
  38 ${day_2_file_name_2}   /home/ubuntu/mytouch2
  39 ${ns_timeout}   15min
  40
  41
  42 *** Test Cases ***
  43 Create Charm VNF Descriptor
  44     [Tags]   charm   sanity   regression
  45
  46     Create VNFD  '%{PACKAGES_FOLDER}/${vnfd_pkg}'
  47
  48
  49 Create Charm NS Descriptor
  50     [Tags]   charm   sanity   regression
  51
  52     Create NSD  '%{PACKAGES_FOLDER}/${nsd_pkg}'
  53
  54
  55 Instantiate Charm Network Service
  56     [Tags]   charm   sanity   regression
  57
  58     ${id}=  Create Network Service  ${nsd_name}  %{VIM_TARGET}  ${ns_name}  ${ns_config}  ${publickey}  ${ns_timeout}
  59     Set Suite Variable  ${ns_id}  ${id}
  60
  61
  62 Get Management Ip Addresses
  63     [Tags]   charm   sanity   regression
  64
  65     ${ip_addr_1}  Get Vnf Management Ip Address  ${ns_id}  ${vnf_member_index_1}
  66     log  ${ip_addr_1}
  67     Set Suite Variable  ${vnf_1_ip_addr}  ${ip_addr_1}
  68     ${ip_addr_2}  Get Vnf Management Ip Address  ${ns_id}  ${vnf_member_index_2}
  69     log  ${ip_addr_2}
  70     Set Suite Variable  ${vnf_2_ip_addr}  ${ip_addr_2}
  71
  72
  73 Test SSH Access
  74     [Tags]   charm   sanity   regression
  75
  76     Variable Should Exist  ${vnf_1_ip_addr}  msg=IP address of the management VNF '${vnf_member_index_1}' is not available
  77     Variable Should Exist  ${vnf_2_ip_addr}  msg=IP address of the management VNF '${vnf_member_index_2}' is not available
  78     Sleep  30s  Waiting ssh daemon to be up
  79     Test SSH Connection  ${vnf_1_ip_addr}  ${username}  ${password}  ${privatekey}
  80     Test SSH Connection  ${vnf_2_ip_addr}  ${username}  ${password}  ${privatekey}
  81
  82
  83 Check Remote Files Created Via Day 1 Operations
  84     [Documentation]     The Charm VNF has a Day 1 operation that creates a file named ${day_1_file_name}.
  85     ...                 This test checks whether that files have been created or not.
  86     [Tags]   charm   sanity   regression
  87
  88     Check If remote File Exists  ${vnf_1_ip_addr}  ${username}  ${password}  ${privatekey}  ${day_1_file_name}
  89     Check If remote File Exists  ${vnf_2_ip_addr}  ${username}  ${password}  ${privatekey}  ${day_1_file_name}
  90
  91
  92 Execute Day 2 Operations
  93     [Documentation]     Performs one Day 2 operation per VNF that creates a new file.
  94     [Tags]   charm   sanity   regression
  95
  96     Variable Should Exist  ${ns_id}  msg=Network service instance is not available
  97     ${ns_op_id_1}=  Execute NS Action  ${ns_name}  ${action_name}  ${vnf_member_index_1}  filename=${day_2_file_name_1}
  98     ${ns_op_id_2}=  Execute NS Action  ${ns_name}  ${action_name}  ${vnf_member_index_2}  filename=${day_2_file_name_2}
  99
 100
 101 Check Remote Files Created Via Day 2 Operations
 102     [Documentation]     Check whether the files created in the previous test via Day 2 operations exist or not.
 103     [Tags]   charm   sanity   regression
 104
 105     Check If remote File Exists  ${vnf_1_ip_addr}  ${username}  ${password}  ${privatekey}  ${day_2_file_name_1}
 106     Check If remote File Exists  ${vnf_2_ip_addr}  ${username}  ${password}  ${privatekey}  ${day_2_file_name_2}
 107
 108
 109 Delete NS Instance
 110     [Tags]   charm   sanity   regression  cleanup
 111
 112     Delete NS  ${ns_name}
 113
 114
 115 Delete NS Descriptor
 116     [Tags]   charm   sanity   regression  cleanup
 117
 118     Delete NSD  ${nsd_name}
 119
 120
 121 Delete VNF Descriptor
 122     [Tags]   charm   sanity   regression  cleanup
 123
 124     Delete VNFD  ${vnfd_name}
 125
 126
 127 *** Keywords ***
 128 Test Cleanup
 129     [Documentation]  Test Suite Cleanup: Deleting descriptors and NS instance
 130
 131     Run Keyword If Test Failed  Delete NS  ${ns_name}
 132
 133     Run Keyword If Test Failed  Delete NSD  ${nsd_name}
 134
 135     Run Keyword If Test Failed  Delete VNFD  ${vnfd_name}
 136