jenkins/ci-pipelines/ci_stage_3.groovy

   1 /* Copyright 2017 Sandvine
   2  *
   3  * All Rights Reserved.
   4  *
   5  *   Licensed under the Apache License, Version 2.0 (the "License"); you may
   6  *   not use this file except in compliance with the License. You may obtain
   7  *   a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *   Unless required by applicable law or agreed to in writing, software
  12  *   distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  13  *   WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  14  *   License for the specific language governing permissions and limitations
  15  *   under the License.
  16  */
  17
  18 properties([
  19     parameters([
  20         string(defaultValue: env.GERRIT_BRANCH, description: '', name: 'GERRIT_BRANCH'),
  21         string(defaultValue: 'system', description: '', name: 'NODE'),
  22         string(defaultValue: '', description: '', name: 'BUILD_FROM_SOURCE'),
  23         string(defaultValue: 'unstable', description: '', name: 'REPO_DISTRO'),
  24         string(defaultValue: '', description: '', name: 'COMMIT_ID'),
  25         string(defaultValue: '-stage_2', description: '', name: 'UPSTREAM_SUFFIX'),
  26         string(defaultValue: 'pubkey.asc', description: '', name: 'REPO_KEY_NAME'),
  27         string(defaultValue: 'release', description: '', name: 'RELEASE'),
  28         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NAME'),
  29         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  30         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  31         string(defaultValue: 'dpkg1', description: '', name: 'GPG_KEY_NAME'),
  32         string(defaultValue: 'artifactory-osm', description: '', name: 'ARTIFACTORY_SERVER'),
  33         string(defaultValue: 'osm-stage_4', description: '', name: 'DOWNSTREAM_STAGE_NAME'),
  34         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_FAIL'),
  35         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_PASS'),
  36         booleanParam(defaultValue: false, description: '', name: 'DO_STAGE_4'),
  37         booleanParam(defaultValue: false, description: '', name: 'DO_INSTALL'),
  38         booleanParam(defaultValue: false, description: '', name: 'DO_SMOKE'),
  39         booleanParam(defaultValue: false, description: '', name: 'SAVE_ARTIFACTS_OVERRIDE'),
  40     ])
  41 ])
  42
  43 def uninstall_osm( stackName ) {
  44     sh """
  45          export OSM_USE_LOCAL_DEVOPS=true
  46          export PATH=$PATH:/snap/bin
  47          installers/full_install_osm.sh -y -s ${stackName} --test --nolxd --nodocker --nojuju --nohostports --nohostclient --uninstall
  48        """
  49 }
  50
  51 node("${params.NODE}") {
  52
  53     sh 'env'
  54
  55     tag_or_branch = params.GERRIT_BRANCH.replaceAll(/\./,"")
  56
  57     stage("Checkout") {
  58         checkout scm
  59     }
  60
  61     ci_helper = load "jenkins/ci-pipelines/ci_helper.groovy"
  62
  63     def upstream_main_job = params.UPSTREAM_SUFFIX
  64
  65     // upstream jobs always use merged artifacts
  66     upstream_main_job += '-merge'
  67     container_name_prefix = "osm-${tag_or_branch}"
  68     container_name = "${container_name_prefix}"
  69     if ( JOB_NAME.contains('merge') ) {
  70         container_name += "-merge"
  71     }
  72     container_name += "-${BUILD_NUMBER}"
  73
  74     // Copy the artifacts from the upstream jobs
  75     stage("Copy Artifacts") {
  76         // cleanup any previous repo
  77         sh 'rm -rf repo'
  78         dir("repo") {
  79             // grab all stable upstream builds based on the
  80
  81             dir("${RELEASE}") {
  82                 def list = ["RO", "openvim", "osmclient", "IM", "devops", "MON", "N2VC", "NBI", "common", "LCM"]
  83                 for (component in list) {
  84                     step ([$class: 'CopyArtifact',
  85                            projectName: "${component}${upstream_main_job}/${GERRIT_BRANCH}"])
  86
  87                     // grab the build name/number
  88                     //options = get_env_from_build('build.env')
  89                     build_num = ci_helper.get_env_value('build.env','BUILD_NUMBER')
  90
  91                     // grab the archives from the stage_2 builds (ie. this will be the artifacts stored based on a merge)
  92                     ci_helper.get_archive(params.ARTIFACTORY_SERVER,component,GERRIT_BRANCH, "${component}${upstream_main_job} :: ${GERRIT_BRANCH}", build_num)
  93
  94                     // cleanup any prevously defined dists
  95                     sh "rm -rf dists"
  96                 }
  97
  98                 // check if an upstream artifact based on specific build number has been requested
  99                 // This is the case of a merge build and the upstream merge build is not yet complete (it is not deemed
 100                 // a successful build yet). The upstream job is calling this downstream job (with the its build artifiact)
 101                 if ( params.UPSTREAM_JOB_NAME ) {
 102                     step ([$class: 'CopyArtifact',
 103                            projectName: "${params.UPSTREAM_JOB_NAME}",
 104                            selector: [$class: 'SpecificBuildSelector', buildNumber: "${params.UPSTREAM_JOB_NUMBER}"]
 105                           ])
 106
 107                     //options = get_env_from_build('build.env')
 108                     // grab the build name/number
 109                     //build_num = sh(returnStdout:true,  script: "cat build.env | awk -F= '/BUILD_NUMBER/{print \$2}'").trim()
 110                     build_num = ci_helper.get_env_value('build.env','BUILD_NUMBER')
 111                     component = ci_helper.get_mdg_from_project(ci_helper.get_env_value('build.env','GERRIT_PROJECT'))
 112
 113                     // the upstream job name contains suffix with the project. Need this stripped off
 114                     def project_without_branch = params.UPSTREAM_JOB_NAME.split('/')[0]
 115
 116                     ci_helper.get_archive(params.ARTIFACTORY_SERVER,component,GERRIT_BRANCH, "${project_without_branch} :: ${GERRIT_BRANCH}", build_num)
 117
 118                     sh "rm -rf dists"
 119                 }
 120
 121                 // sign all the components
 122                 for (component in list) {
 123                     sh "dpkg-sig --sign builder -k ${GPG_KEY_NAME} pool/${component}/*"
 124                 }
 125
 126                 // now create the distro
 127                 for (component in list) {
 128                     sh "mkdir -p dists/${params.REPO_DISTRO}/${component}/binary-amd64/"
 129                     sh "apt-ftparchive packages pool/${component} > dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 130                     sh "gzip -9fk dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 131                 }
 132
 133                 // create and sign the release file
 134                 sh "apt-ftparchive release dists/${params.REPO_DISTRO} > dists/${params.REPO_DISTRO}/Release"
 135                 sh "gpg --yes -abs -u ${GPG_KEY_NAME} -o dists/${params.REPO_DISTRO}/Release.gpg dists/${params.REPO_DISTRO}/Release"
 136
 137                 // copy the public key into the release folder
 138                 // this pulls the key from the home dir of the current user (jenkins)
 139                 sh "cp ~/${REPO_KEY_NAME} ."
 140
 141                 // merge the change logs
 142                 sh """
 143                    rm -f changelog/changelog-osm.html
 144                    [ ! -d changelog ] || for mdgchange in \$(ls changelog); do cat changelog/\$mdgchange >> changelog/changelog-osm.html; done
 145                    """
 146             }
 147             // start an apache server to serve up the images
 148             http_server_name = "${container_name}-apache"
 149
 150             pwd = sh(returnStdout:true,  script: 'pwd').trim()
 151             repo_base_url = ci_helper.start_http_server(pwd,http_server_name)
 152         }
 153     }
 154
 155     error = null
 156
 157     try {
 158         if ( params.DO_INSTALL ) {
 159             stage("Install") {
 160
 161                 //will by default always delete containers on complete
 162                 //sh "jenkins/system/delete_old_containers.sh ${container_name_prefix}"
 163
 164                 commit_id = ''
 165                 repo_distro = ''
 166                 repo_key_name = ''
 167                 release = ''
 168
 169                 if ( params.COMMIT_ID )
 170                 {
 171                     commit_id = "-b ${params.COMMIT_ID}"
 172                 }
 173
 174                 if ( params.REPO_DISTRO )
 175                 {
 176                     repo_distro = "-r ${params.REPO_DISTRO}"
 177                 }
 178
 179                 if ( params.REPO_KEY_NAME )
 180                 {
 181                     repo_key_name = "-k ${params.REPO_KEY_NAME}"
 182                 }
 183
 184                 if ( params.RELEASE )
 185                 {
 186                     release = "-R ${params.RELEASE}"
 187                 }
 188
 189                 sh """
 190                     export PATH=$PATH:/snap/bin
 191                     installers/full_install_osm.sh -y -s ${container_name} --test --nolxd --nodocker --nojuju --nohostports --nohostclient \
 192                                                     ${commit_id} \
 193                                                     ${repo_distro} \
 194                                                     ${repo_base_url} \
 195                                                     ${repo_key_name} \
 196                                                     ${release} \
 197                                                     ${params.BUILD_FROM_SOURCE}
 198                    """
 199             }
 200         }
 201
 202         if ( params.DO_SMOKE ) {
 203             stage("Smoke") {
 204                 ci_helper.systest_run(container_name, 'smoke')
 205                 junit '*.xml'
 206             }
 207         }
 208
 209         stage_4_archive = false
 210         if ( params.DO_STAGE_4 ) {
 211             stage("stage_4") {
 212                 def downstream_params = [
 213                     string(name: 'CONTAINER_NAME', value: container_name),
 214                     string(name: 'NODE', value: NODE_NAME.split()[0]),
 215                 ]
 216                 stage_4_result = build job: "${params.DOWNSTREAM_STAGE_NAME}/${GERRIT_BRANCH}", parameters: downstream_params, propagate: false
 217                 currentBuild.result = stage_4_result.result
 218
 219                 if ( stage_4_result.getResult().equals('SUCCESS') ) {
 220                     stage_4_archive = true;
 221                 }
 222             }
 223         }
 224
 225         // override to save the artifacts
 226         if ( params.SAVE_ARTIFACTS_OVERRIDE || stage_4_archive ) {
 227             stage("Archive") {
 228                 sh "echo ${container_name} > build_version.txt"
 229                 archiveArtifacts artifacts: "build_version.txt", fingerprint: true
 230
 231                 // Archive the tested repo
 232                 dir("repo/${RELEASE}") {
 233                     ci_helper.archive(params.ARTIFACTORY_SERVER,RELEASE,GERRIT_BRANCH,'tested')
 234                 }
 235             }
 236         }
 237     }
 238     catch(caughtError) {
 239         println("Caught error!")
 240         error = caughtError
 241         currentBuild.result = 'FAILURE'
 242     }
 243     finally {
 244         sh "docker stop ${http_server_name}"
 245         sh "docker rm ${http_server_name}"
 246
 247         if ( params.DO_INSTALL ) {
 248             if (error) {
 249                 if ( !params.SAVE_CONTAINER_ON_FAIL ) {
 250                     uninstall_osm ${container_name}
 251                 }
 252                 throw error
 253             }
 254             else {
 255                 if ( !params.SAVE_CONTAINER_ON_PASS ) {
 256                     uninstall_osm ${container_name}
 257                 }
 258             }
 259         }
 260     }
 261 }