jenkins/ci-pipelines/ci_stage_3.groovy

   1 /* Copyright 2017 Sandvine
   2  *
   3  * All Rights Reserved.
   4  *
   5  *   Licensed under the Apache License, Version 2.0 (the "License"); you may
   6  *   not use this file except in compliance with the License. You may obtain
   7  *   a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *   Unless required by applicable law or agreed to in writing, software
  12  *   distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  13  *   WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  14  *   License for the specific language governing permissions and limitations
  15  *   under the License.
  16  */
  17
  18 properties([
  19     parameters([
  20         string(defaultValue: env.GERRIT_BRANCH, description: '', name: 'GERRIT_BRANCH'),
  21         string(defaultValue: 'system', description: '', name: 'NODE'),
  22         string(defaultValue: '', description: '', name: 'BUILD_FROM_SOURCE'),
  23         string(defaultValue: 'unstable', description: '', name: 'REPO_DISTRO'),
  24         string(defaultValue: '', description: '', name: 'COMMIT_ID'),
  25         string(defaultValue: '-stage_2', description: '', name: 'UPSTREAM_SUFFIX'),
  26         string(defaultValue: 'pubkey.asc', description: '', name: 'REPO_KEY_NAME'),
  27         string(defaultValue: 'release', description: '', name: 'RELEASE'),
  28         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NAME'),
  29         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  30         string(defaultValue: '', description: '', name: 'UPSTREAM_JOB_NUMBER'),
  31         string(defaultValue: 'dpkg1', description: '', name: 'GPG_KEY_NAME'),
  32         string(defaultValue: 'artifactory-osm', description: '', name: 'ARTIFACTORY_SERVER'),
  33         string(defaultValue: 'osm-stage_4', description: '', name: 'DOWNSTREAM_STAGE_NAME'),
  34         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_FAIL'),
  35         booleanParam(defaultValue: false, description: '', name: 'SAVE_CONTAINER_ON_PASS'),
  36         booleanParam(defaultValue: true, description: '', name: 'SAVE_ARTIFACTS_ON_SMOKE_SUCCESS'),
  37         booleanParam(defaultValue: false, description: '', name: 'DO_STAGE_4'),
  38         booleanParam(defaultValue: true, description: '',  name: 'DO_BUILD'),
  39         booleanParam(defaultValue: true, description: '', name: 'DO_INSTALL'),
  40         booleanParam(defaultValue: true, description: '', name: 'DO_SMOKE'),
  41         booleanParam(defaultValue: false, description: '', name: 'SAVE_ARTIFACTS_OVERRIDE'),
  42     ])
  43 ])
  44
  45 def uninstall_osm(stackName) {
  46     sh """
  47          export OSM_USE_LOCAL_DEVOPS=true
  48          export PATH=$PATH:/snap/bin
  49          installers/full_install_osm.sh -y -w /tmp/osm -t ${stackName} -s ${stackName} --test --nolxd --nodocker --nojuju --nohostports --nohostclient --uninstall
  50        """
  51 }
  52
  53 def run_systest(stackName,tagName,testName) {
  54     tempdir = sh(returnStdout: true, script: "mktemp -d").trim()
  55     sh "docker run --network net${stackName} -v ${tempdir}:/usr/share/osm-devops/systest/reports osm/osmclient:${tagName} make -C /usr/share/osm-devops/systest ${testName}"
  56     sh "cp ${tempdir}/* ."
  57     junit  '*.xml'
  58 }
  59
  60 node("${params.NODE}") {
  61
  62     sh 'env'
  63
  64     tag_or_branch = params.GERRIT_BRANCH.replaceAll(/\./,"")
  65
  66     stage("Checkout") {
  67         checkout scm
  68     }
  69
  70     ci_helper = load "jenkins/ci-pipelines/ci_helper.groovy"
  71
  72     def upstream_main_job = params.UPSTREAM_SUFFIX
  73
  74     // upstream jobs always use merged artifacts
  75     upstream_main_job += '-merge'
  76     container_name_prefix = "osm-${tag_or_branch}"
  77     container_name = "${container_name_prefix}"
  78     if ( JOB_NAME.contains('merge') ) {
  79         container_name += "-merge"
  80     }
  81     container_name += "-${BUILD_NUMBER}"
  82
  83     // Copy the artifacts from the upstream jobs
  84     stage("Copy Artifacts") {
  85         // cleanup any previous repo
  86         sh 'rm -rf repo'
  87         dir("repo") {
  88             // grab all stable upstream builds based on the
  89
  90             dir("${RELEASE}") {
  91                 def list = ["RO", "openvim", "osmclient", "IM", "devops", "MON", "N2VC", "NBI", "common", "LCM", "POL"]
  92                 for (component in list) {
  93                     step ([$class: 'CopyArtifact',
  94                            projectName: "${component}${upstream_main_job}/${GERRIT_BRANCH}"])
  95
  96                     // grab the build name/number
  97                     //options = get_env_from_build('build.env')
  98                     build_num = ci_helper.get_env_value('build.env','BUILD_NUMBER')
  99
 100                     // grab the archives from the stage_2 builds (ie. this will be the artifacts stored based on a merge)
 101                     ci_helper.get_archive(params.ARTIFACTORY_SERVER,component,GERRIT_BRANCH, "${component}${upstream_main_job} :: ${GERRIT_BRANCH}", build_num)
 102
 103                     // cleanup any prevously defined dists
 104                     sh "rm -rf dists"
 105                 }
 106
 107                 // check if an upstream artifact based on specific build number has been requested
 108                 // This is the case of a merge build and the upstream merge build is not yet complete (it is not deemed
 109                 // a successful build yet). The upstream job is calling this downstream job (with the its build artifiact)
 110                 if ( params.UPSTREAM_JOB_NAME ) {
 111                     step ([$class: 'CopyArtifact',
 112                            projectName: "${params.UPSTREAM_JOB_NAME}",
 113                            selector: [$class: 'SpecificBuildSelector', buildNumber: "${params.UPSTREAM_JOB_NUMBER}"]
 114                           ])
 115
 116                     //options = get_env_from_build('build.env')
 117                     // grab the build name/number
 118                     //build_num = sh(returnStdout:true,  script: "cat build.env | awk -F= '/BUILD_NUMBER/{print \$2}'").trim()
 119                     build_num = ci_helper.get_env_value('build.env','BUILD_NUMBER')
 120                     component = ci_helper.get_mdg_from_project(ci_helper.get_env_value('build.env','GERRIT_PROJECT'))
 121
 122                     // the upstream job name contains suffix with the project. Need this stripped off
 123                     def project_without_branch = params.UPSTREAM_JOB_NAME.split('/')[0]
 124
 125                     ci_helper.get_archive(params.ARTIFACTORY_SERVER,component,GERRIT_BRANCH, "${project_without_branch} :: ${GERRIT_BRANCH}", build_num)
 126
 127                     sh "rm -rf dists"
 128                 }
 129
 130                 // sign all the components
 131                 for (component in list) {
 132                     sh "dpkg-sig --sign builder -k ${GPG_KEY_NAME} pool/${component}/*"
 133                 }
 134
 135                 // now create the distro
 136                 for (component in list) {
 137                     sh "mkdir -p dists/${params.REPO_DISTRO}/${component}/binary-amd64/"
 138                     sh "apt-ftparchive packages pool/${component} > dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 139                     sh "gzip -9fk dists/${params.REPO_DISTRO}/${component}/binary-amd64/Packages"
 140                 }
 141
 142                 // create and sign the release file
 143                 sh "apt-ftparchive release dists/${params.REPO_DISTRO} > dists/${params.REPO_DISTRO}/Release"
 144                 sh "gpg --yes -abs -u ${GPG_KEY_NAME} -o dists/${params.REPO_DISTRO}/Release.gpg dists/${params.REPO_DISTRO}/Release"
 145
 146                 // copy the public key into the release folder
 147                 // this pulls the key from the home dir of the current user (jenkins)
 148                 sh "cp ~/${REPO_KEY_NAME} ."
 149
 150                 // merge the change logs
 151                 sh """
 152                    rm -f changelog/changelog-osm.html
 153                    [ ! -d changelog ] || for mdgchange in \$(ls changelog); do cat changelog/\$mdgchange >> changelog/changelog-osm.html; done
 154                    """
 155             }
 156             // start an apache server to serve up the images
 157             http_server_name = "${container_name}-apache"
 158
 159             pwd = sh(returnStdout:true,  script: 'pwd').trim()
 160             repo_base_url = ci_helper.start_http_server(pwd,http_server_name)
 161         }
 162
 163         // now pull the devops package and install in temporary location
 164         tempdir = sh(returnStdout: true, script: "mktemp -d").trim()
 165         osm_devops_dpkg = sh(returnStdout: true, script: "find . -name osm-devops*.deb").trim()
 166         sh "dpkg -x ${osm_devops_dpkg} ${tempdir}"
 167         OSM_DEVOPS="${tempdir}/usr/share/osm-devops"
 168     }
 169
 170     dir(OSM_DEVOPS) {
 171         error = null
 172         if ( params.DO_BUILD ) {
 173             stage("Build") {
 174                 sh "make -C docker clean"
 175                 sh "make -j4 -C docker CMD_DOCKER_ARGS= TAG=${container_name} RELEASE=${params.RELEASE} REPOSITORY_BASE=${repo_base_url} REPOSITORY_KEY=${params.REPO_KEY_NAME} REPOSITORY=${params.REPO_DISTRO}"
 176             }
 177         }
 178
 179         try {
 180             if ( params.DO_INSTALL ) {
 181                 stage("Install") {
 182
 183                     //will by default always delete containers on complete
 184                     //sh "jenkins/system/delete_old_containers.sh ${container_name_prefix}"
 185
 186                     commit_id = ''
 187                     repo_distro = ''
 188                     repo_key_name = ''
 189                     release = ''
 190
 191                     if ( params.COMMIT_ID )
 192                     {
 193                         commit_id = "-b ${params.COMMIT_ID}"
 194                     }
 195
 196                     if ( params.REPO_DISTRO )
 197                     {
 198                         repo_distro = "-r ${params.REPO_DISTRO}"
 199                     }
 200
 201                     if ( params.REPO_KEY_NAME )
 202                     {
 203                         repo_key_name = "-k ${params.REPO_KEY_NAME}"
 204                     }
 205
 206                     if ( params.RELEASE )
 207                     {
 208                         release = "-R ${params.RELEASE}"
 209                     }
 210
 211                     sh """
 212                         export PATH=$PATH:/snap/bin
 213                         installers/full_install_osm.sh -y -s ${container_name} --test --nolxd --nodocker --nojuju --nohostports --nohostclient \
 214                                                         --nodockerbuild -t ${container_name} \
 215                                                         -w /tmp/osm \
 216                                                         ${commit_id} \
 217                                                         ${repo_distro} \
 218                                                         ${repo_base_url} \
 219                                                         ${repo_key_name} \
 220                                                         ${release} \
 221                                                         ${params.BUILD_FROM_SOURCE}
 222                        """
 223                 }
 224             }
 225
 226             stage_archive = false
 227             if ( params.DO_SMOKE ) {
 228                 stage("OSM Health") {
 229                     sh "installers/osm_health.sh -s ${container_name}"
 230                 }
 231                 stage("Smoke") {
 232                     run_systest(container_name,container_name,"smoke")
 233                     // archive smoke success until stage_4 is ready
 234                     stage_archive = params.SAVE_ARTIFACTS_ON_SMOKE_SUCCESS
 235                 }
 236             }
 237
 238             if ( params.DO_STAGE_4 ) {
 239                 stage("stage_4") {
 240                     def downstream_params = [
 241                         string(name: 'CONTAINER_NAME', value: container_name),
 242                         string(name: 'NODE', value: NODE_NAME.split()[0]),
 243                     ]
 244                     stage_4_result = build job: "${params.DOWNSTREAM_STAGE_NAME}/${GERRIT_BRANCH}", parameters: downstream_params, propagate: false
 245                     currentBuild.result = stage_4_result.result
 246
 247                     if ( stage_4_result.getResult().equals('SUCCESS') ) {
 248                         stage_archive = true;
 249                     }
 250                 }
 251             }
 252
 253             // override to save the artifacts
 254             if ( params.SAVE_ARTIFACTS_OVERRIDE || stage_archive ) {
 255                 stage("Archive") {
 256                     sh "echo ${container_name} > build_version.txt"
 257                     archiveArtifacts artifacts: "build_version.txt", fingerprint: true
 258
 259                     // Archive the tested repo
 260                     dir("repo/${RELEASE}") {
 261                         ci_helper.archive(params.ARTIFACTORY_SERVER,RELEASE,GERRIT_BRANCH,'tested')
 262                     }
 263                 }
 264             }
 265         }
 266         catch(caughtError) {
 267             println("Caught error!")
 268             error = caughtError
 269             currentBuild.result = 'FAILURE'
 270         }
 271         finally {
 272             sh "docker stop ${http_server_name}"
 273             sh "docker rm ${http_server_name}"
 274
 275             if ( params.DO_INSTALL ) {
 276                 if (error) {
 277                     if ( !params.SAVE_CONTAINER_ON_FAIL ) {
 278                         uninstall_osm container_name
 279                     }
 280                     throw error
 281                 }
 282                 else {
 283                     if ( !params.SAVE_CONTAINER_ON_PASS ) {
 284                         uninstall_osm container_name
 285                     }
 286                 }
 287             }
 288         }
 289     }
 290 }