robot-systest/testsuite/cli/TS01__Test_VNF.robot

   1 # -*- coding: utf-8 -*-
   2
   3 ##
   4 # Copyright 2019 Tech Mahindra Limited
   5 #
   6 # All Rights Reserved.
   7 #
   8 # Licensed under the Apache License, Version 2.0 (the "License"); you may
   9 # not use this file except in compliance with the License. You may obtain
  10 # a copy of the License at
  11 #
  12 #         http://www.apache.org/licenses/LICENSE-2.0
  13 #
  14 # Unless required by applicable law or agreed to in writing, software
  15 # distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  16 # WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  17 # License for the specific language governing permissions and limitations
  18 # under the License.
  19 ##
  20
  21 ## Change log:
  22 # 1. Feature 7829: Mrityunjay Yadav, Jayant Madavi : MY00514913@techmahindra.com : 06-aug-2019
  23 ##
  24
  25
  26 *** Settings ***
  27 Documentation    Test Suite to test basic cirros VNF and NS using osm-client
  28 Library     OperatingSystem
  29 Library     String
  30 Library     Collections
  31 Resource    ../../lib/cli/vnfd_lib.robot
  32 Resource    ../../lib/cli/nsd_lib.robot
  33 Resource    ../../lib/cli/ns_lib.robot
  34 Resource    ../../lib/cli/vim_account_lib.robot
  35 Library     ../../lib/custom_lib.py
  36 Variables   ../../resource/cli/test_vnf_data.py
  37
  38 Suite Teardown     Run Keyword And Ignore Error    Test Cleanup
  39
  40
  41 *** Variables ***
  42 @{vnfd_ids}
  43 @{nsd_ids}
  44 @{ns_ids}
  45
  46
  47 *** Test Cases ***
  48 Create VNF Descriptor Test
  49     [Tags]    sanity    smoke
  50
  51     Build VNF Descriptor    ${vnfdPckgPath}
  52     ${vnfd_id}=    Create VNFD    '${CURDIR}${/}../../..${vnfdPckgPath}${vnfdPckg}'
  53     Append To List     ${vnfd_ids}       ${vnfd_id}
  54
  55
  56 Create NS Descriptor Test
  57     [Tags]    sanity     smoke
  58
  59     Build NS Descriptor    ${nsdPckgPath}
  60     ${nsd_id}=    Create NSD    '${CURDIR}${/}../../..${nsdPckgPath}${nsdPckg}'
  61     Append To List     ${nsd_ids}       ${nsd_id}
  62
  63
  64 Network Service Instance Test
  65     [Documentation]  Launch and terminate network services
  66     [Tags]    sanity
  67     [Teardown]  Run Keyword And Ignore Error    Network Service Instance Cleanup
  68
  69     :FOR    ${vim_name}    IN    @{vim}
  70     \    Launch Network Services and Return    ${vim_name}
  71
  72
  73 Delete NS Descriptor Test
  74     [Tags]    sanity     smoke
  75
  76     :FOR    ${nsd}  IN   @{nsd_ids}
  77     \   Delete NSD      ${nsd}
  78
  79
  80 Delete VNF Descriptor Test
  81     [Tags]    sanity    smoke
  82
  83     :FOR    ${vnfd}  IN   @{vnfd_ids}
  84     \   Delete VNFD     ${vnfd}
  85
  86
  87 *** Keywords ***
  88 Test Cleanup
  89     [Documentation]  Test Suit Cleanup: Forcefully delete NSD and VNFD
  90
  91     :FOR    ${nsd}  IN   @{nsd_ids}
  92     \   Force Delete NSD      ${nsd}
  93
  94     :FOR    ${vnfd}  IN   @{vnfd_ids}
  95     \   Force Delete VNFD     ${vnfd}
  96
  97
  98 Network Service Instance Cleanup
  99     [Documentation]  Forcefully delete created network service instances and vim account
 100
 101     :FOR    ${ns}  IN   @{ns_ids}
 102     \   Force Delete NS   ${ns}